[gentoo-commits] gentoo-x86 commit in www-client/dillo: dillo-3.0.5.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         15/07/04 05:30:09

  Modified:             ChangeLog
  Added:                dillo-3.0.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.142                www-client/dillo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?rev=1.142&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?rev=1.142&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?r1=1.141&r2=1.142

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v
retrieving revision 1.141
retrieving revision 1.142
diff -u -r1.141 -r1.142
--- ChangeLog	27 Dec 2014 10:17:45 -0000	1.141
+++ ChangeLog	4 Jul 2015 05:30:08 -0000	1.142
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/dillo
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v 1.141 2014/12/27 10:17:45 jer Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v 1.142 2015/07/04 05:30:08 jer Exp $
+
+*dillo-3.0.5 (04 Jul 2015)
+
+  04 Jul 2015; Jeroen Roovers <jer@g.o> +dillo-3.0.5.ebuild:
+  Version bump.
 
 *dillo-3.0.4.1 (27 Dec 2014)
 



1.1                  www-client/dillo/dillo-3.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/dillo-3.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/dillo-3.0.5.ebuild?rev=1.1&content-type=text/plain

Index: dillo-3.0.5.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/dillo-3.0.5.ebuild,v 1.1 2015/07/04 05:30:08 jer Exp $

EAPI=5
inherit eutils multilib toolchain-funcs

DESCRIPTION="Lean FLTK based web browser"
HOMEPAGE="http://www.dillo.org/"
SRC_URI="http://www.dillo.org/download/${P}.tar.bz2
	mirror://gentoo/${PN}.png"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc +gif ipv6 +jpeg +png ssl"

RDEPEND="
	>=x11-libs/fltk-1.3
	sys-libs/zlib
	jpeg? ( virtual/jpeg:0 )
	png? ( >=media-libs/libpng-1.2:0 )
	ssl? ( dev-libs/openssl:0 )
"
DEPEND="
	${RDEPEND}
	doc? ( app-doc/doxygen )
"

src_prepare() {
	epatch "${FILESDIR}"/${PN}2-inbuf.patch
}

src_configure() {
	econf  \
		$(use_enable gif) \
		$(use_enable ipv6) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable ssl) \
		--docdir="/usr/share/doc/${PF}"
}

src_compile() {
	emake AR=$(tc-getAR)
	if use doc; then
		doxygen Doxyfile || die
	fi
}

src_install() {
	dodir /etc
	default

	use doc && dohtml html/*
	dodoc AUTHORS ChangeLog README NEWS
	dodoc doc/*.txt doc/README

	doicon "${DISTDIR}"/${PN}.png
	make_desktop_entry ${PN} Dillo
}

pkg_postinst() {
	elog "Dillo has installed a default configuration into /etc/dillo/dillorc"
	elog "You can copy this to ~/.dillo/ and customize it"
}