[gentoo-commits] repo/gentoo:master commit in: dev-libs/libxmlb/

[Lars Wendler]

commit:     65a05f60dccb7bf5dbe0d9e202720eb7b2437e9b
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  7 21:32:47 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Sep  7 21:32:56 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65a05f60

dev-libs/libxmlb: Bump to version 0.2.1

Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-libs/libxmlb/Manifest             |  1 +
 dev-libs/libxmlb/libxmlb-0.2.1.ebuild | 58 +++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-libs/libxmlb/Manifest b/dev-libs/libxmlb/Manifest
index f2ebf1dc304..9de6e04de72 100644
--- a/dev-libs/libxmlb/Manifest
+++ b/dev-libs/libxmlb/Manifest
@@ -1,2 +1,3 @@
 DIST libxmlb-0.1.15.tar.gz 92923 BLAKE2B 97b6af812397dd279e7e3c038627fcf8228cbfa5c3af91ceeb5361e32d37d357eda6a193f627a5f4442426fb08abca1ff11684fe199d9d3a4add72ca4f3f5d08 SHA512 58268b3a690af36c0923afdee3ae58e88bf778eebbc6a439be1bc85ed985efdc20cd7006c976586f7be87310dc091d67dddd370f4bbec58379fc4e7349bfa3d8
 DIST libxmlb-0.2.0.tar.gz 97521 BLAKE2B 7a47164503b5b682e2bb9d877622a7dcad06d40bf87d6a7cf9e21898d8444e610ba3985d6be8cf65068f0637ee44ef8678610315be2795476b2f5ccaacb098ea SHA512 cff4245a47a942dd37675921ba753858a3ee0572500a1cd7291d2a063fa7fa9d9157c167bf33694e4e0204504d7e88fbfd2873c4b9851247d6cdb338c2d587a8
+DIST libxmlb-0.2.1.tar.gz 98284 BLAKE2B b9bf02560a231837d7837b43f01d8f78c54a80319379a7bfa191f8303b77c35e82d1e2bb57722f1bfe56224d96bd1513cef702a0375eb85a137bff8ca3104c5c SHA512 4e082f036eb62626d1724ac5093ad625f9259e9e81aa40d5ca0589a3a72dadd669c0718ff64dcae094973b6c282b6c8f8ce7212b7e47211f320035bb639ec59d

diff --git a/dev-libs/libxmlb/libxmlb-0.2.1.ebuild b/dev-libs/libxmlb/libxmlb-0.2.1.ebuild
new file mode 100644
index 00000000000..eef8b51f864
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.2.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # libxmlb.so version
+
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc introspection stemmer test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	sys-apps/util-linux
+	stemmer? ( dev-libs/snowball-stemmer )
+"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+BDEPEND="
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+		${PYTHON_DEPS}
+	)
+"
+
+python_check_deps() {
+	has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use introspection && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgtkdoc="$(usex doc true false)"
+		-Dintrospection="$(usex introspection true false)"
+		-Dstemmer="$(usex stemmer true false)"
+		-Dtests="$(usex test true false)"
+	)
+	meson_src_configure
+}