[gentoo-commits] gentoo-x86 commit in dev-db/postgresql-base: ChangeLog postgresql-base-7.4.26.ebuild

[Patrick Lauer (patrick)]

patrick     09/10/03 16:27:59

  Modified:             ChangeLog
  Added:                postgresql-base-7.4.26.ebuild
  Log:
  Bump to 7.4.26
  (Portage version: 2.2_rc42/cvs/Linux x86_64)

Revision  Changes    Path
1.26                 dev-db/postgresql-base/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/postgresql-base/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/postgresql-base/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/postgresql-base/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	1 Oct 2009 20:48:40 -0000	1.25
+++ ChangeLog	3 Oct 2009 16:27:59 -0000	1.26
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/postgresql-base
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.25 2009/10/01 20:48:40 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.26 2009/10/03 16:27:59 patrick Exp $
+
+*postgresql-base-7.4.26 (03 Oct 2009)
+
+  03 Oct 2009; Patrick Lauer <patrick@g.o>
+  +postgresql-base-7.4.26.ebuild, +files/postgresql-7.4.26-autoconf.patch:
+  Bump to 7.4.26, fixes half of #286700. Thanks to Aaron W. Swenson for
+  testing and patching.
 
   01 Oct 2009; Tobias Klausmann <klausman@g.o>
   postgresql-base-8.4.1.ebuild:



1.1                  dev-db/postgresql-base/postgresql-base-7.4.26.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/postgresql-base/postgresql-base-7.4.26.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/postgresql-base/postgresql-base-7.4.26.ebuild?rev=1.1&content-type=text/plain

Index: postgresql-base-7.4.26.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-7.4.26.ebuild,v 1.1 2009/10/03 16:27:59 patrick Exp $

EAPI="1"

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="none"

inherit eutils multilib toolchain-funcs versionator autotools

KEYWORDS="~amd64 ~x86"

DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2"
LICENSE="POSTGRESQL"
SLOT="$(get_version_component_range 1-2)"
IUSE_LINGUAS="
	linguas_cs linguas_de linguas_es linguas_fr linguas_hr linguas_hu
	linguas_it linguas_nb linguas_pt_BR linguas_ru linguas_sl linguas_sv
	linguas_tr linguas_zh_CN linguas_zh_TW"
IUSE="doc kerberos nls pam pg-intdatetime readline ssl threads zlib ${IUSE_LINGUAS}"
RESTRICT="test"

wanted_languages() {
	for u in ${IUSE_LINGUAS} ; do
		use $u && echo -n "${u#linguas_} "
	done
}

RDEPEND="kerberos? ( virtual/krb5 )
	pam? ( virtual/pam )
	readline? ( >=sys-libs/readline-4.1 )
	ssl? ( >=dev-libs/openssl-0.9.6-r1 )
	zlib? ( >=sys-libs/zlib-1.1.3 )
	>=app-admin/eselect-postgresql-0.3
	!dev-db/postgresql-libs
	!dev-db/postgresql-client
	!dev-db/libpq
	!dev-db/postgresql"
DEPEND="${RDEPEND}
	sys-devel/flex
	>=sys-devel/bison-1.875
	nls? ( sys-devel/gettext )"
PDEPEND="doc? ( dev-db/postgresql-docs:${SLOT} )"

S="${WORKDIR}/postgresql-${PV}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/postgresql-${PV}-autoconf.patch" \
		"${FILESDIR}/postgresql-${SLOT}-hppa.patch" \
		"${FILESDIR}/postgresql-${SLOT}-base.patch"

	# to avoid collision - it only should be installed by server
	rm "${S}/src/backend/nls.mk"

	# because psql/help.c includes the file
	ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/"

	eautoreconf
}

src_compile() {
	econf --prefix=/usr/$(get_libdir)/postgresql-${SLOT} \
		--datadir=/usr/share/postgresql-${SLOT} \
		--sysconfdir=/etc/postgresql-${SLOT} \
		--includedir=/usr/include/postgresql-${SLOT} \
		--with-locale-dir=/usr/share/postgresql-${SLOT}/locale \
		--mandir=/usr/share/postgresql-${SLOT}/man \
		--host=${CHOST} \
		--docdir=/usr/share/doc/${PF} \
		--without-tcl \
		--without-perl \
		--without-python \
		$(use_with kerberos krb5) \
		"$(use_enable nls nls "$(wanted_languages)")" \
		$(use_with pam) \
		$(use_enable pg-intdatetime integer-datetimes ) \
		$(use_with readline) \
		$(use_with ssl openssl) \
		$(use_enable threads thread-safety ) \
		$(use_with zlib) \
		|| die "configure failed"

	emake LD="$(tc-getLD) $(get_abi_LDFLAGS)" || die "emake failed"

	cd "${S}/contrib"
	emake LD="$(tc-getLD) $(get_abi_LDFLAGS)" || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	insinto /usr/include/postgresql-${SLOT}/postmaster
	doins "${S}"/src/include/postmaster/*.h

	# Install missing libpgport.a
	insinto /usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)
	doins "${S}/src/port/libpgport.a"

	dodir /usr/share/postgresql-${SLOT}/man/man1
	tar -zxf "${S}/doc/man.tar.gz" -C "${D}"/usr/share/postgresql-${SLOT}/man man1/{ecpg,pg_config}.1

	rm -rf "${D}/usr/share/doc/${PF}/html"
	rm "${D}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,initlocation,ipcclean,pg_controldata,pg_ctl,pg_resetxlog,pg_restore,postgres,postmaster}.1
	dodoc README HISTORY doc/{README.*,TODO,bug.template}

	cd "${S}/contrib"
	emake DESTDIR="${D}" install || die "emake install failed"
	cd "${S}"

	dodir /etc/eselect/postgresql/slots/${SLOT}

	IDIR="/usr/include/postgresql-${SLOT}"
	cat > "${D}/etc/eselect/postgresql/slots/${SLOT}/base" <<-__EOF__
postgres_ebuilds="\${postgres_ebuilds} ${PF}"
postgres_prefix=/usr/$(get_libdir)/postgresql-${SLOT}
postgres_datadir=/usr/share/postgresql-${SLOT}
postgres_bindir=/usr/$(get_libdir)/postgresql-${SLOT}/bin
postgres_symlinks=(
	${IDIR} /usr/include/postgresql
	${IDIR}/libpq-fe.h /usr/include/libpq-fe.h
	${IDIR}/libpq /usr/include/libpq
	${IDIR}/postgres_ext.h /usr/include/postgres_ext.h
)
__EOF__

	cat >"${T}/50postgresql-98-${SLOT}" <<-__EOF__
		LDPATH=/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)
		MANPATH=/usr/share/postgresql-${SLOT}/man
	__EOF__
	doenvd "${T}/50postgresql-98-${SLOT}"

	keepdir /etc/postgresql-${SLOT}
}

pkg_postinst() {
	eselect postgresql update
	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
	elog "If you need a global psqlrc-file, you can place it in '${ROOT}/etc/postgresql-${SLOT}/'."
}

pkg_postrm() {
	eselect postgresql update
}