[gentoo-commits] repo/gentoo:master commit in: dev-python/apsw/

[Sam James]

commit:     da975336a864f624adb8931df83fdf0a4e64bd1c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 23 05:41:38 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jun 23 05:41:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da975336

dev-python/apsw: restore extension to fix Calibre

Closes: https://bugs.gentoo.org/851741
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/apsw/apsw-3.38.5_p1-r1.ebuild | 54 ++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/dev-python/apsw/apsw-3.38.5_p1-r1.ebuild b/dev-python/apsw/apsw-3.38.5_p1-r1.ebuild
new file mode 100644
index 000000000000..f58c16a0974a
--- /dev/null
+++ b/dev-python/apsw/apsw-3.38.5_p1-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_p/-r}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="
+	https://github.com/rogerbinns/apsw/
+	https://pypi.org/project/apsw/
+"
+SRC_URI="
+	https://github.com/rogerbinns/apsw/archive/${MY_PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="doc"
+
+DEPEND="
+	>=dev-db/sqlite-${PV%_p*}:3
+"
+RDEPEND="
+	${DEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.6.20.1-fix_tests.patch"
+)
+
+python_compile() {
+	# Needed for e.g. bug #851741
+	distutils-r1_python_compile --enable=load_extension
+}
+
+python_test() {
+	esetup.py build_test_extension
+	"${EPYTHON}" tests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}