[gentoo-commits] repo/gentoo:master commit in: dev-python/statsmodels/

[Michał Górny]

commit:     cb7f0140be1afdbbccc5bc230a15f3eaf4f5d0e0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 28 06:50:25 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug 28 07:14:35 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb7f0140

dev-python/statsmodels: Bump to 0.12.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/statsmodels/Manifest                  |  1 +
 dev-python/statsmodels/statsmodels-0.12.0.ebuild | 83 ++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index dba98937e08..62f537be604 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1 +1,2 @@
 DIST statsmodels-0.11.1.tar.gz 15381516 BLAKE2B a40cf9138edd8a9a6707a550d9885e0610f9bc666fcd73a60bd11ade6dcfa806ecd912a725cf2a13902e92f31af2c3e82f244280f70586bb3359dc8fc2842508 SHA512 54afe55a23b431154c159f44d284aa093f3368988f0695c0f3fbb206046cdfb171ab2ba51ce94285d567b8536141f93a1ef404b5f7222f1e61264baf0541926d
+DIST statsmodels-0.12.0.tar.gz 17502050 BLAKE2B 8621882d920db652d1244fcd4a0bc4f31310663c4dc6582421cd64a040e0b64917070aef5962515b07a8e92c0d690d43dea19d8ee9b71c7a3c2548e903e69125 SHA512 a9cbba0c8cd7e11bef4fbb303c204d5d4db4eb9f3f93f608b9be5b3c0d7feccc08dd84b4904557fbd1c12f49f3376b2aa7fabd06daf5649fd72c16b7041afac9

diff --git a/dev-python/statsmodels/statsmodels-0.12.0.ebuild b/dev-python/statsmodels/statsmodels-0.12.0.ebuild
new file mode 100644
index 00000000000..dfa23119e7a
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.12.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/numpy-1.15[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.23.0[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.15[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-1.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/statsmodels-0.11.1-tests.patch"
+)
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter_client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	# these tests require internet
+	sed -i -e 's:test_results_on_the:_&:' \
+		statsmodels/stats/tests/test_dist_dependant_measures.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local jobs=$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")
+
+	pushd "${BUILD_DIR}" >/dev/null || die
+	"${EPYTHON}" -c "
+import statsmodels
+statsmodels.test(extra_args=['-vv', '-n', '${jobs}'], exit=True)" \
+		|| die "tests fail with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}