[gentoo-commits] gentoo-x86 commit in net-nntp/nzbget: metadata.xml ChangeLog nzbget-0.8.0_pre394.ebuild

[Tim Harder (radhermit)]

radhermit    11/08/30 21:41:41

  Modified:             metadata.xml ChangeLog
  Added:                nzbget-0.8.0_pre394.ebuild
  Log:
  Version bump (bug #375959). Add myself as a maintainer.
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-nntp/nzbget/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-nntp/nzbget/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	22 Aug 2008 19:52:40 -0000	1.2
+++ metadata.xml	30 Aug 2011 21:41:41 -0000	1.3
@@ -6,6 +6,10 @@
 		 <email>swegener@g.o</email>
 		 <name>Sven Wegener</name>
 	</maintainer>
+	<maintainer>
+		 <email>radhermit@g.o</email>
+		 <name>Tim Harder</name>
+	</maintainer>
 	<longdescription>A command-line based binary newsgrabber supporting .nzb files.</longdescription>
 	<use>
 		<flag name='parcheck'>Enable support for checking PAR archives</flag>



1.36                 net-nntp/nzbget/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	30 Aug 2011 21:32:40 -0000	1.35
+++ ChangeLog	30 Aug 2011 21:41:41 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for net-nntp/nzbget
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.35 2011/08/30 21:32:40 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.36 2011/08/30 21:41:41 radhermit Exp $
+
+*nzbget-0.8.0_pre394 (30 Aug 2011)
+
+  30 Aug 2011; Tim Harder <radhermit@g.o> +nzbget-0.8.0_pre394.ebuild,
+  metadata.xml:
+  Version bump (bug #375959). Add myself as a maintainer.
 
   30 Aug 2011; Tim Harder <radhermit@g.o> nzbget-0.7.0.ebuild,
   +files/nzbget-0.7.0-underlinking.patch:



1.1                  net-nntp/nzbget/nzbget-0.8.0_pre394.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/nzbget-0.8.0_pre394.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/nzbget-0.8.0_pre394.ebuild?rev=1.1&content-type=text/plain

Index: nzbget-0.8.0_pre394.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/nzbget-0.8.0_pre394.ebuild,v 1.1 2011/08/30 21:41:41 radhermit Exp $

EAPI="4"

inherit eutils autotools

MY_P="${P/_pre/-testing-r}"

DESCRIPTION="A command-line based binary newsgrapper supporting .nzb files"
HOMEPAGE="http://nzbget.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE="debug ssl gnutls ncurses parcheck"

RDEPEND="dev-libs/libxml2
	ssl? (
		gnutls? ( net-libs/gnutls )
		!gnutls? ( dev-libs/openssl )
	)
	ncurses? ( sys-libs/ncurses )
	parcheck? (
		app-arch/libpar2
		dev-libs/libsigc++:2
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

DOCS=( AUTHORS ChangeLog README nzbget.conf.example )

S="${WORKDIR}"/${P/_pre*/-testing}

src_prepare() {
	sed \
		-i \
		-e 's:^PostProcess=.*:#PostProcess=/usr/share/nzbget/postprocess-example.sh:' \
		nzbget.conf.example \
		|| die "sed nzbget.conf.example failed"

	sed \
		-e 's:^$MAINDIR=.*:$MAINDIR=/var/lib/nzbget:' \
		-e 's:^LockFile=.*:LockFile=/var/run/nzbget/nzbget.pid:' \
		-e 's:^LogFile=.*:LogFile=/var/log/nzbget/nzbget.log:' \
		"${S}"/nzbget.conf.example >"${S}"/nzbgetd.conf.example \
		|| die "sed nzbgetd.conf.example failed"

	epatch "${FILESDIR}"/${PN}-0.7.0-openssl-1.patch \
		"${FILESDIR}"/${PN}-0.7.0-underlinking.patch

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable ncurses curses) \
		$(use_enable parcheck) \
		$(use_enable ssl tls) \
		--with-tlslib=$(use gnutls && echo GnuTLS || echo OpenSSL)
}

src_install() {
	default

	insinto /etc
	newins nzbget.conf.example nzbget.conf
	newins nzbgetd.conf.example nzbgetd.conf

	keepdir /var/lib/nzbget/{dst,nzb,queue,tmp}
	keepdir /var/{log,run}/nzbget

	newinitd "${FILESDIR}"/nzbget.initd nzbget
	newconfd "${FILESDIR}"/nzbget.confd nzbget

	exeinto /usr/share/nzbget
	doexe postprocess-example.sh

	insinto /usr/share/nzbget
	doins postprocess-example.conf
}

pkg_preinst() {
	enewgroup nzbget
	enewuser nzbget -1 -1 /var/lib/nzbget nzbget

	fowners nzbget:nzbget /var/lib/nzbget/{dst,nzb,queue,tmp}
	fperms 750 /var/lib/nzbget/{queue,tmp}
	fperms 770 /var/lib/nzbget/{dst,nzb}

	fowners nzbget:nzbget /var/{log,run}/nzbget
	fperms 750 /var/{log,run}/nzbget

	fowners root:nzbget /etc/nzbgetd.conf
	fperms 640 /etc/nzbgetd.conf
}

pkg_postinst() {
	elog
	elog "Please add users that you want to be able to use the system-wide"
	elog "nzbget daemon to the nzbget group. To access the daemon run nzbget"
	elog "with the --configfile /etc/nzbgetd.conf option."
	elog
}