[gentoo-commits] gentoo-x86 commit in sys-fs/quota: ChangeLog quota-3.15.ebuild

[Mike Frysinger (vapier)]

vapier      07/12/24 12:00:09

  Modified:             ChangeLog
  Added:                quota-3.15.ebuild
  Log:
  Version bump #200397 by Hanno Boeck.
  (Portage version: 2.1.4_rc11)

Revision  Changes    Path
1.32                 sys-fs/quota/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/quota/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/quota/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/quota/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/quota/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	12 Jul 2007 18:34:02 -0000	1.31
+++ ChangeLog	24 Dec 2007 12:00:08 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/quota
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/quota/ChangeLog,v 1.31 2007/07/12 18:34:02 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/quota/ChangeLog,v 1.32 2007/12/24 12:00:08 vapier Exp $
+
+*quota-3.15 (24 Dec 2007)
+
+  24 Dec 2007; Mike Frysinger <vapier@g.o> +quota-3.15.ebuild:
+  Version bump #200397 by Hanno Boeck.
 
   12 Jul 2007; Jeroen Roovers <jer@g.o> quota-3.14-r1.ebuild:
   Stable for HPPA (bug #184382).



1.1                  sys-fs/quota/quota-3.15.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/quota/quota-3.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/quota/quota-3.15.ebuild?rev=1.1&content-type=text/plain

Index: quota-3.15.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/quota/quota-3.15.ebuild,v 1.1 2007/12/24 12:00:08 vapier Exp $

inherit eutils flag-o-matic

DESCRIPTION="Linux quota tools"
HOMEPAGE="http://sourceforge.net/projects/linuxquota/"
SRC_URI="mirror://sourceforge/linuxquota/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86"
IUSE="nls tcpd ldap rpc"

RDEPEND="ldap? ( net-nds/openldap )
	tcpd? ( sys-apps/tcp-wrappers )
	rpc? ( net-nds/portmap )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/quota-tools

src_unpack() {
	unpack ${A}
	cd "${S}"

	# patch to prevent quotactl.2 manpage from being installed
	# that page is provided by man-pages instead
	epatch "${FILESDIR}"/${PN}-no-quotactl-manpage.patch

	# Don't strip binaries (from Fedora)
	epatch "${FILESDIR}"/quota-3.06-no-stripping.patch

	append-cppflags -DLDAP_DEPRECATED=1

	sed -i -e "s:,LIBS=\"\$saved_LIBS=\":;LIBS=\"\$saved_LIBS\":" configure
}

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable ldap ldapmail) \
		$(use_enable rpc) \
		$(use_enable rpc rpcsetquota) \
		|| die
	emake || die
}

src_install() {
	emake ROOTDIR="${D}" install || die
	rm -r "${D}"/usr/include || die #70938

	insinto /etc
	insopts -m0644
	doins warnquota.conf quotatab

	dodoc doc/*
	dodoc README.*
	dodoc Changelog

	newinitd "${FILESDIR}"/quota.rc6 quota
	newconfd "${FILESDIR}"/quota.confd quota

	if use rpc ; then
		newinitd "${FILESDIR}"/rpc.rquotad.initd rpc.rquotad
	else
		rm -f "${D}"/usr/sbin/rpc.rquotad
	fi

	if use ldap ; then
		insinto /etc/openldap/schema
		insopts -m0644
		doins ldap-scripts/quota.schema

		exeinto /usr/share/quota/ldap-scripts
		doexe ldap-scripts/*.pl
		doexe ldap-scripts/edquota_editor
	fi
}



-- 
gentoo-commits@g.o mailing list