[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nm-applet/

[Matt Turner]

commit:     badc2ea635b3002f68ba3378f6066bf2f3cca8df
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  7 22:00:13 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Jun  7 22:00:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=badc2ea6

gnome-extra/nm-applet: Version bump to 1.28.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/nm-applet/Manifest                |  1 +
 gnome-extra/nm-applet/nm-applet-1.28.0.ebuild | 52 +++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/gnome-extra/nm-applet/Manifest b/gnome-extra/nm-applet/Manifest
index d6c3d6f3a7bf..f2df7a90f301 100644
--- a/gnome-extra/nm-applet/Manifest
+++ b/gnome-extra/nm-applet/Manifest
@@ -1 +1,2 @@
 DIST network-manager-applet-1.26.0.tar.xz 1971896 BLAKE2B ab87b0e5f8b1c293ac3f2e36c8f834e645fb647e46ce1bf22ac94ed33e6f2f7f8aca5ed43ed46029a281545595978c145773102f06de9b42e579efb8d3e631c3 SHA512 ae3c4f8e55a2cd13093161e1e28873d3cda1c531168ee18115f3f710816f1bdfcf669cd2f796bd38f226d3f6be76407fccbcb19cf9c994b99969b688397b2c71
+DIST network-manager-applet-1.28.0.tar.xz 1894104 BLAKE2B f8263b49b215cf3dbe43a5247a3b04ca77288fe6e7098c08af2346d9cdf7c5102ee1d1e611ce03b322e22dc3a34991aeb45d6544b27e38f113da72674d3b9341 SHA512 1e594c6a8ecfd7c92e718238f036f95c0706a70699b9836ba4ca3b6b033db1b36a08ef4778e6615cfd0cfcaec120063a67c642734c45d71aee86b17a5de4b647

diff --git a/gnome-extra/nm-applet/nm-applet-1.28.0.ebuild b/gnome-extra/nm-applet/nm-applet-1.28.0.ebuild
new file mode 100644
index 000000000000..52c9d5df3847
--- /dev/null
+++ b/gnome-extra/nm-applet/nm-applet-1.28.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome.org meson xdg
+
+DESCRIPTION="NetworkManager connection editor and applet"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="appindicator modemmanager selinux teamd"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=app-crypt/libsecret-0.18
+	>=net-libs/libnma-1.8.27
+	>=x11-libs/gtk+-3.10:3
+	>=dev-libs/libgudev-147:=
+	>=x11-libs/libnotify-0.7.0
+	>=net-misc/networkmanager-1.16:=[modemmanager?,teamd?]
+	appindicator? (
+		dev-libs/libappindicator:3
+		>=dev-libs/libdbusmenu-16.04.0
+	)
+	modemmanager? ( net-misc/modemmanager )
+	selinux? ( sys-libs/libselinux )
+	teamd? ( >=dev-libs/jansson-2.7:= )
+
+	virtual/freedesktop-icon-theme
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dappindicator=$(usex appindicator ubuntu no)
+		$(meson_use modemmanager wwan)
+		$(meson_use selinux)
+		$(meson_use teamd team)
+		-Dmore_asserts=0
+		-Dld_gc=false
+	)
+	meson_src_configure
+}