[gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/, dev-python/spyder/files/

[Andrew Ammerlaan]

commit:     8849ab5008c9507ed371b59b76d8275b4163ba88
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  7 11:29:02 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Mon Nov  7 11:29:02 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8849ab50

dev-python/spyder: add 5.4.0

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/spyder/Manifest                         |   1 +
 .../files/spyder-5.4.0-unpin-qdarkstyle.patch      |  26 +++
 dev-python/spyder/spyder-5.4.0.ebuild              | 195 +++++++++++++++++++++
 3 files changed, 222 insertions(+)

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index b6f3257168e2..9c11f1b72b36 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,2 +1,3 @@
 DIST spyder-5.3.3.gh.tar.gz 24443628 BLAKE2B 767b3e1d59ce650d2df0d229d94eef53bc4c7b52f5d40fd62748efeb3a756a773110aa17442403a1b37777dd39fc367164ad54cd8f767d4311caa8d3e8bf05da SHA512 7d521f8367953849233538cbfd74f1fd98da87e69dbed8076718e81cd09ae66aca84523c4ecdf0e8aeb60644791754df19f09dd244ce11e3f7decc97bb050e02
+DIST spyder-5.4.0.gh.tar.gz 24497211 BLAKE2B 6022e50345a7493e79cc05d735fcded1d109f7b33c94c4b281a0526fe2c3f5c1020c30bc1a48cdde28db6b279b38f191dc6974724ca893220bac034c69ffd46c SHA512 473408c8315ab46dade4cdfb709119d29a38ea77f29c3dc5a8b4e7eece5c1cbd21978ed2665fc6747ef4db9d8726d4ba796ee0716d48657367bb9840760e786f
 DIST spyder-docs-bb9b308b66cc90e47f43418f079bf098eb4efe6c.gh.tar.gz 89966852 BLAKE2B 7698b0210ccfec9f00cc76893f49398a02878c732eba6bbc89c1da4514734aad8ae8ef85a9c701a1d194976a35a8092755f7c5f09b319f670fac21d0a2e6c542 SHA512 9dd428ca2623c5703076887ab593bd92a2e737d74eb914a7a186d2ab4855519abb02875226463d8c11ff5021e7e84a5ba7c200ad5476f0dc4646831bb0b197a1

diff --git a/dev-python/spyder/files/spyder-5.4.0-unpin-qdarkstyle.patch b/dev-python/spyder/files/spyder-5.4.0-unpin-qdarkstyle.patch
new file mode 100644
index 000000000000..87b97a94b34a
--- /dev/null
+++ b/dev-python/spyder/files/spyder-5.4.0-unpin-qdarkstyle.patch
@@ -0,0 +1,26 @@
+diff --git a/setup.py b/setup.py
+index 1aa7f96..5345b0a 100644
+--- a/setup.py
++++ b/setup.py
+@@ -232,7 +232,7 @@ install_requires = [
+     'python-lsp-server[all]>=1.6.0,<1.7.0',
+     'pyxdg>=0.26;platform_system=="Linux"',
+     'pyzmq>=22.1.0',
+-    'qdarkstyle>=3.0.2,<3.1.0',
++    'qdarkstyle>=3.0.2',
+     'qstylizer>=0.2.2',
+     'qtawesome>=1.2.1',
+     'qtconsole>=5.4.0,<5.5.0',
+diff --git a/spyder/dependencies.py b/spyder/dependencies.py
+index 244a161..f44d045 100644
+--- a/spyder/dependencies.py
++++ b/spyder/dependencies.py
+@@ -58,7 +58,7 @@ PYLSP_BLACK_REQVER = '>=1.2.0'
+ PYLS_SPYDER_REQVER = '>=0.4.0'
+ PYXDG_REQVER = '>=0.26'
+ PYZMQ_REQVER = '>=22.1.0'
+-QDARKSTYLE_REQVER = '>=3.0.2;<3.1.0'
++QDARKSTYLE_REQVER = '>=3.0.2'
+ QSTYLIZER_REQVER = '>=0.2.2'
+ QTAWESOME_REQVER = '>=1.2.1'
+ QTCONSOLE_REQVER = '>=5.4.0;<5.5.0'

diff --git a/dev-python/spyder/spyder-5.4.0.ebuild b/dev-python/spyder/spyder-5.4.0.ebuild
new file mode 100644
index 000000000000..72dde78556eb
--- /dev/null
+++ b/dev-python/spyder/spyder-5.4.0.ebuild
@@ -0,0 +1,195 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="bb9b308b66cc90e47f43418f079bf098eb4efe6c"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work. RESTRICTing because IMO it is
+# not worth the several hours I would have to spend every single version bump
+# checking which tests do and do not work.
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-venv-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.4.0[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.5.0[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},svg,webengine]
+	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
+	"${FILESDIR}/${PN}-5.4.0-unpin-qdarkstyle.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+	dev-python/sphinx-panels \
+	dev-python/pydata-sphinx-theme \
+	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# Do not depend on ipython, this dependency is carried in spyder-kernels
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+		-e "/'ipython[ 0-9<=>.,]*',/d" \
+			setup.py || die
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+		-e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+
+	# do not check deps, fails because we removed dependencies above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# can't check for update, need network
+	rm spyder/workers/tests/test_update.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here test results
+# should be checked for success manually
+python_test() {
+	"${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
+	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+	# Plugins with no release yet:
+	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
+	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
+}