[gentoo-commits] repo/gentoo:master commit in: app-text/ghostscript-gpl/

[Andreas Hüttel]

commit:     521a0bbaf9bea07b4c977156bb5cd3efaded1bb4
Author:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 28 22:47:18 2017 +0000
Commit:     Andreas Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sat Jan 28 22:47:57 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=521a0bba

app-text/ghostscript-gpl: Revision bump adding various security patches from Fedora, bug 596576

Many thanks to dev-zero for preparing this.
It fixes CVE-2016-7976, CVE-2016-7977, CVE-2016-7978, CVE-2016-7979, CVE-2016-8602

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 app-text/ghostscript-gpl/Manifest                  |   1 +
 .../ghostscript-gpl/ghostscript-gpl-9.20-r1.ebuild | 255 +++++++++++++++++++++
 2 files changed, 256 insertions(+)

diff --git a/app-text/ghostscript-gpl/Manifest b/app-text/ghostscript-gpl/Manifest
index e7cb3af..19a95d7 100644
--- a/app-text/ghostscript-gpl/Manifest
+++ b/app-text/ghostscript-gpl/Manifest
@@ -3,4 +3,5 @@ DIST ghostscript-9.19.tar.bz2 29616270 SHA256 f67acdcfcde1f86757ff3553cd719f12ea
 DIST ghostscript-9.20.tar.xz 26387028 SHA256 3c0f3dc5df6f784850fa4ce7dcc3d6c56ef543af1fbaedd1d9f8d9f8b66de0ab SHA512 3e636f9746303f0d0fbcdfed22e8da4cc2cfd87c2afde38ffef67acb6a9fc2416aaca691d64355294e70f699bcf4acf33b09d3493dc24bc3c368387f066357fd WHIRLPOOL 0c58d8a860093ae856339839aa5012f5e47d87891fc16890cf7730979cb6506c1b686a6c1ca5dfbdcaafc614d989fec09b665d9eacc784f0dc31bca50d341f7f
 DIST ghostscript-gpl-9.12-patchset-1.tar.bz2 4940 SHA256 5c0e99a192a6d0e142c4c5f38a2d80ceeeb4a8e2265264d31360b06f3d94e0b5 SHA512 e3daf758c75ecb6a38dbece91b0f44ae06985920080b376384a9b3ad2ad35295530c144832158af2933d5fc49782c1fc6733efc60106193499c615a502f5e656 WHIRLPOOL e9436e1681e95a4b578a9de577d9b487ad119893c141baf840cd5dae0b89f5eedbde6d2f1225fb97c425a6dc3f3fb7f1ea6a02ab02b799438c3002fb933575c6
 DIST ghostscript-gpl-9.20-patchset-1.tar.xz 3048 SHA256 c61152a457d00418bea5586094b26a496f891e7150d6a1e3fe041e0d34301530 SHA512 b8b0a39d715f2c054d71710c870514af5a9494017ae35393e3c4323357d72411630de0c6ac50ea4a84a9e4537455e21742c6317b3354d5db1769fe5d39392f35 WHIRLPOOL 0ad329ff8262cc5719bc31f995381d15777a7b293573dc50ce75274a2a6809819ffe5cf4fba679333d981c136bc4f01055de797d6bfa917a7fb4708c8ebeda61
+DIST ghostscript-gpl-9.20-patchset-2.tar.xz 16696 SHA256 10172b0e1c2bf85933d568bb59f3aa7c1faf7b56b8cf3ab54dfa41e032c3490d SHA512 c62acfaae388d9ecd0d00b3b63e1e42fdc917eaf568ac65833490656d6f7261a7b8df3ba44ed50373007f48b4dd3ca9a3c528ae126307d58635200521e32ba4d WHIRLPOOL 3bf59a324f8f35764cad687da158c404f884ed639505ee5a3ca79ef90bba36b8f4e6919a40aae99947b75697d743340aa88b6a5ba1d7c0e12d17b124385347d3
 DIST gsdjvu-1.6.tar.gz 207122 SHA256 6236b14b79345eda87cce9ba22387e166e7614cca2ca86b1c6f0d611c26005df SHA512 57f3866f1f863fa31f066b45ee679cfbdf2c6a9bec922f24fa9f50dd3ea52f192b4c9889b0c9657e96ca9e3528d3fea7dcc53b4d1ea87dd49d138ce9c9684884 WHIRLPOOL 66e5222412d9da2d616ba0a3f73548d031b3e6726eff7bc60bea703b02ce4d22e100adad1faf3fabaac379b4ef8324324eabb8b5320f74ebafe929b577dd6c8d

diff --git a/app-text/ghostscript-gpl/ghostscript-gpl-9.20-r1.ebuild b/app-text/ghostscript-gpl/ghostscript-gpl-9.20-r1.ebuild
new file mode 100644
index 00000000..e90f500
--- /dev/null
+++ b/app-text/ghostscript-gpl/ghostscript-gpl-9.20-r1.ebuild
@@ -0,0 +1,255 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools multilib versionator flag-o-matic toolchain-funcs
+
+DESCRIPTION="Ghostscript is an interpreter for the PostScript language and for PDF"
+HOMEPAGE="http://ghostscript.com/"
+
+# Maintainer notes about djvu support:
+# gsdjvu has not seen any commits since July 2016, which was also roughly the time
+# when ghostscript started rearranging internals. Issues I found so far:
+# * gs_state and gs_imager_state got unified into gs_gstate
+# * decode_glyph changed arguments and semantics (it doesnt give you the unicode now,
+#   but the length of the required byte array, which you have to allocate and fill)
+# * gs_text_enum_t has lost its element pis (???)
+
+MY_P=${P/-gpl}
+# GSDJVU_PV=1.9
+PVM=$(get_version_component_range 1-2)
+PVM_S=$(replace_all_version_separators "" ${PVM})
+# SRC_URI="
+#	https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs${PVM_S}/${MY_P}.tar.xz
+#	mirror://gentoo/${PN}-9.20-patchset-1.tar.xz
+#	djvu? ( mirror://sourceforge/djvu/gsdjvu-${GSDJVU_PV}.tar.gz )"
+SRC_URI="
+	https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs${PVM_S}/${MY_P}.tar.xz
+	https://dev.gentoo.org/~dilfridge/distfiles/${PN}-9.20-patchset-2.tar.xz
+"
+
+LICENSE="AGPL-3 CPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+# IUSE="cups dbus djvu gtk idn l10n_de static-libs tiff X"
+IUSE="cups dbus gtk idn l10n_de static-libs tiff X"
+# RESTRICT="djvu? ( bindist )"
+
+COMMON_DEPEND="
+	app-text/libpaper
+	media-libs/fontconfig
+	>=media-libs/freetype-2.4.9:2=
+	media-libs/jbig2dec
+	>=media-libs/lcms-2.6:2
+	>=media-libs/libpng-1.6.2:0=
+	>=media-libs/openjpeg-2.1.0:2=
+	>=sys-libs/zlib-1.2.7:=
+	virtual/jpeg:0
+	cups? ( >=net-print/cups-1.3.8 )
+	dbus? ( sys-apps/dbus )
+	gtk? ( || ( x11-libs/gtk+:3 x11-libs/gtk+:2 ) )
+	idn? ( net-dns/libidn )
+	tiff? ( >=media-libs/tiff-4.0.1:0= )
+	X? ( x11-libs/libXt x11-libs/libXext )
+"
+#	djvu? ( app-text/djvu )
+
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/poppler-data-0.4.5-r1
+	>=media-fonts/urw-fonts-2.4.9
+	l10n_ja? ( media-fonts/kochi-substitute )
+	l10n_ko? ( media-fonts/baekmuk-fonts )
+	l10n_zh-CN? ( media-fonts/arphicfonts )
+	l10n_zh-TW? ( media-fonts/arphicfonts )
+	!!media-fonts/gnu-gs-fonts-std
+	!!media-fonts/gnu-gs-fonts-other
+	!<net-print/cups-filters-1.0.36-r2
+"
+
+S="${WORKDIR}/${MY_P}"
+
+LANGS="ja ko zh-CN zh-TW"
+for X in ${LANGS} ; do
+	IUSE="${IUSE} l10n_${X}"
+done
+
+#pkg_setup() {
+#	if use djvu; then
+#		ewarn "With USE=\"djvu\", distribution of binaries is restricted!"
+#		ewarn "See http://djvu.sourceforge.net/gsdjvu/COPYING for details on licensing issues."
+#	fi
+#}
+
+src_prepare() {
+	default
+
+	# remove internal copies of various libraries
+	rm -rf "${S}"/cups/libs || die
+	rm -rf "${S}"/expat || die
+	rm -rf "${S}"/freetype || die
+	rm -rf "${S}"/jbig2dec || die
+	rm -rf "${S}"/jpeg{,xr} || die
+	rm -rf "${S}"/lcms{,2} || die
+	rm -rf "${S}"/libpng || die
+	rm -rf "${S}"/tiff || die
+	rm -rf "${S}"/zlib || die
+	rm -rf "${S}"/openjpeg || die
+	# remove internal CMaps (CMaps from poppler-data are used instead)
+	rm -rf "${S}"/Resource/CMap || die
+
+	# apply various patches, many borrowed from Fedora
+	# http://pkgs.fedoraproject.org/cgit/ghostscript.git
+	eapply "${WORKDIR}/patches/"*.patch
+
+#	if use djvu ; then
+#		unpack gsdjvu-${GSDJVU_PV}.tar.gz
+#
+#		local gsdjvu_base=devices
+#		local gsdjvu_msed='-e s/@@djvu@@/DEV/g'
+#
+#		cp gsdjvu-${GSDJVU_PV}/gdevdjvu.c "${S}"/${gsdjvu_base} || die
+#
+#		cp gsdjvu-${GSDJVU_PV}/ps2utf8.ps "${S}"/lib || die
+#
+#		cp gsdjvu-${GSDJVU_PV}/gsdjvu "${S}" || die
+#		cp "${S}"/${gsdjvu_base}/contrib.mak "${S}"/${gsdjvu_base}/contrib.mak.gsdjvu || die
+#		grep -q djvusep "${S}"/${gsdjvu_base}/contrib.mak || \
+#			sed ${gsdjvu_msed} < gsdjvu-${GSDJVU_PV}/gsdjvu.mak >> "${S}"/${gsdjvu_base}/contrib.mak || die
+#
+##		# install ps2utf8.ps, bug #197818
+##		sed -i -e '/$(EXTRA_INIT_FILES)/ a\ps2utf8.ps \\' \
+##			"${S}"/base/unixinst.mak || die "sed failed"
+#	fi
+
+	if ! use gtk ; then
+		sed -i -e "s:\$(GSSOX)::" \
+			-e "s:.*\$(GSSOX_XENAME)$::" \
+			"${S}"/base/unix-dll.mak || die "sed failed"
+	fi
+
+	# Force the include dirs to a neutral location.
+	sed -i \
+		-e "/^ZLIBDIR=/s:=.*:=${T}:" \
+		configure.ac || die
+	# Some files depend on zlib.h directly.  Redirect them. #573248
+	# Also make sure to not define OPJ_STATIC to avoid linker errors due to
+	# hidden symbols (https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=203327#c1)
+	sed -i \
+		-e '/^zlib_h/s:=.*:=:' \
+		-e 's|-DOPJ_STATIC ||' \
+		base/lib.mak || die
+
+	# search path fix
+	# put LDFLAGS after BINDIR, bug #383447
+	sed -i -e "s:\$\(gsdatadir\)/lib:@datarootdir@/ghostscript/${PVM}/$(get_libdir):" \
+		-e "s:exdir=.*:exdir=@datarootdir@/doc/${PF}/examples:" \
+		-e "s:docdir=.*:docdir=@datarootdir@/doc/${PF}/html:" \
+		-e "s:GS_DOCDIR=.*:GS_DOCDIR=@datarootdir@/doc/${PF}/html:" \
+		-e 's:-L$(BINDIR):& $(LDFLAGS):g' \
+		"${S}"/Makefile.in "${S}"/base/*.mak || die "sed failed"
+
+	cd "${S}" || die
+	# remove incorrect symlink, bug 590384
+	rm -f ijs/ltmain.sh || die
+	eautoreconf
+
+	cd "${S}/ijs" || die
+	eautoreconf
+}
+
+src_configure() {
+	local FONTPATH
+	for path in \
+		/usr/share/fonts/urw-fonts \
+		/usr/share/fonts/Type1 \
+		/usr/share/fonts \
+		/usr/share/poppler/cMap/Adobe-CNS1 \
+		/usr/share/poppler/cMap/Adobe-GB1 \
+		/usr/share/poppler/cMap/Adobe-Japan1 \
+		/usr/share/poppler/cMap/Adobe-Japan2 \
+		/usr/share/poppler/cMap/Adobe-Korea1
+	do
+		FONTPATH="$FONTPATH${FONTPATH:+:}${EPREFIX}$path"
+	done
+
+	PKGCONFIG=$(type -P $(tc-getPKG_CONFIG)) \
+	econf \
+		--enable-dynamic \
+		--enable-freetype \
+		--enable-fontconfig \
+		--enable-openjpeg \
+		--disable-compile-inits \
+		--with-drivers=ALL \
+		--with-fontpath="$FONTPATH" \
+		--with-ijs \
+		--with-jbig2dec \
+		--with-libpaper \
+		--without-luratech \
+		$(use_enable cups) \
+		$(use_enable dbus) \
+		$(use_enable gtk) \
+		$(use_with cups pdftoraster) \
+		$(use_with idn libidn) \
+		$(use_with tiff system-libtiff) \
+		$(use_with X x)
+
+#	if use djvu ; then
+#		sed -i -e 's!$(DD)bbox.dev!& $(DD)djvumask.dev $(DD)djvusep.dev!g' \
+#			"${S}"/Makefile || die "sed failed"
+#	fi
+
+	cd "${S}/ijs" || die
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	# -j1 needed because of bug #550926
+	emake -j1 so all
+
+	cd "${S}/ijs" || die
+	emake
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install-so install
+
+#	use djvu && dobin gsdjvu
+
+	# move gsc to gs, bug #343447
+	# gsc collides with gambit, bug #253064
+	mv -f "${ED}"/usr/bin/{gsc,gs} || die
+
+	cd "${S}/ijs" || die
+	emake -j1 DESTDIR="${D}" install
+
+	# rename the original cidfmap to cidfmap.GS
+	mv "${ED}/usr/share/ghostscript/${PVM}/Resource/Init/cidfmap"{,.GS} || die
+
+	# install our own cidfmap to handle CJK fonts
+	insinto /usr/share/ghostscript/${PVM}/Resource/Init
+	doins \
+		"${WORKDIR}/fontmaps/CIDFnmap" \
+		"${WORKDIR}/fontmaps/cidfmap"
+	for X in ${LANGS} ; do
+		if use l10n_${X} ; then
+			doins "${WORKDIR}/fontmaps/cidfmap.${X/-/_}"
+		fi
+	done
+
+	# install the CMaps from poppler-data properly, bug #409361
+	dosym /usr/share/poppler/cMaps /usr/share/ghostscript/${PVM}/Resource/CMap
+
+	use static-libs || prune_libtool_files --all
+
+	if ! use l10n_de; then
+		rm -r "${ED}"/usr/share/man/de || die
+	fi
+}