[gentoo-commits] gentoo-x86 commit in dev-python/epsilon: epsilon-0.7.0.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/01/28 03:48:16

  Modified:             ChangeLog
  Added:                epsilon-0.7.0.ebuild
  Log:
  bump; drop py2.6 (fails some tests), update deps, add IUSE test + testrunner dep + test phase
  
  (Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.31                 dev-python/epsilon/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/epsilon/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/epsilon/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/epsilon/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/epsilon/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	9 Aug 2013 15:42:55 -0000	1.30
+++ ChangeLog	28 Jan 2014 03:48:16 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/epsilon
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/epsilon/ChangeLog,v 1.30 2013/08/09 15:42:55 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/epsilon/ChangeLog,v 1.31 2014/01/28 03:48:16 idella4 Exp $
+
+*epsilon-0.7.0 (28 Jan 2014)
+
+  28 Jan 2014; Ian Delaney <idella4@g.o> +epsilon-0.7.0.ebuild:
+  bump; drop py2.6 (fails some tests), update deps, add IUSE test + testrunner
+  dep + test phase
 
 *epsilon-0.6.0-r2 (09 Aug 2013)
 



1.1                  dev-python/epsilon/epsilon-0.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/epsilon/epsilon-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/epsilon/epsilon-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: epsilon-0.7.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/epsilon/epsilon-0.7.0.ebuild,v 1.1 2014/01/28 03:48:16 idella4 Exp $

EAPI="5"
PYTHON_COMPAT=( python2_7 )

inherit twisted-r1 eutils

DESCRIPTION="Epsilon is a Python utilities package, most famous for its Time class"
HOMEPAGE="http://divmod.org/trac/wiki/DivmodEpsilon http://pypi.python.org/pypi/Epsilon"
SRC_URI="mirror://pypi/${TWISTED_PN:0:1}/${TWISTED_PN}/${TWISTED_P}.tar.gz"

KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="test"

RDEPEND=">=dev-python/twisted-core-13.2.0[${PYTHON_USEDEP}]
		>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
		test? ( dev-python/nose[${PYTHON_USEDEP}] )
		${DEPEND}"

PATCHES=( "${FILESDIR}/epsilon_plugincache_portagesandbox.patch" )

# epsilon doesn't install any plugins, so override the default
TWISTED_PLUGINS=()

python_prepare_all() {
	# Rename to avoid file-collisions
	mv bin/benchmark bin/epsilon-benchmark
	sed -i \
		-e "s#bin/benchmark#bin/epsilon-benchmark#" \
		setup.py || die "sed failed"

	#These test are removed upstream
	rm -f epsilon/test/test_sslverify.py epsilon/sslverify.py || die
	#See bug 357157 comment 5 for Ian Delaney's explanation of this fix
	sed -e 's:month) 2004 9:month) 2004 14:' \
		-i epsilon/test/test_extime.py || die
	# Release tests need DivmodCombinator.
	rm -f epsilon/test/test_release.py* epsilon/release.py || die

	distutils-r1_python_prepare_all
}

python_install_all() {
	dodoc NAME.txt NEWS.txt

	distutils-r1_python_install_all
}

#Lets run some tests, having prepped them
python_test() {
	# No testrunner seems stipulated within the source; pytest and nosetests both work
	nosetests ${PN}/test || die "testsuite failed under ${EPYTHON}"
}