[gentoo-commits] gentoo-x86 commit in sys-devel/m4: ChangeLog m4-1.4.14-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/03/31 11:51:16

  Modified:             ChangeLog
  Added:                m4-1.4.14-r1.ebuild
  Log:
  Disable libsigsegv automagic dependency (bug #278026).
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.131                sys-devel/m4/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/m4/ChangeLog?rev=1.131&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/m4/ChangeLog?rev=1.131&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/m4/ChangeLog?r1=1.130&r2=1.131

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/m4/ChangeLog,v
retrieving revision 1.130
retrieving revision 1.131
diff -u -r1.130 -r1.131
--- ChangeLog	28 Mar 2010 11:20:59 -0000	1.130
+++ ChangeLog	31 Mar 2010 11:51:16 -0000	1.131
@@ -1,6 +1,12 @@
 # ChangeLog for sys-devel/m4
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/m4/ChangeLog,v 1.130 2010/03/28 11:20:59 the_paya Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/m4/ChangeLog,v 1.131 2010/03/31 11:51:16 flameeyes Exp $
+
+*m4-1.4.14-r1 (31 Mar 2010)
+
+  31 Mar 2010; Diego E. Pettenò <flameeyes@g.o>
+  +m4-1.4.14-r1.ebuild:
+  Disable libsigsegv automagic dependency (bug #278026).
 
   28 Mar 2010; Javier Villavicencio <the_paya@g.o> m4-1.4.14.ebuild,
   +files/m4-1.4.14-gnulib_spawn.patch:



1.1                  sys-devel/m4/m4-1.4.14-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/m4/m4-1.4.14-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/m4/m4-1.4.14-r1.ebuild?rev=1.1&content-type=text/plain

Index: m4-1.4.14-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/m4/m4-1.4.14-r1.ebuild,v 1.1 2010/03/31 11:51:16 flameeyes Exp $

inherit eutils

DESCRIPTION="GNU macro processor"
HOMEPAGE="http://www.gnu.org/software/m4/m4.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="examples"

# remember: cannot dep on autoconf since it needs us
DEPEND="|| ( app-arch/xz-utils app-arch/lzma-utils )"
RDEPEND=""

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.4.14-gnulib_spawn.patch # 310335
}

src_compile() {
	# Disable automagic dependency over libsigsegv; see bug #278026
	export ac_cv_libsigsegv=no

	local myconf=""
	[[ ${USERLAND} != "GNU" ]] && myconf="--program-prefix=g"
	econf \
		--enable-changeword \
		${myconf} \
		|| die
	emake || die
}

src_test() {
	[[ -d /none ]] && die "m4 tests will fail with /none/" #244396
	emake check || die
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc BACKLOG ChangeLog NEWS README* THANKS TODO
	if use examples ; then
		docinto examples
		dodoc examples/*
		rm -f "${D}"/usr/share/doc/${PF}/examples/Makefile*
	fi
	rm -f "${D}"/usr/lib/charset.alias #172864
}