[gentoo-commits] repo/gentoo:master commit in: dev-util/vulkan-tools/

[Nick Sarnie]

commit:     a5e559f331c8f88863cddc95afe949d12a5526a3
Author:     Sergei Chernyadyev <serg.cherniadjev <AT> gmail <DOT> com>
AuthorDate: Mon Dec 19 20:10:28 2022 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Wed Dec 28 21:39:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a5e559f3

dev-util/vulkan-tools: Version bump

Signed-off-by: Sergei Chernyadyev <serg.cherniadjev <AT> gmail.com>
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 dev-util/vulkan-tools/Manifest                    |  1 +
 dev-util/vulkan-tools/vulkan-tools-1.3.236.ebuild | 82 +++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 1e28a261797b..6c6ab95b9c4d 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1 +1,2 @@
 DIST vulkan-tools-1.3.231.tar.gz 876613 BLAKE2B 5c57e5f1f101d79b2bc57a7033a438c470db0d089beaeafa69865f95f14a55c0f71fcc0fb0dea1d898ddcdb80364abb883805e6b60f488a2b5b56bb42cffd4e9 SHA512 b6b1404e3d77e85c5f5d7e111193503e9b2a409a506692a862fcfc01a57d3ee5c6410f47dc7175175b817a1f0e9af62b7a99934c33c68f90babd698aeaeb0b8f
+DIST vulkan-tools-1.3.236.tar.gz 880927 BLAKE2B 0d2b885057d063946140489eae4fb08ad8ff3172d23243f746c74090a20990901b18126cfb41efdd38b24f7c2e7dcd62dd3453f0f6130c618632592a4ecb1d31 SHA512 aa3b934ab084a29ae2503be96f0af69c52b693525cd5bd641c85b5a6f79ec3b7a48ba1b08a1a898229f80086bd5fc819b8ad4019835490653edadcf2d086b9f3

diff --git a/dev-util/vulkan-tools/vulkan-tools-1.3.236.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.3.236.ebuild
new file mode 100644
index 000000000000..8a1f2672d510
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.3.236.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv"
+	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.10.2
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	~media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	~dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+}