[gentoo-commits] gentoo-x86 commit in x11-terms/rxvt-unicode: rxvt-unicode-9.07.ebuild ChangeLog

[Alex Alexander (wired)]

wired       09/12/31 00:45:14

  Modified:             ChangeLog
  Added:                rxvt-unicode-9.07.ebuild
  Log:
  [rxvt-unicode] version bump, bug #298952
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.145                x11-terms/rxvt-unicode/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?r1=1.144&r2=1.145

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -u -r1.144 -r1.145
--- ChangeLog	13 Dec 2009 15:35:05 -0000	1.144
+++ ChangeLog	31 Dec 2009 00:45:14 -0000	1.145
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/rxvt-unicode
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v 1.144 2009/12/13 15:35:05 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v 1.145 2009/12/31 00:45:14 wired Exp $
+
+*rxvt-unicode-9.07 (31 Dec 2009)
+
+  31 Dec 2009; Alex Alexander <wired@g.o> +rxvt-unicode-9.07.ebuild:
+  version bump, bug #298952
 
   13 Dec 2009; Brent Baude <ranger@g.o> rxvt-unicode-9.05-r3.ebuild:
   Marking rxvt-unicode-9.05-r3 ppc64 for bug 260199



1.1                  x11-terms/rxvt-unicode/rxvt-unicode-9.07.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.07.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.07.ebuild?rev=1.1&content-type=text/plain

Index: rxvt-unicode-9.07.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.07.ebuild,v 1.1 2009/12/31 00:45:14 wired Exp $

EAPI="2"

inherit autotools flag-o-matic

DESCRIPTION="rxvt clone with xft and unicode support"
HOMEPAGE="http://software.schmorp.de/pkg/rxvt-unicode.html"
SRC_URI="http://dist.schmorp.de/rxvt-unicode/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="truetype perl iso14755 afterimage xterm-color wcwidth +vanilla"

# see bug #115992 for modular x deps
RDEPEND="x11-libs/libX11
	x11-libs/libXft
	afterimage? ( media-libs/libafterimage )
	x11-libs/libXrender
	perl? ( dev-lang/perl )
	>=sys-libs/ncurses-5.7-r3"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xproto"

src_prepare() {
	if (use xterm-color || use wcwidth); then
		ewarn "You enabled xterm-color or wcwidth or both."
		ewarn "Please note that neither of them are supported by upstream."
		ewarn "You are at your own if you run into problems."
		ebeep 5
	fi

	local tdir=/usr/share/terminfo
	if use xterm-color; then
		epatch doc/urxvt-8.2-256color.patch
		sed -e \
			's/^\(rxvt-unicode\)/\1256/;s/colors#88/colors#256/;s/pairs#256/pairs#32767/' \
			doc/etc/rxvt-unicode.terminfo > doc/etc/rxvt-unicode256.terminfo
		sed -i -e \
			"s~^\(\s\+@TIC@.*\)~\1\n\t@TIC@ -o "${D}"/${tdir} \$(srcdir)/etc/rxvt-unicode256.terminfo~" \
			doc/Makefile.in
	fi

	# kill the rxvt-unicode terminfo file - #192083
	sed -i -e "/rxvt-unicode.terminfo/d" doc/Makefile.in ||
		die "sed failed"

	use wcwidth && epatch doc/wcwidth.patch

	# bug #240165
	epatch "${FILESDIR}"/${PN}-9.06-no-urgency-if-focused.diff

	# ncurses will provide rxvt-unicode terminfo, so we don't install them again
	# see bug #192083
	#
	# According to my tests this is not (yet?) true, so keep it prepared and
	# disabled  until it's needed again.
	#if has_version '<sys-libs/ncurses-5.7'; then
	sed -i -e \
		"s~@TIC@ \(\$(srcdir)/etc/rxvt\)~@TIC@ -o "${D}"/${tdir} \1~" \
		doc/Makefile.in
	#else
	#	# Remove everything except if we have rxvt-unicode256
	#	sed -i -e \
	#		'/rxvt-unicode256/p;/@TIC@/d' \
	#		doc/Makefile.in
	#fi

	# bug #263638
	epatch "${FILESDIR}"/${PN}-9.06-popups-hangs.patch

	# bug #237271
	if ! use vanilla; then
		ewarn "You are going to include third-party bug fixes/features."
		ewarn "They came without any warranty and are not supported by the"
		ewarn "Gentoo community."
		ebeep 5
		epatch "${FILESDIR}"/${PN}-9.05_no-MOTIF-WM-INFO.patch
	fi

	eautoreconf
}

src_configure() {
	local myconf=''

	use iso14755 || myconf='--disable-iso14755'
	use xterm-color && myconf="$myconf --enable-xterm-colors=256"

	econf --enable-everything \
		$(use_enable truetype xft) \
		$(use_enable afterimage) \
		$(use_enable perl) \
		--disable-text-blink \
		${myconf}
}

src_compile() {
	emake || die

	sed -i \
		-e 's/RXVT_BASENAME = "rxvt"/RXVT_BASENAME = "urxvt"/' \
		"${S}"/doc/rxvt-tabbed || die "tabs sed failed"
}

src_install() {
	make DESTDIR="${D}" install || die

	dodoc README.FAQ Changes
	cd "${S}"/doc
	dodoc README* changes.txt etc/* rxvt-tabbed
}

pkg_postinst() {
	einfo "urxvt now always uses TERM=rxvt-unicode so that the"
	einfo "upstream-supplied terminfo files can be used."
}