[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-settings-daemon/

[Sam James]

commit:     0e2dbaae80b55996ceb2ef98593edfbdd82b5fb3
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Tue Dec 28 20:42:09 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 21 17:15:08 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0e2dbaae

gnome-extra/cinnamon-settings-daemon: 5.2.0 version bump

Add Python 3.10 support.

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/cinnamon-settings-daemon/Manifest      |  1 +
 .../cinnamon-settings-daemon-5.2.0.ebuild          | 94 ++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index 46679822f1f0..ebffce5672bd 100644
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-settings-daemon-5.0.4.tar.gz 663647 BLAKE2B 459ca8b407291e7a84742b75a272a621d05ef1929ec76dd913af477629db862429165cec26a5985c75f81ce8eaddccc6b74cfa882106784bbfb40e015a21bab8 SHA512 861847fb238ae53fdb31c55ab7f8475f3cad9b48a5dd3611e5ea05129e16b44cc48b3ff5d38c2fdcc3669191f952bf194b6bcba80816fb4daee9e91d85b1c781
+DIST cinnamon-settings-daemon-5.2.0.tar.gz 662588 BLAKE2B aca6aac0a7b85fa9fb60f1101e0027d5faf3f6d95f7d306ae0ad9dd2e19bb1b48ab4333bbcdff5405b52c306f67eb34bfce895b37529d3ce015182aac41dcf07 SHA512 ae076956715bc7b47746868df0f1cb4034a8ce26b2d64878c74654f08a4498155063f16bf7972316fa138f72e10a82e8589fdb607f8072bbcd92e106bedbe98e

diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.2.0.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.2.0.ebuild
new file mode 100644
index 000000000000..b4238e71f45e
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.2.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit meson gnome2-utils python-any-r1 xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-settings-daemon"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libgudev:=
+	>=gnome-base/libgnomekbd-3.6
+	>=gnome-extra/cinnamon-desktop-5.2:0=
+	media-libs/fontconfig
+	>=media-libs/lcms-2.2:2
+	media-libs/libcanberra:0=[gtk3,pulseaudio]
+	>=media-sound/pulseaudio-0.9.16[glib]
+	>=sys-apps/dbus-1.1.2
+	dev-libs/dbus-glib
+	>=sys-auth/polkit-0.97
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14.0:3
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	>=x11-libs/libxklavier-5.0
+	>=sys-power/upower-0.9.11
+
+	colord? ( >=x11-misc/colord-0.1.27:= )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=gnome-base/librsvg-2.36.2
+		x11-drivers/xf86-input-wacom
+		x11-libs/libXtst )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	systemd? ( sys-apps/systemd:0= )
+	!systemd? ( sys-auth/elogind:0= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libxml2:2
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts
+}
+
+src_configure() {
+	# gudev not optional on Linux platforms
+	local emesonargs=(
+		-Duse_gudev=enabled
+		-Duse_polkit=enabled
+		-Duse_logind=enabled
+		$(meson_feature colord use_color)
+		$(meson_feature cups use_cups)
+		$(meson_feature smartcard use_smartcard)
+		$(meson_feature input_devices_wacom use_wacom)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}