[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     404cff2bb375846c85ee9d03a54ef9be7013a444
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jul  4 00:53:40 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jul  4 00:54:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=404cff2b

sys-kernel/gentoo-kernel-bin: bump to 5.4.128 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.128-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 35a7581502e..1e5783125ac 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -76,6 +76,7 @@ DIST gentoo-kernel-5.4.127-1.amd64.xpak 61364361 BLAKE2B 9ff813492bd7bc1f135b36b
 DIST gentoo-kernel-5.4.127-1.arm64.xpak 56394161 BLAKE2B e3b9dc7334615ed225ba0cf71f18e45d7f4c0afb82f467597801094361df137feda3c26051c4bb1eef76b9bf9c77394b6029d4fe703746262f1fe3e7ce623ca9 SHA512 2f59983a0e5ca2e08c598aada66e3d5c052a0f67448bf979261d75e0e38d8f0e5e3921aa4f09564709262d86aac2361ccb367c6ba78addba6a6731eb98a10c87
 DIST gentoo-kernel-5.4.127-1.x86.xpak 53135461 BLAKE2B f363e24cdeae29dad876a1aaa8c0159d627d27d632de2d9509cc4f78cea4cc8ce963956771b542219f9a948e8b1a2d6aa5b80878a21d99cc0c1c3bbdc14f538c SHA512 9f9bb382a88c4f73b94956cb765c9ef5e380ee4e12b67ffb22cbfc8815bdcbf1a62b68ba770fe03d7ec3d753bbb8b3c11845ebcfcb2ef263cab9442c9fe0d340
 DIST gentoo-kernel-5.4.128-1.amd64.xpak 61349719 BLAKE2B 11cbd06fa2e8489c57ef2383f5fdfd0a270f7994bbabf1c9dab589ce12278ba9d02a3549da1ac0f0c553a991d54fa2db42c67a26d15c1bdbbe496f3711d73b1d SHA512 6b59014f8b33f1ad3f5b1c233f4ec737ed7058ceac83e1c92c42ff1de5c7358067eeed6d491d9a03c33705b8d5df15e47388e444d8237b6fae389ba78947035e
+DIST gentoo-kernel-5.4.128-1.arm64.xpak 56376275 BLAKE2B fad0b8cb4f9279ba59b660700ba21b36e432b8e89fe6623aa5799a7951c7641f20676e5e540237a92b671ee11cddcc4e338ad079d7cdd48af35a57d53aa65419 SHA512 96aa492cbb67adee064ebf9b97fd4f3e176e7ce4a7ed83038959fc7e06c42115fbf02cfcc40dd457bcd3f4f7769919e40eac3f2e13c0183a729596700a1706c6
 DIST gentoo-kernel-5.4.128-1.x86.xpak 53129699 BLAKE2B 0f51b8436776dc077e5f7540948e61cc5a2be00518e7da6372cd7f59de108d2efdf3f477d934efff979d94df21ed76568404298df91df6493d079aca2fad03e6 SHA512 e63f619c19f00c1dc1c5e11d0937ce4a0e9acef643336b51a8dc203a93dd1c3641eec8fda00713c6c40570e52a22a8714983de6819a4b9efaa6a37c6231653f4
 DIST gentoo-kernel-5.4.129-1.amd64.xpak 61346649 BLAKE2B 37d29b604a69fd8bc84c41bc619bef982d10cf31d7220ff79bb853a674eb594418338748968042d19352458ba61015bf631c8f36f3a1a6674bcaf228dfaac240 SHA512 30601d1b125d1bf1999e49f817d8a553f387c512a85cd2921e201e7e06b85b90148aef276fdcdfa50f5da477a067bae52af5c400f1cb596f9fec21bb3162db44
 DIST gentoo-kernel-5.4.129-1.x86.xpak 53134201 BLAKE2B c7d76168ceb139ff7e206e5005d6cad2c7c54320967ca9e9c8dcf493677527fa3712d43c9b6dba96a54ad8b1d68cce937dd3643b0ac2d1e8a32c1d27361f578a SHA512 edf3c3f744738bbc06f13307259ef6315cb5bda60d9ca165853b7ea4b2f983ba72efa3bb1b4db1a0b21deb5060b7636a5c41840b36cd1ee224bce69358db6e4d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.128-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.128-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.128-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}