[gentoo-commits] repo/gentoo:master commit in: dev-lua/lua-openssl/

[Conrad Kostecki]

commit:     41f5da67eb8b9f4d570b6c35c96a21e93c56f82f
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 24 17:58:51 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Jan 27 19:40:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41f5da67

dev-lua/lua-openssl: drop old version

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-lua/lua-openssl/lua-openssl-0.7.8_p0-r3.ebuild | 99 ----------------------
 1 file changed, 99 deletions(-)

diff --git a/dev-lua/lua-openssl/lua-openssl-0.7.8_p0-r3.ebuild b/dev-lua/lua-openssl/lua-openssl-0.7.8_p0-r3.ebuild
deleted file mode 100644
index 88652952c1f..00000000000
--- a/dev-lua/lua-openssl/lua-openssl-0.7.8_p0-r3.ebuild
+++ /dev/null
@@ -1,99 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-EGIT_COMMIT_AUX="8d09895473b73e4fb72b7573615f69c36e1860a2"
-MY_PN_AUX="lua-auxiliar"
-MY_PN_COMPAT="lua-compat-5.3"
-MY_PV="${PV//_p/-}"
-MY_PV_COMPAT="0.10"
-
-inherit toolchain-funcs
-
-DESCRIPTION="OpenSSL binding for Lua"
-HOMEPAGE="https://github.com/zhaozg/lua-openssl"
-SRC_URI="
-	https://github.com/zhaozg/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/zhaozg/${MY_PN_AUX}/archive/${EGIT_COMMIT_AUX}.tar.gz -> ${MY_PN_AUX}-${EGIT_COMMIT_AUX}.tar.gz
-	https://github.com/keplerproject/${MY_PN_COMPAT}/archive/v${MY_PV_COMPAT}.tar.gz -> ${MY_PN_COMPAT}-${MY_PV_COMPAT}.tar.gz
-"
-S="${WORKDIR}/${PN}-${MY_PV}"
-
-LICENSE="MIT openssl PHP-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="libressl luajit test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	!dev-lua/luaossl
-	!dev-lua/luasec
-	luajit? ( dev-lang/luajit:2 )
-	!luajit? ( >=dev-lang/lua-5.1:0 )
-	libressl? ( dev-libs/libressl:0= )
-	!libressl? ( dev-libs/openssl:0=[-bindist] )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	test? ( ${RDEPEND} )
-"
-
-DOCS=( "README.md" "samples/." )
-
-src_prepare() {
-	default
-
-	# Allow override of LUA* variables
-	sed -e '/LUA  /s/:=/?=/g' -e '/LUA_VERSION/s/:=/?=/g' -i Makefile || die
-
-	# Prepare needed dependencies (source code files only)
-	rm -r deps/{auxiliar,lua-compat} || die
-	mv "${WORKDIR}/${MY_PN_AUX}-${EGIT_COMMIT_AUX}" deps/auxiliar || die
-	mv "${WORKDIR}/${MY_PN_COMPAT}-${MY_PV_COMPAT}" deps/lua-compat || die
-}
-
-src_compile() {
-	local myemakeargs=(
-		"AR=$(tc-getAR)"
-		"CC=$(tc-getCC)"
-		"LUA="
-		"LUA_CFLAGS=${CFLAGS} -I$($(tc-getPKG_CONFIG) --variable includedir $(usex luajit 'luajit' 'lua'))"
-		"LUA_LIBS=${LDFLAGS}"
-		"LUA_VERSION=$($(tc-getPKG_CONFIG) --variable $(usex luajit 'abiver' 'V') $(usex luajit 'luajit' 'lua'))"
-		"TARGET_SYS=${CTARGET:-${CHOST}}"
-	)
-
-	emake "${myemakeargs[@]}"
-}
-
-src_test() {
-	local myemakeargs=(
-		"LUA=$(usex luajit 'luajit' 'lua')"
-		"LUA_CFLAGS="
-		"LUA_LIBS="
-		"LUA_VERSION=$($(tc-getPKG_CONFIG) --variable $(usex luajit 'abiver' 'V') $(usex luajit 'luajit' 'lua'))"
-		"TARGET_SYS=${CTARGET:-${CHOST}}"
-	)
-
-	emake "${myemakeargs[@]}" test
-}
-
-src_install() {
-	local myemakeargs=(
-		"LUA="
-		"LUA_CFLAGS="
-		"LUA_LIBDIR=${ED}/$($(tc-getPKG_CONFIG) --variable INSTALL_CMOD $(usex luajit 'luajit' 'lua'))"
-		"LUA_LIBS="
-		"LUA_VERSION=$($(tc-getPKG_CONFIG) --variable $(usex luajit 'abiver' 'V') $(usex luajit 'luajit' 'lua'))"
-		"TARGET_SYS=${CTARGET:-${CHOST}}"
-	)
-
-	emake "${myemakeargs[@]}" install
-
-	insinto "$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD $(usex luajit 'luajit' 'lua'))"
-	doins -r "lib/."
-
-	einstalldocs
-}