[gentoo-commits] gentoo-x86 commit in app-misc/screen: screen-4.2.1.ebuild ChangeLog screen-4.2.0-r1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    14/04/28 06:04:54

  Modified:             ChangeLog
  Added:                screen-4.2.1.ebuild
  Removed:              screen-4.2.0-r1.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.193                app-misc/screen/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/screen/ChangeLog?rev=1.193&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/screen/ChangeLog?rev=1.193&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/screen/ChangeLog?r1=1.192&r2=1.193

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/screen/ChangeLog,v
retrieving revision 1.192
retrieving revision 1.193
diff -u -r1.192 -r1.193
--- ChangeLog	20 Apr 2014 18:37:01 -0000	1.192
+++ ChangeLog	28 Apr 2014 06:04:54 -0000	1.193
@@ -1,6 +1,16 @@
 # ChangeLog for app-misc/screen
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/screen/ChangeLog,v 1.192 2014/04/20 18:37:01 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/screen/ChangeLog,v 1.193 2014/04/28 06:04:54 polynomial-c Exp $
+
+*screen-4.2.1 (28 Apr 2014)
+
+  28 Apr 2014; Lars Wendler <polynomial-c@g.o> -screen-4.2.0-r1.ebuild,
+  +screen-4.2.1.ebuild, -files/screen-4.2.0-check_for_altscreen.patch,
+  -files/screen-4.2.0-incompatible-protocol.patch,
+  -files/screen-4.2.0-long_terminal_names.patch,
+  -files/screen-4.2.0-nonethack_segfault_fix.patch,
+  -files/screen-4.2.0-tgetent.patch:
+  Version bump. Removed old.
 
   20 Apr 2014; Lars Wendler <polynomial-c@g.o> -files/4.2.0-tinfo.patch:
   Removed unused patch.



1.1                  app-misc/screen/screen-4.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/screen/screen-4.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/screen/screen-4.2.1.ebuild?rev=1.1&content-type=text/plain

Index: screen-4.2.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/screen/screen-4.2.1.ebuild,v 1.1 2014/04/28 06:04:54 polynomial-c Exp $

EAPI=5

inherit autotools eutils flag-o-matic pam toolchain-funcs user

DESCRIPTION="Full-screen window manager that multiplexes physical terminals between several processes"
HOMEPAGE="http://www.gnu.org/software/screen/"
SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug nethack pam selinux multiuser"

RDEPEND=">=sys-libs/ncurses-5.2
	pam? ( virtual/pam )
	selinux? ( sec-policy/selinux-screen )"
DEPEND="${RDEPEND}
	sys-apps/texinfo"
RDEPEND="${RDEPEND}
	>=sys-apps/openrc-0.11.6"

pkg_setup() {
	# Make sure utmp group exists, as it's used later on.
	enewgroup utmp 406
}

src_prepare() {
	# Don't use utempter even if it is found on the system
	epatch "${FILESDIR}"/4.0.2-no-utempter.patch

	# sched.h is a system header and causes problems with some C libraries
	mv sched.h _sched.h || die
	sed -i '/include/ s:sched.h:_sched.h:' screen.h || die

	# Fix manpage.
	sed -i \
		-e "s:/usr/local/etc/screenrc:${EPREFIX}/etc/screenrc:g" \
		-e "s:/usr/local/screens:${EPREFIX}/run/screen:g" \
		-e "s:/local/etc/screenrc:${EPREFIX}/etc/screenrc:g" \
		-e "s:/etc/utmp:${EPREFIX}/var/run/utmp:g" \
		-e "s:/local/screens/S-:${EPREFIX}/run/screen/S-:g" \
		doc/screen.1 \
		|| die "sed doc/screen.1 failed"

	# reconfigure
	eautoreconf
}

src_configure() {
	append-cppflags "-DMAXWIN=${MAX_SCREEN_WINDOWS:-100}"

	[[ ${CHOST} == *-solaris* ]] && append-libs -lsocket -lnsl

	use nethack || append-cppflags "-DNONETHACK"
	use debug && append-cppflags "-DDEBUG"

	econf \
		--with-socket-dir="${EPREFIX}/run/screen" \
		--with-sys-screenrc="${EPREFIX}/etc/screenrc" \
		--with-pty-mode=0620 \
		--with-pty-group=5 \
		--enable-rxvt_osc \
		--enable-telnet \
		--enable-colors256 \
		$(use_enable pam)

	LC_ALL=POSIX emake term.h
	emake osdef.h

	emake -C doc screen.info
}

src_install() {
	local tmpfiles_perms tmpfiles_group

	dobin screen

	if use multiuser || use prefix
	then
		fperms 4755 /usr/bin/screen
		tmpfiles_perms="0755"
		tmpfiles_group="root"
	else
		fowners root:utmp /usr/bin/screen
		fperms 2755 /usr/bin/screen
		tmpfiles_perms="0775"
		tmpfiles_group="utmp"
	fi

	dodir /etc/tmpfiles.d
	echo "d /run/screen ${tmpfiles_perms} root ${tmpfiles_group}" >"${ED}"/etc/tmpfiles.d/screen.conf

	insinto /usr/share/screen
	doins terminfo/{screencap,screeninfo.src}
	insinto /usr/share/screen/utf8encodings
	doins utf8encodings/??
	insinto /etc
	doins "${FILESDIR}"/screenrc

	pamd_mimic_system screen auth

	dodoc \
		README ChangeLog INSTALL TODO NEWS* patchlevel.h \
		doc/{FAQ,README.DOTSCREEN,fdpat.ps,window_to_display.ps}

	doman doc/screen.1
	doinfo doc/screen.info
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]
	then
		elog "Some dangerous key bindings have been removed or changed to more safe values."
		elog "We enable some xterm hacks in our default screenrc, which might break some"
		elog "applications. Please check /etc/screenrc for information on these changes."
	fi

	ewarn "This revision changes the screen socket location to /run/screen."
}