[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Lars Wendler]

commit:     5cfa6035560f2f22f0b6b288d7cafc395800dcef
Author:     David Heidelberg <david <AT> ixit <DOT> cz>
AuthorDate: Sun Dec  1 11:04:44 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Dec  1 19:49:58 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5cfa6035

sys-apps/fwupd: bump 1.3.5

Closes: https://bugs.gentoo.org/701648

Signed-off-by: David Heidelberg <david <AT> ixit.cz>
Closes: https://github.com/gentoo/gentoo/pull/13821
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.3.5.ebuild | 159 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 160 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index d5fff80f106..1ace98b947c 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -2,3 +2,4 @@ DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B 4eb6d5008d0e515880147a94b2632ed70b5f7ab
 DIST fwupd-1.2.8.tar.gz 1911999 BLAKE2B 61a24ce24f778b96f7ad23496890f7a1d20c09e6bbd707f29d154992668d5c0a25cfd31b5d0d11519740e086c098cbdfd440fe9f5cab4dde0ac43fe6b438e911 SHA512 d603f9f4e5a4c0fc6abb0b75f7d884eff47fb8a16285aa545f7140fe98ce781d127ff3769f9c206bb3bfd084bbc5bf6abf9424f70e727ff79162416fe7881154
 DIST fwupd-1.3.3.tar.gz 2125604 BLAKE2B 4471d270ec7f99857dd811b2ba9d8f591a0787ee7ad2bf45edff90904483b8fe54483cde2722e7ee9afb426b17b4d4090f6935b3fa2712a277d058802fc2e9f5 SHA512 b8f0d88fa9c1c8219dd040775d76207f1be87294ebb5f38043b77a670a1601cc597a711f5635aa3d164a08ee0dd068dd22514acae96f6fc5ad20d35099d02f50
 DIST fwupd-1.3.4.tar.gz 2151009 BLAKE2B 3ea171d4a9498963b6082ae2e3f9b41edde862b84f3f506e403bc2dd6a08ec27ccbac6c5891bdf567860f43b008ccd36a7e6d40e72f2d252eceb913833372719 SHA512 00b6ba394c74252c1c7eba5e5e1fd92f234fb6db6de8bca69fbc578bf3b12790867b6adaef6c422c801d28990d390bbe8af67ab0f5bd3a744adbeb053708a254
+DIST fwupd-1.3.5.tar.gz 2164874 BLAKE2B aa268f3d94b3c7104cad5e80de81a724ba978e3da468cd2d44833656c5b0a95b1f720f5c7a0dd9812b8afce4c58e8f777e13ea2e1f4ce0b8b582ee3c731b744a SHA512 b1944b06bed9cb10ec90219235b168a76fcf6ff7b8938dfba36259f07efed71a755d7b91fcbe8f6fda00ac971bd5d4734a49e045005e2e1c32b49fc5b86c48dd

diff --git a/sys-apps/fwupd/fwupd-1.3.5.ebuild b/sys-apps/fwupd/fwupd-1.3.5.ebuild
new file mode 100644
index 00000000000..684e4c548a4
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.3.5.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt consolekit dell gtk-doc elogind minimal +gpg introspection +man nvme pkcs7 redfish synaptics systemd test thunderbolt uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( consolekit elogind minimal systemd )
+	dell? ( uefi )
+	minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.2.9[introspection?]
+	>=dev-libs/libxmlb-0.1.13
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	virtual/libelf:0=
+	virtual/udev
+	consolekit? ( >=sys-auth/consolekit-1.0.0 )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	elogind? ( sys-auth/elogind )
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	!minimal? (
+		>=sys-auth/polkit-0.103
+	)
+	nvme? ( sys-libs/efivar )
+	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+	redfish? ( sys-libs/efivar )
+	systemd? ( >=sys-apps/systemd-211 )
+	thunderbolt? (
+		sys-apps/thunderbolt-software-user-space
+	)
+	uefi? (
+		app-crypt/tpm2-tss
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+RDEPEND="
+	${DEPEND}
+	sys-apps/dbus
+"
+
+pkg_setup() {
+	tc-ld-disable-gold # bug https://github.com/fwupd/fwupd/issues/1530
+
+	python-single-r1_pkg_setup
+	if use nvme; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		$(meson_use agent)
+		$(meson_use amt plugin_amt)
+		$(meson_use consolekit)
+		$(meson_use dell plugin_dell)
+		$(meson_use elogind)
+		$(meson_use gpg)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use man)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use pkcs7)
+		$(meson_use redfish plugin_redfish)
+		$(meson_use synaptics plugin_synaptics)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use uefi plugin_uefi)
+		# Requires libflashrom which our sys-apps/flashrom
+		# package does not provide
+		-Dplugin_flashrom="false"
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+	)
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
+			"${FILESDIR}"/${PN}-r1 \
+			> "${T}"/${PN} || die
+		doinitd "${T}"/${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}