[gentoo-commits] gentoo-x86 commit in x11-wm/ctwm: ChangeLog ctwm-3.8.1.ebuild

[Jeroen Roovers (jer)]

jer         12/02/07 22:13:08

  Modified:             ChangeLog
  Added:                ctwm-3.8.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha85/cvs/Linux x86_64)

Revision  Changes    Path
1.27                 x11-wm/ctwm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ctwm/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ctwm/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ctwm/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/ctwm/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	21 Dec 2011 08:51:41 -0000	1.26
+++ ChangeLog	7 Feb 2012 22:13:07 -0000	1.27
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/ctwm
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/ctwm/ChangeLog,v 1.26 2011/12/21 08:51:41 phajdan.jr Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/ctwm/ChangeLog,v 1.27 2012/02/07 22:13:07 jer Exp $
+
+*ctwm-3.8.1 (07 Feb 2012)
+
+  07 Feb 2012; Jeroen Roovers <jer@g.o> +ctwm-3.8.1.ebuild:
+  Version bump.
 
   21 Dec 2011; Pawel Hajdan jr <phajdan.jr@g.o> ctwm-3.8a-r1.ebuild:
   x86 stable wrt bug #393941



1.1                  x11-wm/ctwm/ctwm-3.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ctwm/ctwm-3.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ctwm/ctwm-3.8.1.ebuild?rev=1.1&content-type=text/plain

Index: ctwm-3.8.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/ctwm/ctwm-3.8.1.ebuild,v 1.1 2012/02/07 22:13:07 jer Exp $

EAPI=4

inherit eutils toolchain-funcs

DESCRIPTION="A clean, light window manager."
HOMEPAGE="http://ctwm.free.lp.se/"
SRC_URI="http://ctwm.free.lp.se/dist/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE=""

RDEPEND="
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXmu
	x11-libs/libXt
"
DEPEND="
	${RDEPEND}
	app-text/rman
	virtual/jpeg
	x11-misc/imake
	x11-proto/xextproto
	x11-proto/xproto
"

src_prepare() {
	# overflow bug 338180
	sed -i menus.c -e "/char modStr/ s/5/6/" || die

	# implicit 'isspace'
	sed -i parse.c -e "/<stdio.h>/ a#include <ctype.h>" || die

	sed -i Imakefile -e "/^CONFDIR/s@=.*@= /etc/X11/twm@g" || die

	cp Imakefile.local-template Imakefile.local

	# TODO: Add GNOME support
	sed -i Imakefile.local -e '/^#define GNOME/d' || die
}

src_compile() {
	xmkmf || die
	emake \
		CC=$(tc-getCC) \
		CFLAGS="${CFLAGS}" \
		EXTRA_LDOPTIONS="${LDFLAGS}" \
		TWMDIR=/usr/share/${PN}
}

src_install() {
	emake BINDIR=/usr/bin \
		MANPATH=/usr/share/man \
		TWMDIR=/usr/share/${PN} \
		DESTDIR="${D}" install

	emake MANPATH=/usr/share/man \
		DOCHTMLDIR=/usr/share/doc/${PF}/html \
		DESTDIR="${D}" install.man

	echo "#!/bin/sh" > ${T}/ctwm
	echo "/usr/bin/ctwm" >> ${T}/ctwm

	exeinto /etc/X11/Sessions
	doexe "${T}"/ctwm

	dodoc CHANGES README* TODO* PROBLEMS
	dodoc *.ctwmrc*
}