[gentoo-commits] repo/gentoo:master commit in: app-text/html2text/

[Michał Górny]

commit:     a09956475820a07f01fabe695710d59f0b14687a
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Sun Sep 30 14:58:41 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Oct  8 16:09:13 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a0995647

app-text/html2text: EAPI7 revbump, improve ebuild

Closes: https://bugs.gentoo.org/667382
Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger <AT> gmail.com>
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/10027

 app-text/html2text/html2text-1.3.2a-r2.ebuild | 40 +++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/app-text/html2text/html2text-1.3.2a-r2.ebuild b/app-text/html2text/html2text-1.3.2a-r2.ebuild
new file mode 100644
index 00000000000..f96c4819e23
--- /dev/null
+++ b/app-text/html2text/html2text-1.3.2a-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="HTML to text converter"
+HOMEPAGE="http://www.mbayer.de/html2text/"
+SRC_URI="http://www.mbayer.de/html2text/downloads/${P}.tar.gz
+	http://www.mbayer.de/html2text/downloads/patch-utf8-${P}.diff
+	http://www.mbayer.de/html2text/downloads/patch-amd64-${P}.diff
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+
+PATCHES=(
+	"${FILESDIR}/${P}-compiler.patch"
+	"${FILESDIR}/${P}-urlistream-get.patch"
+	"${DISTDIR}/patch-utf8-${P}.diff"
+	"${DISTDIR}/patch-amd64-${P}.diff"
+)
+
+src_prepare() {
+	default
+	gunzip html2text.1.gz html2textrc.5.gz || die
+	tc-export CXX
+}
+
+src_compile() {
+	emake LDFLAGS="${LDFLAGS}" DEBUG="${CXXFLAGS}"
+}
+
+src_install() {
+	dobin html2text
+	doman html2text.1 html2textrc.5
+	dodoc CHANGES CREDITS KNOWN_BUGS README TODO
+}