[gentoo-commits] repo/proj/libressl:master commit in: dev-qt/qtnetwork/

[Stefan Strogin]

commit:     ea3b8838b3a089e473daf5372bb81836a81ab54d
Author:     Dennis Gaebler <dennis.gaebler <AT> uni-ulm <DOT> de>
AuthorDate: Thu Sep 12 19:17:13 2019 +0000
Commit:     Stefan Strogin <steils <AT> gentoo <DOT> org>
CommitDate: Fri Sep 13 07:25:55 2019 +0000
URL:        https://gitweb.gentoo.org/repo/proj/libressl.git/commit/?id=ea3b8838

dev-qt/qtnetwork: bump to 5.12.5

Reported-by: Dennis Gaebler <dennis.gaebler <AT> uni-ulm.de>
Closes: https://github.com/gentoo/libressl/pull/306
Signed-off-by: Stefan Strogin <steils <AT> gentoo.org>

 dev-qt/qtnetwork/Manifest                |  1 +
 dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild | 68 ++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-qt/qtnetwork/Manifest b/dev-qt/qtnetwork/Manifest
index 83c7984..a1c8a32 100644
--- a/dev-qt/qtnetwork/Manifest
+++ b/dev-qt/qtnetwork/Manifest
@@ -1,2 +1,3 @@
 DIST qtbase-everywhere-src-5.12.3.tar.xz 48382148 BLAKE2B 779c43a75403e0f21357a90228bbcc3f216495613f4f17a2f442c7aa93f277a79cc7addf5ae44e22964069580f4932cfd14ba4773aa0ab30405d5587577a545c SHA512 1dab927573eb22b1ae772de3a418f7d3999ea78d6e667a7f2494390dd1f0981ea93f4f892cb6e124ac18812c780ee71da3021b485c61eaf1ef2234a5c12b7fe2
 DIST qtbase-everywhere-src-5.12.4.tar.xz 48431020 BLAKE2B 7eeb3f6698984343ec14d03b8ad66ab23d81cd7a25c590316f7300c868ab869a9c96b125d56bba149ee116dff44bf47c751cce06f2cdd2d3121e5448708c5f6b SHA512 28b029a0d3621477f625d474b8bc38ddcc7173df6adb274b438e290b6c50bd0891e5b62c04b566a281781acee3a353a6a3b0bc88228e996994f92900448d7946
+DIST qtbase-everywhere-src-5.12.5.tar.xz 48463288 BLAKE2B db394becd1c0c2be9f86658f58dbadb5e3b81af82edf2e8b69652a8587a2aa30f481774fa20d55ce7e8b9cc158dedd343dc3964e4ff0bcf111e8c4feceb27e0a SHA512 9a95060318cadfcd6dace6b28353fa868a8dcfe9def0bd884edf7d9f72606bae625de0269323a94b81d594a6c398106c266304106329b79c7dae4e5b88269660

diff --git a/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild b/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild
new file mode 100644
index 0000000..b741121
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+fi
+
+IUSE="bindist connman libproxy libressl networkmanager sctp +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	sys-libs/zlib:=
+	connman? ( ~dev-qt/qtdbus-${PV} )
+	libproxy? ( net-libs/libproxy )
+	networkmanager? ( ~dev-qt/qtdbus-${PV} )
+	sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0=[bindist=] )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+RDEPEND="${DEPEND}
+	connman? ( net-misc/connman )
+	networkmanager? ( net-misc/networkmanager )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.12.1-libressl.patch
+	"${FILESDIR}"/${PN}-5.12.4-libressl.patch
+)
+
+QT5_TARGET_SUBDIRS=(
+	src/network
+	src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+	libproxy:libproxy:
+	ssl::SSL
+	ssl::OPENSSL
+	ssl:openssl-linked:LINKED_OPENSSL
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:network
+)
+
+pkg_setup() {
+	use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+	use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+	local myconf=(
+		$(usex connman -dbus-linked '')
+		$(qt_use libproxy)
+		$(usex networkmanager -dbus-linked '')
+		$(qt_use sctp)
+		$(usex ssl -openssl-linked '')
+	)
+	qt5-build_src_configure
+}