[gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-9999.ebuild virtualbox-ose-1.6.2.ebuild virtualbox-ose-1.6.4.ebuild virtualbox-ose-1.6.6.ebuild virtualbox-ose-1.5.6.ebuild

[Markus Ullmann (jokey)]

jokey       08/09/06 19:21:40

  Modified:             ChangeLog virtualbox-ose-9999.ebuild
                        virtualbox-ose-1.6.2.ebuild
                        virtualbox-ose-1.6.4.ebuild
  Added:                virtualbox-ose-1.6.6.ebuild
  Removed:              virtualbox-ose-1.5.6.ebuild
  Log:
  Port from dev overlay
  (Portage version: 2.2_rc8/cvs/Linux 2.6.26-gentoo i686)

Revision  Changes    Path
1.4                  app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	31 Aug 2008 11:22:15 -0000	1.3
+++ ChangeLog	6 Sep 2008 19:21:39 -0000	1.4
@@ -1,6 +1,31 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.3 2008/08/31 11:22:15 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.4 2008/09/06 19:21:39 jokey Exp $
+
+*virtualbox-ose-1.6.6 (06 Sep 2008)
+
+  06 Sep 2008; Markus Ullmann <jokey@g.o>
+  -files/virtualbox-ose-1.5.6-remove-alsa.patch,
+  -files/virtualbox-ose-1.5.6-remove-unused.patch,
+  files/virtualbox-ose-1.6.4-fix-missing-makefiles.patch,
+  +files/virtualbox-ose-1.6.6-remove-unused.patch,
+  files/virtualbox-ose-wrapper, -virtualbox-ose-1.5.6.ebuild,
+  virtualbox-ose-1.6.2.ebuild, virtualbox-ose-1.6.4.ebuild,
+  +virtualbox-ose-1.6.6.ebuild, virtualbox-ose-9999.ebuild:
+  Port from dev overlay
+
+  03 Sep 2008; Alessio Cassibba (X-Drum) <swapon@×××××.com>
+  -virtualbox-ose-1.5.6.ebuild,
+  -files/virtualbox-ose-1.5.6-remove-alsa.patch,
+  -files/virtualbox-ose-1.5.6-remove-unused.patch,
+  virtualbox-ose-1.6.2.ebuild, virtualbox-ose-1.6.4.ebuild,
+  +virtualbox-ose-1.6.6.ebuild,
+  +files/virtualbox-ose-1.6.6-remove-unused.patch,
+  files/virtualbox-ose-wrapper:
+  Version bump; fix SRC_URI; enable additions by default wrt bug #235889; add
+  dev-util/kbuild and dev-lang/yasm to DEPEND and force to build without
+  shipped binaries (kBuild, yasm), thanks to Alon Bar-Lev for pointing out
+  this, wrt bug #232775; add qt3 USE flag;
 
   27 Aug 2008; Markus Ullmann <jokey@g.o>
   virtualbox-ose-1.6.4.ebuild:
@@ -56,13 +81,13 @@
   04 Mar 2008; Markus Ullmann <jokey@g.o> virtualbox-1.5.4-r1.ebuild:
   Stable on x86 wrt bug #208905
 
-  26 Feb 2008; Diego Pettenò <flameeyes@g.o>
+  26 Feb 2008; Diego Pettenò <flameeyes@g.o>
   virtualbox-1.5.6.ebuild:
   Fix patch naming.
 
 *virtualbox-1.5.6 (25 Feb 2008)
 
-  25 Feb 2008; Diego Pettenò <flameeyes@g.o>
+  25 Feb 2008; Diego Pettenò <flameeyes@g.o>
   +virtualbox-1.5.6.ebuild:
   Version bump, as requested by the proxy-maintainer Alessio Cassibba.
 
@@ -111,7 +136,7 @@
   Fix desktop entry for bug #196832, typo in wrapper and HAL warning. Thanks
   to Alessio for providing needed modifications
 
-  29 Oct 2007; Dawid Węgliński <cla@g.o> virtualbox-1.5.2.ebuild:
+  29 Oct 2007; Dawid Węgliński <cla@g.o> virtualbox-1.5.2.ebuild:
   Stable on x86
 
 *virtualbox-1.5.2 (22 Oct 2007)
@@ -188,7 +213,7 @@
   virtualbox-1.3.8.ebuild, virtualbox-9999.ebuild:
   Fix for sdl useflag bug #177335
 
-  21 Apr 2007; Raúl Porcel <armin76@g.o> virtualbox-1.3.8.ebuild:
+  21 Apr 2007; Raúl Porcel <armin76@g.o> virtualbox-1.3.8.ebuild:
   x86 stable
 
 *virtualbox-1.3.8 (16 Mar 2007)



1.2                  app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild?r1=1.1&r2=1.2

Index: virtualbox-ose-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- virtualbox-ose-9999.ebuild	27 Aug 2008 12:39:00 -0000	1.1
+++ virtualbox-ose-9999.ebuild	6 Sep 2008 19:21:39 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild,v 1.1 2008/08/27 12:39:00 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild,v 1.2 2008/09/06 19:21:39 jokey Exp $
 
 EAPI=1
 



1.2                  app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild?r1=1.1&r2=1.2

Index: virtualbox-ose-1.6.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- virtualbox-ose-1.6.2.ebuild	27 Aug 2008 12:39:00 -0000	1.1
+++ virtualbox-ose-1.6.2.ebuild	6 Sep 2008 19:21:39 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild,v 1.1 2008/08/27 12:39:00 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.2.ebuild,v 1.2 2008/09/06 19:21:39 jokey Exp $
 
 EAPI=1
 
@@ -9,12 +9,12 @@
 MY_P=VirtualBox-${PV}-OSE
 DESCRIPTION="Softwarefamily of powerful x86 virtualization"
 HOMEPAGE="http://www.virtualbox.org/"
-SRC_URI="http://www.virtualbox.org/download/${PV}/${MY_P}.tar.bz2"
+SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="additions alsa headless pulseaudio sdk"
+IUSE="+additions alsa headless pulseaudio sdk"
 
 RDEPEND="!app-emulation/virtualbox-bin
 	~app-emulation/virtualbox-modules-${PV}



1.3                  app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild?r1=1.2&r2=1.3

Index: virtualbox-ose-1.6.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- virtualbox-ose-1.6.4.ebuild	27 Aug 2008 13:43:38 -0000	1.2
+++ virtualbox-ose-1.6.4.ebuild	6 Sep 2008 19:21:39 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild,v 1.2 2008/08/27 13:43:38 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.4.ebuild,v 1.3 2008/09/06 19:21:39 jokey Exp $
 
 EAPI=1
 
@@ -9,12 +9,12 @@
 MY_P=VirtualBox-${PV}-OSE
 DESCRIPTION="Softwarefamily of powerful x86 virtualization"
 HOMEPAGE="http://www.virtualbox.org/"
-SRC_URI="http://www.virtualbox.org/download/${PV}/${MY_P}.tar.bz2"
+SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 x86"
-IUSE="additions alsa headless pulseaudio sdk"
+IUSE="+additions alsa headless pulseaudio sdk"
 
 RDEPEND="!app-emulation/virtualbox-bin
 	~app-emulation/virtualbox-modules-${PV}
@@ -146,6 +146,12 @@
 	newexe "${FILESDIR}/${PN}-wrapper" "VBox.sh" || die
 	fowners root:vboxusers /opt/VirtualBox/VBox.sh
 	fperms 0750 /opt/VirtualBox/VBox.sh
+
+	# Disable logging by default, broken in this release (bug #233683)
+	sed -i \
+			-e "/vbox.cfg\"$/a export VBOX_LOG_DEST=\"nofile\"" \
+			"${D}"/opt/VirtualBox/VBox.sh || die "VBox.sh sed failed"
+
 	newexe "${S}"/src/VBox/Installer/linux/VBoxAddIF.sh "VBoxAddIF.sh" || die
 	fowners root:vboxusers /opt/VirtualBox/VBoxAddIF.sh
 	fperms 0750 /opt/VirtualBox/VBoxAddIF.sh



1.1                  app-emulation/virtualbox-ose/virtualbox-ose-1.6.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.6.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-ose-1.6.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-1.6.6.ebuild,v 1.1 2008/09/06 19:21:39 jokey Exp $

EAPI=1

inherit eutils fdo-mime flag-o-matic qt3 toolchain-funcs

MY_P=VirtualBox-${PV}-OSE
DESCRIPTION="Softwarefamily of powerful x86 virtualization"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+additions alsa headless pulseaudio +qt3 sdk"

RDEPEND="!app-emulation/virtualbox-bin
	~app-emulation/virtualbox-modules-${PV}
	dev-libs/libIDL
	>=dev-libs/libxslt-1.1.19
	dev-libs/xalan-c
	dev-libs/xerces-c
	!headless? (
		qt3? ( x11-libs/qt:3 )
		x11-libs/libXcursor
		media-libs/libsdl
		x11-libs/libXt )"
DEPEND="${RDEPEND}
	dev-util/kbuild
	>=dev-lang/yasm-0.6.2
	sys-devel/bin86
	sys-devel/dev86
	sys-power/iasl
	media-libs/libpng
	alsa? ( >=media-libs/alsa-lib-1.0.13 )
	pulseaudio? ( media-sound/pulseaudio )"
# sys-apps/hal is required at runtime (bug #197541)
RDEPEND="${RDEPEND}
	additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )
	sys-apps/usermode-utilities
	net-misc/bridge-utils
	sys-apps/hal"

S=${WORKDIR}/${MY_P/-OSE/}

pkg_setup() {
	# known problems with gcc 4.3 and the recompiler
	# http://www.virtualbox.org/ticket/936
	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "43" ]]; then
			eerror "there are known problems with gcc 4.3 and the virtualbox"
			eerror "recompiler stuff. Please use at least a version of gcc < 4.3"
			die "gcc 4.3 cannot build the virtualbox recompiler"
	fi

	if ! use headless; then
			# The VBoxSDL frontend needs media-libs/libsdl compiled
			# with USE flag X enabled (bug #177335)
			if ! built_with_use media-libs/libsdl X; then
				eerror "media-libs/libsdl was compiled without the \"X\" USE flag enabled."
				eerror "Please re-emerge media-libs/libsdl with USE=\"X\"."
				die "media-libs/libsdl should be compiled with the \"X\" USE flag."
			fi
	else
			if use qt3; then
					einfo ""
					einfo "You selected USE=\"qt3 headless\", defaulting to"
					einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
					einfo ""
			fi
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Remove shipped binaries (kBuild,yasm), see bug #232775
	rm -rf kBuild/bin tools

	# Don't build things unused or splitted into separate ebuilds (eg: additions)
	epatch "${FILESDIR}/${P}-remove-unused.patch"
}

src_compile() {

	local myconf
	# Don't build vboxdrv kernel module
	myconf="--disable-kmods --disable-qt4"

	if ! use pulseaudio; then
			myconf="${myconf} --disable-pulse"
	fi
	if ! use alsa; then
			myconf="${myconf} --disable-alsa"
	fi
	if ! use headless; then
			if ! use qt3; then
					myconf="${myconf} --disable-qt"
			fi
	else
			myconf="${myconf} --build-headless"
	fi

	./configure --with-gcc="$(tc-getCC)" --with-g++="$(tc-getCXX)" \
	${myconf} || die "configure failed"
	source ./env.sh

	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
	# and strip all flags
	strip-flags

	MAKE="kmk" emake TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
		TOOL_YASM_AS=yasm \
		all || die "kmk failed"
}

src_install() {
	cd "${S}"/out/linux.${ARCH}/release/bin

	# create virtualbox configurations files
	insinto /etc/vbox
	newins "${FILESDIR}/${PN}-config" vbox.cfg
	newins "${FILESDIR}/${PN}-interfaces" interfaces

	insinto /opt/VirtualBox
	if use sdk; then
		doins -r sdk
		fowners root:vboxusers /opt/VirtualBox/sdk/bin/xpidl
		fperms 0750 /opt/VirtualBox/sdk/bin/xpidl
	fi

	rm -rf sdk src tst* testcase xpidl SUPInstall SUPUninstall VBox.png \
	VBoxBFE vditool VBoxSysInfo.sh vboxkeyboard.tar.gz

	doins -r *

	if ! use headless; then
			for each in VBox{Manage,SDL,SVC,XPCOMIPCD,Tunctl,Headless} ; do
				fowners root:vboxusers /opt/VirtualBox/${each}
				fperms 0750 /opt/VirtualBox/${each}
			done

			if use qt3; then
				fowners root:vboxusers /opt/VirtualBox/VirtualBox
				fperms 0750 /opt/VirtualBox/VirtualBox

				dosym /opt/VirtualBox/VBox.sh /usr/bin/VirtualBox
			fi

			dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxSDL

			newicon	"${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
			domenu "${FILESDIR}"/${PN}.desktop
	else
			for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl,Headless} ; do
				fowners root:vboxusers /opt/VirtualBox/${each}
				fperms 0750 /opt/VirtualBox/${each}
			done
	fi

	exeinto /opt/VirtualBox
	newexe "${FILESDIR}/${PN}-wrapper" "VBox.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBox.sh
	fperms 0750 /opt/VirtualBox/VBox.sh
	newexe "${S}"/src/VBox/Installer/linux/VBoxAddIF.sh "VBoxAddIF.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBoxAddIF.sh
	fperms 0750 /opt/VirtualBox/VBoxAddIF.sh

	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxManage
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxVRDP
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxHeadless
	dosym /opt/VirtualBox/VBoxTunctl /usr/bin/VBoxTunctl
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxAddIF
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxDeleteIF
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog ""
	if ! use headless; then
			elog "To launch VirtualBox just type: \"VirtualBox\""
	fi
	elog "You must be in the vboxusers group to use VirtualBox."
	elog ""
	elog "The last user manual is available for download at:"
	elog "http://www.virtualbox.org/download/UserManual.pdf"
	elog ""
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}