[gentoo-commits] gentoo-x86 commit in media-sound/lilypond: lilypond-9999.ebuild ChangeLog lilypond-2.17.25.ebuild

[Tim Harder (radhermit)]

radhermit    13/08/29 06:05:10

  Modified:             lilypond-9999.ebuild ChangeLog
  Added:                lilypond-2.17.25.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.4                  media-sound/lilypond/lilypond-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild?r1=1.3&r2=1.4

Index: lilypond-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- lilypond-9999.ebuild	30 May 2013 07:07:58 -0000	1.3
+++ lilypond-9999.ebuild	29 Aug 2013 06:05:10 -0000	1.4
@@ -1,9 +1,9 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild,v 1.3 2013/05/30 07:07:58 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/lilypond-9999.ebuild,v 1.4 2013/08/29 06:05:10 radhermit Exp $
 
 EAPI=5
-PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+PYTHON_COMPAT=( python{2_6,2_7} )
 
 inherit elisp-common autotools eutils git-2 python-single-r1
 



1.160                media-sound/lilypond/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/ChangeLog?rev=1.160&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/ChangeLog?rev=1.160&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/ChangeLog?r1=1.159&r2=1.160

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lilypond/ChangeLog,v
retrieving revision 1.159
retrieving revision 1.160
diff -u -r1.159 -r1.160
--- ChangeLog	16 Aug 2013 04:07:30 -0000	1.159
+++ ChangeLog	29 Aug 2013 06:05:10 -0000	1.160
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/lilypond
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/ChangeLog,v 1.159 2013/08/16 04:07:30 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/ChangeLog,v 1.160 2013/08/29 06:05:10 radhermit Exp $
+
+*lilypond-2.17.25 (29 Aug 2013)
+
+  29 Aug 2013; Tim Harder <radhermit@g.o> +lilypond-2.17.25.ebuild,
+  lilypond-9999.ebuild:
+  Version bump.
 
   16 Aug 2013; Tim Harder <radhermit@g.o> -lilypond-2.17.19.ebuild,
   -lilypond-2.17.20.ebuild, -lilypond-2.17.21.ebuild, -lilypond-2.17.22.ebuild:



1.1                  media-sound/lilypond/lilypond-2.17.25.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/lilypond-2.17.25.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lilypond/lilypond-2.17.25.ebuild?rev=1.1&content-type=text/plain

Index: lilypond-2.17.25.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/lilypond-2.17.25.ebuild,v 1.1 2013/08/29 06:05:10 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit elisp-common autotools eutils python-single-r1

DESCRIPTION="GNU Music Typesetter"
SRC_URI="http://download.linuxaudio.org/lilypond/sources/v${PV:0:4}/${P}.tar.gz"
HOMEPAGE="http://lilypond.org/"

LICENSE="GPL-3 FDL-1.3"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
LANGS=" ca cs da de el eo es fi fr it ja nl ru sv tr uk vi zh_TW"
IUSE="debug emacs profile vim-syntax ${LANGS// / linguas_}"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND=">=app-text/ghostscript-gpl-8.15
	>=dev-scheme/guile-1.8.2[deprecated,regex]
	media-fonts/urw-fonts
	media-libs/fontconfig
	media-libs/freetype:2
	>=x11-libs/pango-1.12.3
	emacs? ( virtual/emacs )
	${PYTHON_DEPS}"
DEPEND="${RDEPEND}
	app-text/t1utils
	dev-lang/perl
	dev-texlive/texlive-metapost
	virtual/pkgconfig
	media-gfx/fontforge
	>=sys-apps/texinfo-4.11
	>=sys-devel/bison-2.0
	sys-devel/flex
	sys-devel/gettext
	sys-devel/make"

# Correct output data for tests isn't bundled with releases
RESTRICT="test"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.17.2-tex-docs.patch

	if ! use vim-syntax ; then
		sed -i 's/vim//' GNUmakefile.in || die
	fi

	# respect CFLAGS
	sed -i 's/OPTIMIZE -g/OPTIMIZE/' aclocal.m4 || die

	for lang in ${LANGS}; do
		use linguas_${lang} || rm po/${lang}.po || die
	done

	# respect AR
	sed -i "s/^AR=ar/AR=$(tc-getAR)/" stepmake/stepmake/library-vars.make || die

	eautoreconf
}

src_configure() {
	# documentation generation currently not supported since it requires a newer
	# version of texi2html than is currently in the tree

	econf \
		--with-ncsb-dir=/usr/share/fonts/urw-fonts \
		--disable-documentation \
		--disable-optimising \
		--disable-pipe \
		$(use_enable debug debugging) \
		$(use_enable profile profiling)
}

src_compile() {
	default

	if use emacs ; then
		elisp-compile elisp/lilypond-{font-lock,indent,mode,what-beat}.el \
			|| die "elisp-compile failed"
	fi
}

src_install () {
	emake DESTDIR="${D}" vimdir=/usr/share/vim/vimfiles install

	# remove elisp files since they are in the wrong directory
	rm -r "${ED}"/usr/share/emacs || die

	if use emacs ; then
		elisp-install ${PN} elisp/*.{el,elc} elisp/out/*.el \
			|| die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
	fi

	python_fix_shebang "${ED}"

	dodoc AUTHORS.txt HACKING NEWS.txt README.txt
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}