[gentoo-commits] repo/gentoo:master commit in: sys-apps/s390-tools/

[Mikle Kolyada]

commit:     c2c7e7257fae107de1f8401f18f2c563404b9bfc
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 18 13:14:11 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Fri Jan 18 13:14:11 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c2c7e725

sys-apps/s390-tools: EAPI bump, fix fuse slot

Closes: https://bugs.gentoo.org/673676
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 sys-apps/s390-tools/s390-tools-2.4.0-r1.ebuild | 51 ++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/sys-apps/s390-tools/s390-tools-2.4.0-r1.ebuild b/sys-apps/s390-tools/s390-tools-2.4.0-r1.ebuild
new file mode 100644
index 00000000000..e970ee55b2d
--- /dev/null
+++ b/sys-apps/s390-tools/s390-tools-2.4.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs udev
+
+DESCRIPTION="User space utilities for the zSeries (s390) Linux kernel and device drivers"
+HOMEPAGE="https://www.ibm.com/developerworks/linux/linux390/s390-tools.html"
+SRC_URI="https://github.com/ibm-s390-tools/s390-tools/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 MIT"
+SLOT="0"
+KEYWORDS="-* ~s390"
+IUSE="fuse ncurses pfm snmp zlib"
+
+RDEPEND="fuse? ( sys-fs/fuse:0= )
+	ncurses? ( sys-libs/ncurses:0= )
+	pfm? ( app-misc/pfm )
+	snmp? ( net-analyzer/net-snmp )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	dev-util/indent
+	app-admin/genromfs"
+
+src_configure() {
+	export MAKEOPTS+=" V=1"
+	export HAVE_DRACUT=0
+	export HAVE_FUSE=$(usex fuse 1 0)
+	export HAVE_NCURSES=$(usex ncurses 1 0)
+	export HAVE_SNMP=$(usex snmp 1 0)
+	export HAVE_PFM=$(usex pfm 1 0)
+	export HAVE_ZLIB=$(usex zlib 1 0)
+	tc-export AR BUILD_CC CC CXX LD NM OBJCOPY
+}
+
+src_compile() {
+	emake \
+		AR="${AR}" \
+		HOSTCC="${BUILD_CC}" \
+		CC="${CC}" LINK="${CC}" \
+		CXX="${CXX}" LINKXX="${CXX}" \
+		LD="${LD}" \
+		NM="${NM}" \
+		OBJCOPY="${OBJCOPY}"
+}
+
+src_install() {
+	default
+	udev_dorules etc/udev/rules.d/*.rules
+}