[gentoo-commits] gentoo-x86 commit in dev-scheme/guile: ChangeLog guile-1.8.8-r1.ebuild

[Panagiotis Christopoulos (pchrist)]

pchrist     11/04/29 14:17:17

  Modified:             ChangeLog
  Added:                guile-1.8.8-r1.ebuild
  Log:
  revbump, first try to fix bug #202205. Fix based on old patch from Alexis Ballier (aballier)
  
  (Portage version: 2.1.9.46/cvs/Linux i686)

Revision  Changes    Path
1.85                 dev-scheme/guile/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/guile/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/guile/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/guile/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	29 Apr 2011 09:44:07 -0000	1.84
+++ ChangeLog	29 Apr 2011 14:17:17 -0000	1.85
@@ -1,6 +1,13 @@
 # ChangeLog for dev-scheme/guile
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v 1.84 2011/04/29 09:44:07 pchrist Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v 1.85 2011/04/29 14:17:17 pchrist Exp $
+
+*guile-1.8.8-r1 (29 Apr 2011)
+
+  29 Apr 2011; Panagiotis Christopoulos <pchrist@g.o>
+  +guile-1.8.8-r1.ebuild, +files/guile-1.8.8-fix_guile-config.patch:
+  revbump, first try to fix bug #202205. Fix based on old patch from Alexis
+  Ballier (aballier)
 
   29 Apr 2011; Panagiotis Christopoulos <pchrist@g.o>
   guile-1.8.8.ebuild:



1.1                  dev-scheme/guile/guile-1.8.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/guile/guile-1.8.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/guile/guile-1.8.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: guile-1.8.8-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/guile-1.8.8-r1.ebuild,v 1.1 2011/04/29 14:17:17 pchrist Exp $

EAPI=3
inherit eutils autotools flag-o-matic elisp-common

DESCRIPTION="Scheme interpreter"
HOMEPAGE="http://www.gnu.org/software/guile/"
SRC_URI="mirror://gnu/guile/${P}.tar.gz"

LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="networking +regex discouraged +deprecated emacs nls debug-freelist debug-malloc debug +threads"
RESTRICT="!regex? ( test )"

DEPEND="
	>=dev-libs/gmp-4.1
	>=sys-devel/libtool-1.5.6
	sys-devel/gettext
	emacs? ( virtual/emacs )"
RDEPEND="${DEPEND}"

# Guile seems to contain some slotting support, /usr/share/guile/ is slotted,
# but there are lots of collisions. Most in /usr/share/libguile. Therefore
# I'm slotting this in the same slot as guile-1.6* for now.
SLOT="12"
MAJOR="1.8"

src_prepare() {
	# 
	epatch "${FILESDIR}/${P}-fix_guile-config.patch"
	eautoreconf
}

src_configure() {
	# see bug #178499
	filter-flags -ftree-vectorize

	#will fail for me if posix is disabled or without modules -- hkBst
	econf \
		--disable-error-on-warning \
		--disable-static \
		--enable-posix \
		$(use_enable networking) \
		$(use_enable regex) \
		$(use deprecated || use_enable discouraged) \
		$(use_enable deprecated) \
		$(use_enable emacs elisp) \
		$(use_enable nls) \
		--disable-rpath \
		$(use_enable debug-freelist) \
		$(use_enable debug-malloc) \
		$(use_enable debug guile-debug) \
		$(use_with threads) \
		--with-modules \
		EMACS=no
}

src_compile()  {
	emake || die "make failed"

	# Above we have disabled the build system's Emacs support;
	# for USE=emacs we compile (and install) the files manually
	if use emacs; then
		cd emacs
		elisp-compile *.el || die
	fi
}

src_install() {
	einstall || die "install failed"

	dodoc AUTHORS ChangeLog GUILE-VERSION HACKING NEWS README THANKS || die

	# texmacs needs this, closing bug #23493
	dodir /etc/env.d
	echo "GUILE_LOAD_PATH=\"${EPREFIX}/usr/share/guile/${MAJOR}\"" > "${ED}"/etc/env.d/50guile

	# necessary for registering slib, see bug 206896
	keepdir /usr/share/guile/site

	if use emacs; then
		elisp-install ${PN} emacs/*.{el,elc} || die
		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el" || die
	fi
}

pkg_postinst() {
	[ "${EROOT}" == "/" ] && pkg_config
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}

pkg_config() {
	if has_version dev-scheme/slib; then
		einfo "Registering slib with guile"
		install_slib_for_guile
	fi
}

_pkg_prerm() {
	rm -f "${EROOT}"/usr/share/guile/site/slibcat
}