[gentoo-commits] repo/gentoo:master commit in: net-mail/cyrus-imapd/, net-mail/cyrus-imapd/files/

[Eray Aslan]

commit:     5a962760019eb9bfd19f0d3c01fc4d13d8b82bd8
Author:     Eray Aslan <eras <AT> gentoo <DOT> org>
AuthorDate: Tue May  9 09:44:47 2017 +0000
Commit:     Eray Aslan <eras <AT> gentoo <DOT> org>
CommitDate: Tue May  9 09:44:47 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a962760

net-mail/cyrus-imapd: fix underlinking for sieve perl module

Thanks to Maciej S. Szmigiero for the patch. Bug 604470

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 net-mail/cyrus-imapd/cyrus-imapd-2.5.11-r1.ebuild  | 180 +++++++++++++++++++++
 .../cyrus-imapd/files/cyrus-imapd-sieve-libs.patch |  43 +++++
 2 files changed, 223 insertions(+)

diff --git a/net-mail/cyrus-imapd/cyrus-imapd-2.5.11-r1.ebuild b/net-mail/cyrus-imapd/cyrus-imapd-2.5.11-r1.ebuild
new file mode 100644
index 00000000000..cbe96037773
--- /dev/null
+++ b/net-mail/cyrus-imapd/cyrus-imapd-2.5.11-r1.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools multilib pam ssl-cert user toolchain-funcs
+
+MY_P=${P/_/}
+
+DESCRIPTION="The Cyrus IMAP Server"
+HOMEPAGE="http://www.cyrusimap.org/"
+SRC_URI="ftp://ftp.cyrusimap.org/cyrus-imapd/${MY_P}.tar.gz"
+
+LICENSE="BSD-with-attribution"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="afs berkdb clamav http kerberos mysql nntp pam perl postgres \
+	replication +server sieve snmp sqlite ssl static-libs tcpd"
+
+# virtual/mysql-5.5 added for the --variable= option below
+DEPEND="sys-libs/zlib
+	dev-libs/libpcre
+	>=dev-libs/cyrus-sasl-2.1.13
+	dev-libs/jansson
+	afs? ( net-fs/openafs )
+	berkdb? ( >=sys-libs/db-3.2:* )
+	clamav? ( app-antivirus/clamav )
+	http? ( dev-libs/libxml2 dev-libs/libical )
+	kerberos? ( virtual/krb5 )
+	mysql? ( >=virtual/mysql-5.5 )
+	nntp? ( !net-nntp/leafnode )
+	pam? (
+			virtual/pam
+			>=net-mail/mailbase-1
+		)
+	perl? ( dev-lang/perl:= )
+	postgres? ( dev-db/postgresql:* )
+	snmp? ( >=net-analyzer/net-snmp-5.2.2-r1 )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( >=dev-libs/openssl-1.0.1e:0[-bindist] )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 snmp? ( net-analyzer/net-snmp[tcpd=] ) )"
+
+# all blockers really needed?
+RDEPEND="${DEPEND}
+	!mail-mta/courier
+	!net-mail/bincimap
+	!net-mail/courier-imap
+	!net-mail/uw-imap
+	!net-mail/cyrus-imap-admin"
+
+REQUIRED_USE="afs? ( kerberos )
+	http? ( sqlite )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	enewuser cyrus -1 -1 /usr/cyrus mail
+}
+
+src_prepare() {
+	eapply -p0 "${FILESDIR}/${PN}-db.patch"
+	# bug 604470
+	eapply -p1 "${FILESDIR}/${PN}-sieve-libs.patch"
+	# Fix master(8)->cyrusmaster(8) manpage.
+	for i in `grep -rl -e 'master\.8' -e 'master(8)' "${S}"` ; do
+		sed -i -e 's:master\.8:cyrusmaster.8:g' \
+			-e 's:master(8):cyrusmaster(8):g' \
+			"${i}" || die "sed failed" || die "sed failed"
+	done
+	mv man/master.8 man/cyrusmaster.8 || die "mv failed"
+	sed -i -e "s:MASTER:CYRUSMASTER:g" \
+		-e "s:Master:Cyrusmaster:g" \
+		-e "s:master:cyrusmaster:g" \
+		man/cyrusmaster.8 || die "sed failed"
+
+	# lock.h to afs/lock.h
+	sed -i -e '/lock.h/s:lock.h:afs/lock.h:' \
+		ptclient/afskrb.c || die
+
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	if use afs ; then
+		myconf+=" --with-afs-libdir=/usr/$(get_libdir)"
+		myconf+=" --with-afs-incdir=/usr/include/afs"
+	fi
+	econf \
+		--enable-murder \
+		--enable-netscapehack \
+		--enable-idled \
+		--enable-event-notification \
+		--enable-autocreate \
+		--enable-pcre \
+		--with-service-path=/usr/$(get_libdir)/cyrus \
+		--with-cyrus-user=cyrus \
+		--with-cyrus-group=mail \
+		--with-com_err=yes \
+		--with-sasl \
+		--without-krb \
+		--without-krbdes \
+		--with-zlib \
+		$(use_enable afs) \
+		$(use_enable afs krb5afspts) \
+		$(use_with berkdb bdb) \
+		$(use_with clamav) \
+		$(use_enable nntp) \
+		$(use_enable http) \
+		$(use_enable replication) \
+		$(use_enable kerberos gssapi) \
+		$(use_with mysql) \
+		$(use_with postgres pgsql) \
+		$(use_with perl) \
+		$(use_with sqlite) \
+		$(use_with ssl openssl) \
+		$(use_enable server) \
+		$(use_enable sieve) \
+		$(use_with snmp) \
+		$(use_enable static-libs static) \
+		$(use_with tcpd libwrap) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALLDIRS=vendor install
+
+	dodoc README*
+	dodoc -r doc
+	cp doc/cyrusv2.mc "${D}/usr/share/doc/${PF}/html"
+	cp -r contrib tools "${D}/usr/share/doc/${PF}"
+	rm -f doc/text/Makefile*
+
+	insinto /etc
+	doins "${FILESDIR}/cyrus.conf" "${FILESDIR}/imapd.conf"
+
+	# turn off sieve if not installed
+	if ! use sieve; then
+		sed -i -e "/sieve/s/^/#/" "${D}/etc/cyrus.conf" || die
+	fi
+
+	newinitd "${FILESDIR}/cyrus.rc6" cyrus
+	newconfd "${FILESDIR}/cyrus.confd" cyrus
+	newpamd "${FILESDIR}/cyrus.pam-include" sieve
+
+	for subdir in imap/{,db,log,msg,proc,socket,sieve} spool/imap/{,stage.} ; do
+		keepdir "/var/${subdir}"
+		fowners cyrus:mail "/var/${subdir}"
+		fperms 0750 "/var/${subdir}"
+	done
+	for subdir in imap/{user,quota,sieve} spool/imap ; do
+		for i in a b c d e f g h i j k l m n o p q r s t v u w x y z ; do
+			keepdir "/var/${subdir}/${i}"
+			fowners cyrus:mail "/var/${subdir}/${i}"
+			fperms 0750 "/var/${subdir}/${i}"
+		done
+	done
+}
+
+pkg_preinst() {
+	if ! has_version ${CATEGORY}/${PN} ; then
+		elog "For correct logging add the following to /etc/syslog.conf:"
+		elog "    local6.*         /var/log/imapd.log"
+		elog "    auth.debug       /var/log/auth.log"
+		echo
+
+		elog "You have to add user cyrus to the sasldb2. Do this with:"
+		elog "    saslpasswd2 cyrus"
+	fi
+}
+
+pkg_postinst() {
+	# do not install server.{key,pem) if they exist.
+	if use ssl ; then
+		if [ ! -f "${ROOT}"etc/ssl/cyrus/server.key ]; then
+			install_cert /etc/ssl/cyrus/server
+			chown cyrus:mail "${ROOT}"etc/ssl/cyrus/server.{key,pem}
+		fi
+	fi
+}

diff --git a/net-mail/cyrus-imapd/files/cyrus-imapd-sieve-libs.patch b/net-mail/cyrus-imapd/files/cyrus-imapd-sieve-libs.patch
new file mode 100644
index 00000000000..0bfdc1d3155
--- /dev/null
+++ b/net-mail/cyrus-imapd/files/cyrus-imapd-sieve-libs.patch
@@ -0,0 +1,43 @@
+--- a/configure.ac	2016-10-17 23:01:04.000000000 +0200
++++ b/configure.ac	2016-12-28 02:42:37.936610002 +0100
+@@ -400,6 +379,7 @@
+   fi
+ 
+   LIBS="${LIBS} ${SQLITE_LIBADD}"
++  AC_SUBST(SQLITE_LIBADD)
+   CPPFLAGS="${SQLITE_INCADD} ${CPPFLAGS}"
+ 
+   AC_DEFINE(HAVE_SQLITE,[],[Build in SQLite support?])
+@@ -437,7 +416,9 @@
+ 	fi
+ 
+ 	if test "$cyrus_cv_pcre_utf8" = "yes"; then
+-		LIBS="$LIBS -lpcre -lpcreposix";
++		PCRE_LIBS="-lpcre -lpcreposix"
++		AC_SUBST(PCRE_LIBS)
++		LIBS="$LIBS $PCRE_LIBS"
+ 		AC_DEFINE(ENABLE_REGEX, [], [Do we have a regex library?])
+ 		AC_DEFINE(HAVE_PCREPOSIX_H, [], [Do we have usable pcre library?])
+ 	else
+--- a/perl/imap/Makefile.PL.in	2016-10-17 23:01:04.000000000 +0200
++++ b/perl/imap/Makefile.PL.in	2016-12-28 02:42:04.559449967 +0100
+@@ -69,7 +69,7 @@
+     'clean'	=> {'FILES' => 'libcyrperl.a cyradm'},
+     'OBJECT'    => 'IMAP.o',
+     'MYEXTLIB'  => '@top_builddir@/perl/.libs/libcyrus.a @top_builddir@/perl/.libs/libcyrus_min.a',
+-    'LIBS'	=> [ "@BDB_LIB@ $LIB_SASL @SSL_LIBS@ @LIB_RT@ @LIB_UUID@ @ZLIB@"],
++    'LIBS'	=> [ "@BDB_LIB@ $LIB_SASL @SSL_LIBS@ @LIB_RT@ @LIB_UUID@ @ZLIB@ @PCRE_LIBS@ @SQLITE_LIBADD@"],
+     'DEFINE'	=> '-DPERL_POLLUTE',    # e.g., '-DHAVE_SOMETHING' 
+     'INC'	=> "@BDB_INC@ -I@top_srcdir@ -I@top_srcdir@/com_err/et @SASLFLAGS@ @SSL_CPPFLAGS@ -I@top_srcdir@/perl/imap", 
+     'EXE_FILES' => [cyradm],
+--- a/perl/sieve/managesieve/Makefile.PL.in	2016-10-17 23:01:04.000000000 +0200
++++ b/perl/sieve/managesieve/Makefile.PL.in	2016-12-28 02:42:34.496490437 +0100
+@@ -52,7 +52,7 @@
+     'ABSTRACT'  => 'Cyrus Sieve management interface',
+     'VERSION_FROM' => "@top_srcdir@/perl/sieve/managesieve/managesieve.pm", # finds $VERSION
+     'MYEXTLIB'  => '../lib/libisieve.a @top_builddir@/perl/.libs/libcyrus.a @top_builddir@/perl/.libs/libcyrus_min.a',
+-    'LIBS'	=> ["@BDB_LIB@ $LIB_SASL @SSL_LIBS@ @LIB_RT@ @LIB_UUID@ @ZLIB@"],
++    'LIBS'	=> ["@BDB_LIB@ $LIB_SASL @SSL_LIBS@ @LIB_RT@ @LIB_UUID@ @ZLIB@ @PCRE_LIBS@ @SQLITE_LIBADD@"],
+     'CCFLAGS'	=> '@COV_CFLAGS@',
+     'DEFINE'	=> '-DPERL_POLLUTE',     # e.g., '-DHAVE_SOMETHING' 
+     'INC'	=> "@BDB_INC@ -I@top_srcdir@/lib -I@top_srcdir@/perl/sieve/lib @SASLFLAGS@ @SSL_CPPFLAGS@",