[gentoo-commits] gentoo-x86 commit in kde-base/kopete: ChangeLog kopete-4.3.1.ebuild

[Theo Chatzimichos (tampakrap)]

tampakrap    09/09/01 15:48:20

  Modified:             ChangeLog
  Added:                kopete-4.3.1.ebuild
  Log:
  Version bump KDE 4.3.1
  (Portage version: 2.2_rc38/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.211                kde-base/kopete/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	4 Aug 2009 17:17:23 -0000	1.210
+++ ChangeLog	1 Sep 2009 15:48:19 -0000	1.211
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kopete
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.210 2009/08/04 17:17:23 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.211 2009/09/01 15:48:19 tampakrap Exp $
+
+*kopete-4.3.1 (01 Sep 2009)
+
+  01 Sep 2009; Theo Chatzimichos <tampakrap@g.o>
+  +kopete-4.3.1.ebuild:
+  Version bump
 
   04 Aug 2009; Alex Alexander <wired@g.o> metadata.xml:
   added skype use desc



1.1                  kde-base/kopete/kopete-4.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/kopete-4.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kopete/kopete-4.3.1.ebuild?rev=1.1&content-type=text/plain

Index: kopete-4.3.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/kopete-4.3.1.ebuild,v 1.1 2009/09/01 15:48:19 tampakrap Exp $

EAPI="2"

KMNAME="kdenetwork"
inherit kde4-meta

DESCRIPTION="KDE multi-protocol IM client"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
IUSE="debug +handbook ssl v4l2"

# tests hang, last checked for 4.2.96
RESTRICT=test

# Available plugins
#
#	addbookmarks: NO DEPS
#	alias: NO DEPS (disabled upstream)
#	autoreplace: NO DEPS
#	contactnotes: NO DEPS
#	highlight: NO DEPS
#	history: NO DEPS
#	latex: virtual/latex as RDEPEND
#	nowlistening: NO DEPS
#	otr: libotr
#	pipes: NO DEPS
#	privacy: NO DEPS
#	statistics: dev-db/sqlite:3
#	texteffect: NO DEPS
#	translator: NO DEPS
#	urlpicpreview: NO DEPS
#	webpresence: libxml2 libxslt
# NOTE: By default we enable all plugins that don't have any dependencies
PLUGINS="+addbookmarks +autoreplace +contactnotes +highlight +history latex
+nowlistening otr +pipes +privacy +statistics +texteffect +translator
+urlpicpreview webpresence"

# Available protocols
#
#	bonjour: NO DEPS
#	gadu: net-libs/libgadu @since 4.3
#	groupwise: app-crypt/qca:2
#	irc: NO DEPS, probably will fail so inform user about it
#	jabber: net-dns/libidn app-crypt/qca:2 ENABLED BY DEFAULT NETWORK
#	jingle: media-libs/speex net-libs/ortp DISABLED BY UPSTREAM
#	meanwhile: net-libs/meanwhile
#	msn: libmsn == this is wlm plugin, we disable msn one
#	oscar: NO DEPS
#	qq: NO DEPS
#	sms: NO DEPS
#   telepathy: net-libs/decibel
#   testbed: NO DEPS
#	winpopup: NO DEPS
#	yahoo: NO DEPS
PROTOCOLS="bonjour facebook gadu groupwise +jabber meanwhile msn oscar qq
skype testbed winpopup yahoo"

# disabled protocols
#   telepathy: net-libs/decibel
#   irc: NO DEPS

IUSE="${IUSE} ${PLUGINS} ${PROTOCOLS}"

COMMONDEPEND="
	dev-libs/libpcre
	x11-libs/libXScrnSaver
	>=x11-libs/qt-gui-4.4.0:4[mng]
	gadu? ( >=net-libs/libgadu-1.8.0 )
	groupwise? ( app-crypt/qca:2 )
	jabber? (
		app-crypt/qca:2
		net-dns/libidn
	)
	meanwhile? ( net-libs/meanwhile )
	msn? ( net-libs/libmsn )
	otr? ( >=net-libs/libotr-3.2.0 )
	statistics? ( dev-db/sqlite:3 )
	webpresence? ( dev-libs/libxml2 dev-libs/libxslt )
	v4l2? ( media-libs/libv4l )
"
RDEPEND="${COMMONDEPEND}
	latex? (
		media-gfx/imagemagick
		virtual/latex-base
	)
	ssl? ( app-crypt/qca-ossl )
"
#	telepathy? ( net-libs/decibel )"
DEPEND="${COMMONDEPEND}
	x11-proto/scrnsaverproto
"
PDEPEND="
	facebook? ( net-im/kopete-facebook )
"

src_configure() {
	local x x2
	# Disable old msn support.
	mycmakeargs="${mycmakeargs} -DWITH_msn=OFF"
	# enable protocols
	for x in ${PROTOCOLS}; do
		[[ ${x/+/} = msn ]] && x2=wlm || x2=""
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_with ${x/+/} ${x2})"
	done
	# enable plugins
	for x in ${PLUGINS}; do
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_with ${x/+/})"
	done

	kde4-meta_src_configure
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	#if use telepathy; then
	#	elog "To use kopete telepathy plugins, you need to start gabble first:"
	#	elog "GABBLE_PERSIST=1 telepathy-gabble &"
	#	elog "export TELEPATHY_DATA_PATH=/usr/share/telepathy/managers/"
	#fi

	if ! use ssl; then
		if use jabber || use msn; then # || use irc; then
			echo
			elog "In order to use ssl in jabber, msn and irc you'll need to"
			elog "install app-crypt/qca-ossl package."
			echo
		fi
	fi
}