[gentoo-commits] repo/gentoo:master commit in: sys-power/acpilight/

[Brian Evans]

commit:     23815cc21c9d3b8d84c0a14a4cdf5cbea76d4ccd
Author:     Brian Evans <grknight <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  1 16:12:13 2020 +0000
Commit:     Brian Evans <grknight <AT> gentoo <DOT> org>
CommitDate: Tue Sep  1 16:16:17 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23815cc2

sys-power/acpilight: Revbump for single impl and 3.8

Signed-off-by: Brian Evans <grknight <AT> gentoo.org>

 sys-power/acpilight/acpilight-1.2-r1.ebuild | 54 +++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/sys-power/acpilight/acpilight-1.2-r1.ebuild b/sys-power/acpilight/acpilight-1.2-r1.ebuild
new file mode 100644
index 00000000000..36f03785d73
--- /dev/null
+++ b/sys-power/acpilight/acpilight-1.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
+
+inherit python-single-r1 udev
+
+MY_P="${PN}-v${PV}"
+
+DESCRIPTION="Replacement for xbacklight that uses the ACPI interface to set brightness"
+HOMEPAGE="https://gitlab.com/wavexx/acpilight/"
+SRC_URI="https://gitlab.com/wavexx/acpilight/-/archive/v${PV}/${MY_P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+S="${WORKDIR}/${MY_P}"
+
+RDEPEND="virtual/udev
+	acct-group/video
+	${PYTHON_DEPS}
+	!x11-apps/xbacklight"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+DOCS=( README.rst NEWS.rst )
+
+# Disable Makefile that installs by default
+src_compile() { :; }
+
+src_install() {
+	python_doscript xbacklight
+	udev_dorules "${S}"/90-backlight.rules
+	doman xbacklight.1
+	einstalldocs
+	newinitd "${FILESDIR}"/acpilight.initd acpilight
+	newconfd "${FILESDIR}"/acpilight.confd acpilight
+}
+
+pkg_postinst() {
+	udev_reload
+	einfo
+	elog "To use the xbacklight binary as a regular user, you must be a part of the video group"
+	einfo
+	elog "If this utility does not find any backlights to manipulate,"
+	elog "verify you have kernel support on the device and display driver enabled."
+	einfo
+	elog "To take advantage of the OpenRC init script, and automate the process of"
+	elog "saving and restoring the brightness level you should add acpilight"
+	elog "to the boot runlevel. You can do this as root like so:"
+	elog "# rc-update add acpilight boot"
+	einfo
+}