[gentoo-commits] gentoo-x86 commit in dev-java/icedtea-bin: ChangeLog icedtea-bin-6.1.13.3-r1.ebuild

[Vlastimil Babka (caster)]

caster      14/06/03 06:30:12

  Modified:             ChangeLog
  Added:                icedtea-bin-6.1.13.3-r1.ebuild
  Log:
  Revbump to use external dev-java/icedtea-web:0 for javaws and nsplugin, instead of bundling vulnerable old version. Security bug #501472.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4E61DE84)

Revision  Changes    Path
1.61                 dev-java/icedtea-bin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-bin/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-bin/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-bin/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/icedtea-bin/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	2 Jun 2014 22:28:44 -0000	1.60
+++ ChangeLog	3 Jun 2014 06:30:12 -0000	1.61
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/icedtea-bin
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-bin/ChangeLog,v 1.60 2014/06/02 22:28:44 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-bin/ChangeLog,v 1.61 2014/06/03 06:30:12 caster Exp $
+
+*icedtea-bin-6.1.13.3-r1 (03 Jun 2014)
+
+  03 Jun 2014; Vlastimil Babka <caster@g.o>
+  +icedtea-bin-6.1.13.3-r1.ebuild:
+  Revbump to use external dev-java/icedtea-web:0 for javaws and nsplugin,
+  instead of bundling vulnerable old version. Security bug #501472.
 
 *icedtea-bin-7.2.4.7 (02 Jun 2014)
 



1.1                  dev-java/icedtea-bin/icedtea-bin-6.1.13.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-bin/icedtea-bin-6.1.13.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-bin/icedtea-bin-6.1.13.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: icedtea-bin-6.1.13.3-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-bin/icedtea-bin-6.1.13.3-r1.ebuild,v 1.1 2014/06/03 06:30:12 caster Exp $

EAPI="5"

inherit java-vm-2 multilib prefix

dist="http://dev.gentoo.org/~caster/distfiles/"
TARBALL_VERSION="${PV}"

DESCRIPTION="A Gentoo-made binary build of the IcedTea JDK"
HOMEPAGE="http://icedtea.classpath.org"
SRC_URI="
	amd64? ( ${dist}/${PN}-core-${TARBALL_VERSION}-amd64.tar.bz2 )
	x86? ( ${dist}/${PN}-core-${TARBALL_VERSION}-x86.tar.bz2 )
	doc? ( ${dist}/${PN}-doc-${TARBALL_VERSION}.tar.bz2 )
	examples? (
		amd64? ( ${dist}/${PN}-examples-${TARBALL_VERSION}-amd64.tar.bz2 )
		x86? ( ${dist}/${PN}-examples-${TARBALL_VERSION}-x86.tar.bz2 )
	)
	source? ( ${dist}/${PN}-src-${TARBALL_VERSION}.tar.bz2 )"

LICENSE="GPL-2-with-linking-exception"
SLOT="6"
KEYWORDS="-* ~amd64 ~x86"

IUSE="+X +alsa cjk +cups doc examples nsplugin selinux source webstart"
REQUIRED_USE="nsplugin? ( X )"
RESTRICT="strip"

# 423161
QA_PREBUILT="opt/.*"

ALSA_COMMON_DEP="
	>=media-libs/alsa-lib-1.0.20"
CUPS_COMMON_DEP="
	>=net-print/cups-1.4"
X_COMMON_DEP="
	>=dev-libs/glib-2.32:2
	>=media-libs/freetype-2.4.9:2
	>=x11-libs/gtk+-2.24:2
	>=x11-libs/libX11-1.4
	>=x11-libs/libXext-1.3
	>=x11-libs/libXi-1.6
	>=x11-libs/libXtst-1.2"

COMMON_DEP="
	>=media-libs/giflib-4.1.6-r1
	>=media-libs/libpng-1.6:0=
	>=sys-devel/gcc-4.5.4
	>=sys-libs/glibc-2.15
	>=sys-libs/zlib-1.2.3-r1
	|| ( virtual/jpeg:62 media-libs/jpeg:62 )
	selinux? ( sec-policy/selinux-java )"

RDEPEND="${COMMON_DEP}
	X? (
		${X_COMMON_DEP}
		media-fonts/dejavu
		cjk? (
			media-fonts/arphicfonts
			media-fonts/baekmuk-fonts
			media-fonts/lklug
			media-fonts/lohit-fonts
			media-fonts/sazanami
		)
	)
	alsa? ( ${ALSA_COMMON_DEP} )
	cups? ( ${CUPS_COMMON_DEP} )"

PDEPEND="webstart? ( dev-java/icedtea-web:0 )
	nsplugin? ( dev-java/icedtea-web:0[icedtea7] )"

src_install() {
	local dest="/opt/${P}"
	local ddest="${ED}/${dest}"
	dodir "${dest}"

	# Ensures HeadlessGraphicsEnvironment is used.
	if ! use X; then
		rm -r jre/lib/$(get_system_arch)/xawt || die
	fi

	# doins can't handle symlinks.
	cp -pRP bin include jre lib man "${ddest}" || die

	# Remove on next bump as the needed marks are already set by icedtea ebuild.
	java-vm_set-pax-markings "${ddest}"

	dodoc ../doc/{ASSEMBLY_EXCEPTION,THIRD_PARTY_README}

	if use doc; then
		dohtml -r ../doc/html/*
	fi

	if use examples; then
		cp -pRP share/{demo,sample} "${ddest}" || die
	fi

	if use source; then
		cp src.zip "${ddest}" || die
	fi

	# Remove after next bump, handled by icedtea ebuild. Bug 390663
	cp "${FILESDIR}"/fontconfig.Gentoo.properties.src "${T}"/fontconfig.Gentoo.properties || die
	eprefixify "${T}"/fontconfig.Gentoo.properties
	insinto "${dest}"/jre/lib
	doins "${T}"/fontconfig.Gentoo.properties

	if use webstart || use nsplugin; then
		dosym /usr/$(get_libdir)/icedtea${SLOT}-web/bin/itweb-settings ${dest}/bin/itweb-settings
		dosym /usr/$(get_libdir)/icedtea${SLOT}-web/bin/itweb-settings ${dest}/jre/bin/itweb-settings
	fi
	if use webstart; then
		dosym /usr/$(get_libdir)/icedtea${SLOT}-web/bin/javaws ${dest}/bin/javaws
		dosym /usr/$(get_libdir)/icedtea${SLOT}-web/bin/javaws ${dest}/jre/bin/javaws
	fi

	set_java_env
	java-vm_revdep-mask "${dest}"
}

pkg_preinst() {
	if has_version "<=dev-java/icedtea-bin-1.10.4:${SLOT}"; then
		# portage would preserve the symlink otherwise, related to bug #384397
		rm -f "${EROOT}/usr/lib/jvm/icedtea6-bin"
		elog "To unify the layout and simplify scripts, the identifier of Icedtea-bin-6*"
		elog "has changed from 'icedtea6-bin' to 'icedtea-bin-6' starting from version 6.1.10.4"
		elog "If you had icedtea6-bin as system VM, the change should be automatic, however"
		elog "build VM settings in /etc/java-config-2/build/jdk.conf are not changed"
		elog "and the same holds for any user VM settings. Sorry for the inconvenience."
	fi
}

pkg_postinst() {
	if use nsplugin; then
		if [[ -n ${REPLACING_VERSIONS} ]] && ! version_is_at_least 6.1.13.3-r1 ${REPLACING_VERSIONS} ]]; then
			elog "The nsplugin for icedtea-bin is now provided by the icedtea-web package"
			elog "If you had icedtea-bin-6 nsplugin selected, you may see a related error below"
			elog "The switch should complete properly during the subsequent installation of icedtea-web"
			elog "Afterwards you may verify the output of 'eselect java-nsplugin list' and adjust accordingly'"
		fi
	fi

	# Set as default VM if none exists
	java-vm-2_pkg_postinst
}