[gentoo-commits] gentoo-x86 commit in sys-cluster/ceph: ceph-0.80.1.ebuild ceph-9999.ebuild ChangeLog metadata.xml ceph-0.79.ebuild

[Yixun Lan (dlan)]

dlan        14/05/21 07:43:24

  Modified:             ceph-9999.ebuild ChangeLog metadata.xml
  Added:                ceph-0.80.1.ebuild
  Removed:              ceph-0.79.ebuild
  Log:
  version bump 0.80.1, fix bug #510396, #507956, thanks @babykart, @Changyuan Yu, @LeeL
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

Revision  Changes    Path
1.10                 sys-cluster/ceph/ceph-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild?r1=1.9&r2=1.10

Index: ceph-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ceph-9999.ebuild	17 Apr 2014 23:51:20 -0000	1.9
+++ ceph-9999.ebuild	21 May 2014 07:43:23 -0000	1.10
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild,v 1.9 2014/04/17 23:51:20 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild,v 1.10 2014/05/21 07:43:23 dlan Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python{2_6,2_7} )
@@ -24,7 +24,7 @@
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="cryptopp debug fuse gtk libatomic +libaio libxfs libzfs +nss radosgw static-libs tcmalloc"
+IUSE="cryptopp debug fuse gtk libatomic +libaio +nss radosgw static-libs tcmalloc xfs zfs"
 
 CDEPEND="
 	app-arch/snappy
@@ -40,8 +40,8 @@
 	dev-libs/libxml2
 	fuse? ( sys-fs/fuse )
 	libatomic? ( dev-libs/libatomic_ops )
-	libxfs? ( sys-fs/xfsprogs )
-	libzfs? ( sys-fs/zfs )
+	xfs? ( sys-fs/xfsprogs )
+	zfs? ( sys-fs/zfs )
 	gtk? (
 		x11-libs/gtk+:2
 		dev-cpp/gtkmm:2.4
@@ -79,9 +79,6 @@
 src_prepare() {
 	[[ ${PATCHES[@]} ]] && epatch "${PATCHES[@]}"
 
-	sed -e "/bin=/ s:lib:$(get_libdir):" "${FILESDIR}"/${PN}.initd \
-		> "${T}"/${PN}.initd || die
-
 	epatch_user
 	eautoreconf
 }
@@ -101,8 +98,8 @@
 		$(use_with gtk gtk2) \
 		$(use_enable static-libs static) \
 		$(use_with tcmalloc) \
-		$(use_with libxfs) \
-		$(use_with libzfs)
+		$(use_with xfs libxfs) \
+		$(use_with zfs libzfs)
 }
 
 src_install() {
@@ -114,7 +111,7 @@
 	newexe src/init-ceph ceph_init.sh
 
 	insinto /etc/logrotate.d/
-	newins src/logrotate.conf ${PN}
+	newins "${FILESDIR}"/ceph.logrotate ${PN}
 
 	chmod 644 "${ED}"/usr/share/doc/${PF}/sample.*
 
@@ -122,8 +119,8 @@
 	keepdir /var/lib/${PN}/tmp
 	keepdir /var/log/${PN}/stat
 
-	newinitd "${T}/${PN}.initd" ${PN}
-	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+	newinitd "${FILESDIR}/${PN}.initd-r1" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd-r1" ${PN}
 
 	_python_rewrite_shebang \
 		"${ED}"/usr/sbin/{ceph-disk,ceph-create-keys} \
@@ -139,4 +136,12 @@
 	elog " sys-block/parted		to manage disk partions"
 	elog " sys-fs/btrfs-progs	to use btrfs filesytem"
 	elog " sys-fs/cryptsetup	to use encrypted devices with dm-crypt"
+	elog ""
+	elog "To have many daemons of one type, create your own script:"
+	elog ""
+	elog "cd /etc/init.d"
+	elog "for dmn in mds.a mon.a osd.0 osd.1 osd.2; do"
+	elog "  ln -s ceph ceph-${dmn};"
+	elog "  rc-update add ceph-${dmn} default;"
+	elog "done"
 }



1.50                 sys-cluster/ceph/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	17 Apr 2014 23:51:20 -0000	1.49
+++ ChangeLog	21 May 2014 07:43:24 -0000	1.50
@@ -1,6 +1,14 @@
 # ChangeLog for sys-cluster/ceph
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.49 2014/04/17 23:51:20 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.50 2014/05/21 07:43:24 dlan Exp $
+
+*ceph-0.80.1 (21 May 2014)
+
+  21 May 2014; Yixun Lan <dlan@g.o> -ceph-0.79.ebuild,
+  +ceph-0.80.1.ebuild, ceph-9999.ebuild, +files/ceph.confd-r1,
+  +files/ceph.initd-r1, +files/ceph.logrotate, metadata.xml:
+  version bump 0.80.1, fix bug #510396, #507956, thanks @babykart, @Changyuan
+  Yu, @LeeL
 
 *ceph-0.79 (17 Apr 2014)
 



1.5                  sys-cluster/ceph/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/ceph/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	17 Apr 2014 23:51:20 -0000	1.4
+++ metadata.xml	21 May 2014 07:43:24 -0000	1.5
@@ -15,9 +15,9 @@
 	<flag name='fuse'>Build fuse client</flag>
 	<flag name='libatomic'>Use libatomic instead of builtin atomic operations</flag>
 	<flag name='libaio'>Use libaio as asynchronous input/output library</flag>
-	<flag name='libxfs'>Add xfs support</flag>
-	<flag name='libzfs'>Add zfs support</flag>
 	<flag name='nss'>Use <pkg>dev-libs/nss</pkg> for cryptography</flag>
 	<flag name='radosgw'>Add radosgw support</flag>
+	<flag name='xfs'>Add xfs support</flag>
+	<flag name='zfs'>Add zfs support</flag>
 </use>
 </pkgmetadata>



1.1                  sys-cluster/ceph/ceph-0.80.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-0.80.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-0.80.1.ebuild?rev=1.1&content-type=text/plain

Index: ceph-0.80.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.80.1.ebuild,v 1.1 2014/05/21 07:43:23 dlan Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

if [[ $PV = *9999* ]]; then
	scm_eclass=git-r3
	EGIT_REPO_URI="
		git://github.com/ceph/ceph.git
		https://github.com/ceph/ceph.git"
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://ceph.com/download/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86"
fi

inherit autotools eutils multilib python-any-r1 udev ${scm_eclass}

DESCRIPTION="Ceph distributed filesystem"
HOMEPAGE="http://ceph.com/"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="cryptopp debug fuse gtk libatomic +libaio +nss radosgw static-libs tcmalloc xfs zfs"

CDEPEND="
	app-arch/snappy
	dev-libs/boost:=[threads]
	dev-libs/fcgi
	dev-libs/libaio
	dev-libs/libedit
	dev-libs/leveldb[snappy]
	nss? ( dev-libs/nss )
	cryptopp? ( dev-libs/crypto++ )
	sys-apps/keyutils
	sys-apps/util-linux
	dev-libs/libxml2
	fuse? ( sys-fs/fuse )
	libatomic? ( dev-libs/libatomic_ops )
	xfs? ( sys-fs/xfsprogs )
	zfs? ( sys-fs/zfs )
	gtk? (
		x11-libs/gtk+:2
		dev-cpp/gtkmm:2.4
		gnome-base/librsvg
	)
	radosgw? (
		dev-libs/fcgi
		dev-libs/expat
		net-misc/curl
	)
	tcmalloc? ( dev-util/google-perftools )
	$(python_gen_any_dep '
	virtual/python-argparse[${PYTHON_USEDEP}]
	' )
	${PYTHON_DEPS}
	"
DEPEND="${CDEPEND}
	virtual/pkgconfig"
RDEPEND="${CDEPEND}
	sys-apps/hdparm
	$(python_gen_any_dep '
	dev-python/flask[${PYTHON_USEDEP}]
	dev-python/requests[${PYTHON_USEDEP}]
	' )"
REQUIRED_USE="
	^^ ( nss cryptopp )
	"

STRIP_MASK="/usr/lib*/rados-classes/*"

PATCHES=(
	"${FILESDIR}"/${PN}-fix-gnustack.patch
	"${FILESDIR}"/${PN}-0.79-libzfs.patch
)

pkg_setup() {
	python-any-r1_pkg_setup
}

src_prepare() {
	[[ ${PATCHES[@]} ]] && epatch "${PATCHES[@]}"

	epatch_user
	eautoreconf
}

src_configure() {
	econf \
		--without-hadoop \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--includedir=/usr/include \
		$(use_with debug) \
		$(use_with fuse) \
		$(use_with libaio) \
		$(use_with libatomic libatomic-ops) \
		$(use_with nss) \
		$(use_with cryptopp) \
		$(use_with radosgw) \
		$(use_with gtk gtk2) \
		$(use_enable static-libs static) \
		$(use_with tcmalloc) \
		$(use_with xfs libxfs) \
		$(use_with zfs libzfs)
}

src_install() {
	default

	prune_libtool_files --all

	exeinto /usr/$(get_libdir)/ceph
	newexe src/init-ceph ceph_init.sh

	insinto /etc/logrotate.d/
	newins "${FILESDIR}"/ceph.logrotate ${PN}

	chmod 644 "${ED}"/usr/share/doc/${PF}/sample.*

	keepdir /var/lib/${PN}
	keepdir /var/lib/${PN}/tmp
	keepdir /var/log/${PN}/stat

	newinitd "${FILESDIR}/${PN}.initd-r1" ${PN}
	newconfd "${FILESDIR}/${PN}.confd-r1" ${PN}

	_python_rewrite_shebang \
		"${ED}"/usr/sbin/{ceph-disk,ceph-create-keys} \
		"${ED}"/usr/bin/{ceph,ceph-rest-api}

	#install udev rules
	udev_dorules udev/50-rbd.rules
	udev_dorules udev/95-ceph-osd.rules
}

pkg_postinst() {
	elog "We suggest to install following packages"
	elog " sys-block/parted		to manage disk partions"
	elog " sys-fs/btrfs-progs	to use btrfs filesytem"
	elog " sys-fs/cryptsetup	to use encrypted devices with dm-crypt"
	elog ""
	elog "To have many daemons of one type, create your own script:"
	elog ""
	elog "cd /etc/init.d"
	elog "for dmn in mds.a mon.a osd.0 osd.1 osd.2; do"
	elog "  ln -s ceph ceph-${dmn};"
	elog "  rc-update add ceph-${dmn} default;"
	elog "done"
}