[gentoo-commits] repo/gentoo:master commit in: dev-python/aws-xray-sdk-python/

[Michał Górny]

commit:     f0b9b7ca28fd468abf588279101d11e85b65fd51
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 29 06:41:46 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr 29 07:18:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0b9b7ca

dev-python/aws-xray-sdk-python: Bump to 2.8.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/aws-xray-sdk-python/Manifest            |  1 +
 .../aws-xray-sdk-python-2.8.0.ebuild               | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-python/aws-xray-sdk-python/Manifest b/dev-python/aws-xray-sdk-python/Manifest
index 9b5ea842d8d..8e0ba4f675b 100644
--- a/dev-python/aws-xray-sdk-python/Manifest
+++ b/dev-python/aws-xray-sdk-python/Manifest
@@ -1 +1,2 @@
 DIST aws-xray-sdk-python-2.7.0.gh.tar.gz 265934 BLAKE2B f697c2bbe21db4b20b200ba9e9c264df81e3a6ff64d73639756d8f51a1abe0ecfaf1b852a3befde535757dfa3f75348e2eee1d5124147f04d11f5b5f20976b95 SHA512 d9ff1a190e5503f904258ac47cd7b1c686a9c74d0699f69f053df19ec7ea197da1c9c29a97624ff0758346a0dca9e3a292bf54ba3f340fcd392248602a85bfd9
+DIST aws-xray-sdk-python-2.8.0.gh.tar.gz 267880 BLAKE2B 7a433a0b1b3ca38a100f3b23c79e9b0d7f84cb096f6d30832fdf16f171f9528aee8b81aaf3ba263a90d46f791de8b2f37a919651f9699e5fcf3073db83fc25b4 SHA512 e0fb3fb0bfbd963863714537ea12771df7ffa2857aaf4cdb6414d71ecdfc65c2623fa40a6a48c4eab30f4370d545a595db2762932133a6eba56121a4048502fb

diff --git a/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.8.0.ebuild b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.8.0.ebuild
new file mode 100644
index 00000000000..f1434194a8b
--- /dev/null
+++ b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.8.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="https://github.com/aws/aws-xray-sdk-python https://pypi.org/project/aws-xray-sdk/"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local args=(
+		# unpackaged deps
+		--ignore tests/ext/aiobotocore
+		--ignore tests/ext/pg8000
+		--ignore tests/ext/psycopg2
+		--ignore tests/ext/pymysql
+		--ignore tests/ext/pynamodb
+		--ignore tests/ext/sqlalchemy_core/test_postgres.py
+		--deselect tests/ext/django/test_db.py
+
+		# Internet access
+		--deselect
+		tests/test_patcher.py::test_external_file
+		--deselect
+		tests/test_patcher.py::test_external_module
+		--deselect
+		tests/test_patcher.py::test_external_submodules_full
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		--deselect
+		tests/ext/aiohttp/test_client.py
+		--ignore
+		tests/ext/httplib
+		--ignore
+		tests/ext/requests
+	)
+
+	epytest -p no:django "${args[@]}"
+}