[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest/

[Michał Górny]

commit:     071a60eef6915a7f72483e4e933ff83769aa229c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 29 08:45:31 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 29 08:48:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=071a60ee

dev-python/pytest: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pytest/Manifest            |   1 -
 dev-python/pytest/pytest-7.1.3.ebuild | 103 ----------------------------------
 2 files changed, 104 deletions(-)

diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index f079452bf72a..a809f17b2db6 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,2 +1 @@
-DIST pytest-7.1.3.tar.gz 1257801 BLAKE2B 39935fbfc9eb79a220324b8642e80225472a658f85fa8ef50b1dff5396dd30cfde22b2faf3909df0ba7d08ea14f548794974a7fd7670d7204e8d625ea5949630 SHA512 07a6b30fc90776dcd59972e2e4fc03ba02270bf1460faba765bfcf8b04888797be15a16a2ae947d97eb523250be200297d8a442870b3b6d56ae776b28fd18dce
 DIST pytest-7.2.0.tar.gz 1300608 BLAKE2B 051c1c28aae1b2ff97af0b6e58046d8d3ee9b72909d4c8360f7ca3b9f2ed46f24a6db2d6138d1a629ec650bf7b0a14d89b44d0779340c31b60abb8608defd30b SHA512 a16b034c8522f0aa6ee9541b07b79be713565a6e755ab0489b38c2b0a0ed9f7857c87f952ff24c199a2e4c0d71ee26e918dd06abfe994d30ac90e32ae3e8c4d1

diff --git a/dev-python/pytest/pytest-7.1.3.ebuild b/dev-python/pytest/pytest-7.1.3.ebuild
deleted file mode 100644
index dfe60173b54c..000000000000
--- a/dev-python/pytest/pytest-7.1.3.ebuild
+++ /dev/null
@@ -1,103 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_TESTED=( python3_{8..11} pypy3 )
-PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
-
-inherit distutils-r1 multiprocessing
-
-DESCRIPTION="Simple powerful testing with Python"
-HOMEPAGE="
-	https://pytest.org/
-	https://github.com/pytest-dev/pytest/
-	https://pypi.org/project/pytest/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
-	dev-python/iniconfig[${PYTHON_USEDEP}]
-	>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
-	>=dev-python/py-1.8.2[${PYTHON_USEDEP}]
-	>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/setuptools_scm-6.2.3[${PYTHON_USEDEP}]
-	test? (
-		${RDEPEND}
-		$(python_gen_cond_dep '
-			dev-python/argcomplete[${PYTHON_USEDEP}]
-			>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
-			dev-python/mock[${PYTHON_USEDEP}]
-			>=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-			dev-python/requests[${PYTHON_USEDEP}]
-			dev-python/xmlschema[${PYTHON_USEDEP}]
-		' "${PYTHON_TESTED[@]}")
-	)
-"
-
-src_test() {
-	# workaround new readline defaults
-	echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
-	local -x INPUTRC="${T}"/inputrc
-	distutils-r1_src_test
-}
-
-python_test() {
-	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
-		einfo "Skipping tests on ${EPYTHON}"
-		return
-	fi
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	local -x COLUMNS=80
-
-	local EPYTEST_DESELECT=(
-		# broken by epytest args
-		testing/test_warnings.py::test_works_with_filterwarnings
-
-		# tend to be broken by random pytest plugins
-		# (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
-		testing/test_helpconfig.py::test_version_less_verbose
-		testing/test_helpconfig.py::test_version_verbose
-		testing/test_junitxml.py::test_random_report_log_xdist
-		testing/test_junitxml.py::test_runs_twice_xdist
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
-		testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
-		testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
-		testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
-
-		# unstable with xdist
-		testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
-
-		# TODO (XPASS)
-		testing/test_debugging.py::TestDebuggingBreakpoints::test_pdb_not_altered
-		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_simple
-		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_twice
-		testing/test_debugging.py::TestPDB::test_pdb_with_injected_do_debug
-		testing/test_debugging.py::test_pdb_suspends_fixture_capturing
-	)
-
-	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
-		# regressions on pypy3.9
-		# https://github.com/pytest-dev/pytest/issues/9787
-		testing/test_skipping.py::test_errors_in_xfail_skip_expressions
-		testing/test_unraisableexception.py
-	)
-
-	epytest -p xdist -n "$(makeopts_jobs)"
-}