[gentoo-commits] gentoo-x86 commit in sci-mathematics/pspp: pspp-0.8.1.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    13/10/30 16:21:48

  Modified:             ChangeLog
  Added:                pspp-0.8.1.ebuild
  Log:
  Version bump, patches not needed anymore, fix bug #489526, thanks cujyaz@××××××××××.com
  
  (Portage version: 2.2.7-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.25                 sci-mathematics/pspp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/pspp/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/pspp/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/pspp/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/pspp/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	10 Sep 2013 02:40:07 -0000	1.24
+++ ChangeLog	30 Oct 2013 16:21:48 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for sci-mathematics/pspp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/pspp/ChangeLog,v 1.24 2013/09/10 02:40:07 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/pspp/ChangeLog,v 1.25 2013/10/30 16:21:48 bicatali Exp $
+
+*pspp-0.8.1 (30 Oct 2013)
+
+  30 Oct 2013; Sébastien Fabbro <bicatali@g.o> +pspp-0.8.1.ebuild:
+  Version bump, patches not needed anymore, fix bug #489526, thanks
+  cujyaz@××××××××××.com
 
   10 Sep 2013; Patrick Lauer <patrick@g.o> pspp-0.8.0.ebuild:
   Whitespace



1.1                  sci-mathematics/pspp/pspp-0.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/pspp/pspp-0.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/pspp/pspp-0.8.1.ebuild?rev=1.1&content-type=text/plain

Index: pspp-0.8.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/pspp/pspp-0.8.1.ebuild,v 1.1 2013/10/30 16:21:48 bicatali Exp $

EAPI=5

AUTOTOOLS_IN_SOURCE_BUILD=1

inherit eutils elisp-common autotools-utils multilib

DESCRIPTION="Program for statistical analysis of sampled data"
HOMEPAGE="http://www.gnu.org/software/pspp/pspp.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3"

KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="cairo doc emacs examples gtk ncurses nls perl postgres static-libs"

RDEPEND="
	dev-libs/libxml2:2
	sci-libs/gsl
	sys-devel/gettext
	sys-libs/readline
	sys-libs/zlib
	virtual/libiconv
	cairo? ( x11-libs/cairo )
	emacs? ( virtual/emacs )
	gtk? ( x11-libs/gtk+:2
		   gnome-base/libglade:2.0
		   >=x11-libs/gtksourceview-2.2:2.0 )
	ncurses? ( sys-libs/ncurses )
	postgres? ( dev-db/postgresql-server )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( virtual/latex-base )"

SITEFILE=50${PN}-gentoo.el

# if autoreconf is needed, might need patch for gettext in
# https://savannah.gnu.org/bugs/index.php?39708

src_configure() {
	local myeconfargs=(
		--disable-rpath
		$(use_enable nls)
		$(use_with cairo)
		$(use_with gtk gui)
		$(use_with ncurses libncurses)
		$(use_with perl perl-module)
		$(use_with postgres libpq)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile pkglibdir="${EPREFIX}/usr/$(get_libdir)"
	use doc && emake html pdf
	use emacs && elisp-compile *.el
}

src_install() {
	autotools-utils_src_install pkglibdir="${EPREFIX}/usr/$(get_libdir)"

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi

	if use doc; then
		dohtml -r doc/pspp{,-dev}.html
		dodoc doc/pspp{,-dev}.pdf
	fi

	if use emacs; then
		elisp-install ${PN} *.el *.elc
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst () {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}