[gentoo-commits] gentoo-x86 commit in app-mobilephone/obexftp: ChangeLog obexftp-0.22_rc9.ebuild

[Alin Nastac (mrness)]

mrness      07/10/01 18:09:51

  Modified:             ChangeLog
  Added:                obexftp-0.22_rc9.ebuild
  Log:
  Fix examples installation, broken by previous update.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.32                 app-mobilephone/obexftp/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	6 Sep 2007 06:23:28 -0000	1.31
+++ ChangeLog	1 Oct 2007 18:09:51 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/obexftp
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.31 2007/09/06 06:23:28 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.32 2007/10/01 18:09:51 mrness Exp $
+
+*obexftp-0.22_rc9 (01 Oct 2007)
+
+  01 Oct 2007; Alin Năstac <mrness@g.o> +obexftp-0.22_rc9.ebuild:
+  Fix examples installation, broken by previous update.
 
   06 Sep 2007; Alin Năstac <mrness@g.o> obexftp-0.22_rc7.ebuild:
   Fix compile error when USE="ruby -bluetooth" (#174507).



1.1                  app-mobilephone/obexftp/obexftp-0.22_rc9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22_rc9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22_rc9.ebuild?rev=1.1&content-type=text/plain

Index: obexftp-0.22_rc9.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22_rc9.ebuild,v 1.1 2007/10/01 18:09:51 mrness Exp $

inherit eutils perl-module flag-o-matic

DESCRIPTION="File transfer over OBEX for mobile phones"
HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
SRC_URI="http://triq.net/obexftp/${P/_/-}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="bluetooth debug perl python ruby swig tcl"

RDEPEND=">=dev-libs/openobex-1.3
	bluetooth? ( >=net-wireless/bluez-libs-2.25 )
	perl? ( >=dev-lang/perl-5.8.8 )
	python? ( >=dev-lang/python-2.4.4 )
	ruby? ( >=dev-lang/ruby-1.8.5 )
	tcl? ( >=dev-lang/tcl-8.4.14 )"
DEPEND="${RDEPEND}
	swig? ( >=dev-lang/swig-1.3.31 )
	dev-util/pkgconfig"

S="${WORKDIR}"/${P%_*}

src_compile() {
	if use debug ; then
		strip-flags
		append-flags "-g -DOBEXFTP_DEBUG=5"
	fi
	if use ruby && ! use bluetooth ; then
		sed -i -e "s/^\(.*bluetooth.*\)$/#\1/" swig/ruby/extconf.rb
	fi

	econf \
		$(use_enable bluetooth) \
		$(use_enable swig) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable tcl) \
		$(use_enable ruby) || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
	dohtml doc/*.html

	# Install examples
	insinto /usr/share/doc/${PF}/examples
	doins examples/*.c
	use perl && doins examples/*.pl
	use python && doins examples/*.py
	use ruby && doins examples/*.rb
	use tcl && doins examples/*.tcl

	use perl && fixlocalpod
}



-- 
gentoo-commits@g.o mailing list