[gentoo-commits] repo/gentoo:master commit in: www-client/opera/

[Stephan Hartmann]

commit:     fc8ea8790a3671d747f49401b67180d0d1abdde6
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 20 14:15:46 2021 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Tue Apr 20 14:15:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fc8ea879

www-client/opera: remove old

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera/Manifest                   |   1 -
 www-client/opera/opera-75.0.3969.171.ebuild | 132 ----------------------------
 2 files changed, 133 deletions(-)

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index ba7bd5f6e43..b83768dc556 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,3 +1,2 @@
 DIST opera-ffmpeg-codecs-89.0.4381.8.tar.xz 1427048 BLAKE2B 6f92f8582663b46875f4a3d9b0b80b14eb8b361b23699bd5e10319c9b16b26a436cd710cec684a818189eae4892fc41daf2b3387282926e964d4d395a1c7778e SHA512 7947eeaa361e78d1a69d244727ad601719fd4e6d6c284b1655e9fd9c74cf718f42ba3e0d0277f96a7b9cab984d743ea190404e2f74b5e1a6b9bd244e45b71e77
-DIST opera-stable_75.0.3969.171_amd64.deb 74486264 BLAKE2B 24d356ff2de1853789a2e5e40ed809ebfed37637fbfe59b350519b4f92e676f96e61394fee9db8761b8cd2bc10b7e539bff5947df5c880cecb50caf28be55187 SHA512 e687aea0e5b15b41f6aa7ba8ff2e50b0d0d15c4d7a7b3ab2f66fb54221f1732c85772ea581431c71781601848878d1ea175907fcbd6dd4afdb7648d52c00b9f2
 DIST opera-stable_75.0.3969.218_amd64.deb 74540844 BLAKE2B 377df35c29e33dcdd4b06e8822e58d870227c5795889208a3fdd88fab09aef64d2790c92dcc2f64129ee3c8bed6df6000f72fea4fe8370869b1d7c389271597e SHA512 cd33090527b9c1071442f951995773e062853f6d8d7c07415898759c01823d8c1ee9e08b0b2c858bf6720954a026ff048217b5d6af7ebb05b7a45fcd904ce062

diff --git a/www-client/opera/opera-75.0.3969.171.ebuild b/www-client/opera/opera-75.0.3969.171.ebuild
deleted file mode 100644
index fb6da3dbb4c..00000000000
--- a/www-client/opera/opera-75.0.3969.171.ebuild
+++ /dev/null
@@ -1,132 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-CHROMIUM_LANGS="
-	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-inherit chromium-2 multilib pax-utils unpacker xdg
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* amd64"
-
-FFMPEG_VERSION="89.0.4381.8"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
-	proprietary-codecs? (
-		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs suid"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	app-accessibility/at-spi2-atk:2
-	app-accessibility/at-spi2-core:2
-	dev-libs/atk
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	unpacker
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	rm -r "usr/share/lintian" || die
-
-	# fix docs
-	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-	gzip -d usr/share/doc/${PF}/changelog.gz || die
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
-}