[gentoo-commits] gentoo-x86 commit in media-sound/rhythmbox: metadata.xml ChangeLog rhythmbox-0.12.4.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/09/06 11:43:41

  Modified:             metadata.xml ChangeLog
  Added:                rhythmbox-0.12.4.ebuild
  Log:
  Version bump. New Gudev code replacing hal for hardware detection, build and crash fixes. Translation updates.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  media-sound/rhythmbox/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	18 Jul 2009 10:13:22 -0000	1.7
+++ metadata.xml	6 Sep 2009 11:43:41 -0000	1.8
@@ -6,5 +6,7 @@
   <use>
     <flag name="daap">Enable support for local network music sharing via daap</flag>
 	<flag name="brasero">Enable CD burning via <pkg>app-cdr/brasero</pkg> rather than <pkg>gnome-extra/nautilus-cd-burner</pkg></flag>
+	<flag name="udev">Enable hardware detection via <pkg>sys-fs/udev</pkg>
+	replacing the deprecated <pkg>sys-apps/hal</pkg> code.</flag>
   </use>
 </pkgmetadata>



1.158                media-sound/rhythmbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/ChangeLog?rev=1.158&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/ChangeLog?rev=1.158&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/ChangeLog?r1=1.157&r2=1.158

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v
retrieving revision 1.157
retrieving revision 1.158
diff -u -r1.157 -r1.158
--- ChangeLog	24 Aug 2009 22:05:35 -0000	1.157
+++ ChangeLog	6 Sep 2009 11:43:41 -0000	1.158
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/rhythmbox
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.157 2009/08/24 22:05:35 mrpouet Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.158 2009/09/06 11:43:41 eva Exp $
+
+*rhythmbox-0.12.4 (06 Sep 2009)
+
+  06 Sep 2009; Gilles Dartiguelongue <eva@g.o>
+  +rhythmbox-0.12.4.ebuild, metadata.xml:
+  Version bump. New Gudev code replacing hal for hardware detection, build
+  and crash fixes. Translation updates.
 
   24 Aug 2009; Romain Perier <mrpouet@g.o>
   rhythmbox-0.12.3-r2.ebuild:



1.1                  media-sound/rhythmbox/rhythmbox-0.12.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/rhythmbox-0.12.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rhythmbox/rhythmbox-0.12.4.ebuild?rev=1.1&content-type=text/plain

Index: rhythmbox-0.12.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/rhythmbox-0.12.4.ebuild,v 1.1 2009/09/06 11:43:41 eva Exp $

EAPI="2"
WANT_AUTOMAKE="1.10"

inherit eutils gnome2 python multilib virtualx

DESCRIPTION="Music management and playback software for GNOME"
HOMEPAGE="http://www.rhythmbox.org/"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+brasero cdr daap doc gnome-keyring hal ipod libnotify lirc musicbrainz mtp nsplugin python test udev"

# FIXME: double check what to do with fm-radio plugin
# TODO: watchout for udev use flag changes

SLOT="0"

COMMON_DEPEND=">=dev-libs/glib-2.16.0
	>=x11-libs/gtk+-2.16
	>=dev-libs/dbus-glib-0.71
	>=dev-libs/totem-pl-parser-2.26.0
	>=gnome-base/gconf-2
	>=gnome-extra/gnome-media-2.14.0
	>=net-libs/libsoup-2.26:2.4[gnome]

	>=media-libs/gst-plugins-base-0.10.20
	|| (
		>=media-libs/gst-plugins-base-0.10.24
		>=media-libs/gst-plugins-bad-0.10.6 )

	cdr? (
		brasero? ( >=app-cdr/brasero-0.9.1 )
		!brasero? ( >=gnome-extra/nautilus-cd-burner-2.21.6 ) )
	daap? ( >=net-dns/avahi-0.6 )
	gnome-keyring? ( >=gnome-base/gnome-keyring-0.4.9 )
	udev? (
		ipod? ( >=media-libs/libgpod-0.6 )
		mtp? ( >=media-libs/libmtp-0.3.0 )
		>=sys-fs/udev-145[extras] )
	hal? (
		ipod? ( >=media-libs/libgpod-0.6 )
		mtp? ( >=media-libs/libmtp-0.3.0 )
		>=sys-apps/hal-0.5 )
	libnotify? ( >=x11-libs/libnotify-0.4.1 )
	lirc? ( app-misc/lirc )
	musicbrainz? ( media-libs/musicbrainz:3 )
	python? (
		>=dev-lang/python-2.4.2
		|| (
			>=dev-lang/python-2.5
			dev-python/celementtree )
		>=dev-python/pygtk-2.8
		>=dev-python/gnome-vfs-python-2.22.0
		>=dev-python/gconf-python-2.22.0
		>=dev-python/libgnome-python-2.22.0
		>=dev-python/gst-python-0.10.8 )"

RDEPEND="${COMMON_DEPEND}
	>=media-plugins/gst-plugins-soup-0.10
	>=media-plugins/gst-plugins-libmms-0.10
	|| (
		>=media-plugins/gst-plugins-cdparanoia-0.10
		>=media-plugins/gst-plugins-cdio-0.10 )
	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
	>=media-plugins/gst-plugins-taglib-0.10.6
	nsplugin? ( || (
		net-libs/xulrunner
		www-client/seamonkey
		www-client/mozilla-firefox ) )"

# gtk-doc-am needed for eautoreconf
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.40
	app-text/scrollkeeper
	app-text/gnome-doc-utils
	doc? ( >=dev-util/gtk-doc-1.4 )
	test? ( dev-libs/check )"

DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
	  MAINTAINERS MAINTAINERS.old NEWS README THANKS"

pkg_setup() {
	if ! use hal && ! use udev; then
		if use ipod; then
			ewarn "ipod support requires hal or udev support.  Please"
			ewarn "re-emerge with USE=udev to enable ipod support"
		fi

		if use mtp; then
			ewarn "MTP support requires hal or udev support.  Please"
			ewarn "re-emerge with USE=udev to enable MTP support"
		fi
	fi

	if use hal && use udev; then
		einfo "udev support replaces hal support completely. You can disable"
		einfo "hal on this package via /etc/portage/package.use."
	fi

	if ! use cdr ; then
		ewarn "You have cdr USE flag disabled."
		ewarn "You will not be able to play audio CDs."
	fi

	if use brasero; then
		G2CONF="${G2CONF} $(use_with cdr libbrasero-media) --without-libnautilus-burn"
	else
		G2CONF="${G2CONF} $(use_with cdr libnautilus-burn) --without-libbrasero-media"
	fi

	G2CONF="${G2CONF}
		MOZILLA_PLUGINDIR=/usr/$(get_libdir)/nsbrowser/plugins
		$(use_with gnome-keyring)
		$(use_with gudev)
		$(use_with hal)
		$(use_with ipod)
		$(use_enable libnotify)
		$(use_enable lirc)
		$(use_enable musicbrainz)
		$(use_with mtp)
		$(use_enable nsplugin browser-plugin)
		$(use_enable python)
		$(use_enable daap)
		$(use_with daap mdns avahi)
		--enable-mmkeys
		--disable-scrollkeeper
		--disable-schemas-install
		--disable-static
		--disable-vala"

	export GST_INSPECT=/bin/true
}

src_prepare() {
	gnome2_src_prepare

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile
}

src_compile() {
	addpredict "$(unset HOME; echo ~)/.gconf"
	addpredict "$(unset HOME; echo ~)/.gconfd"
	gnome2_src_compile
}

src_test() {
	unset SESSION_MANAGER
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "test failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	use python && python_mod_optimize /usr/$(get_libdir)/rhythmbox/plugins

	ewarn
	ewarn "If ${PN} doesn't play some music format, please check your"
	ewarn "USE flags on media-plugins/gst-plugins-meta"
	ewarn
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/rhythmbox/plugins
}