[gentoo-commits] gentoo-x86 commit in app-admin/ansible: ansible-1.3.4.ebuild ChangeLog ansible-1.2.1.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    13/11/22 12:07:46

  Modified:             ChangeLog
  Added:                ansible-1.3.4.ebuild
  Removed:              ansible-1.2.1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.28                 app-admin/ansible/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	11 Oct 2013 11:30:57 -0000	1.27
+++ ChangeLog	22 Nov 2013 12:07:46 -0000	1.28
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/ansible
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.27 2013/10/11 11:30:57 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.28 2013/11/22 12:07:46 pinkbyte Exp $
+
+*ansible-1.3.4 (22 Nov 2013)
+
+  22 Nov 2013; Sergey Popov <pinkbyte@g.o> -ansible-1.2.1.ebuild,
+  +ansible-1.3.4.ebuild:
+  Version bump, drop old
 
 *ansible-1.3.3 (11 Oct 2013)
 



1.1                  app-admin/ansible/ansible-1.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.3.4.ebuild?rev=1.1&content-type=text/plain

Index: ansible-1.3.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-1.3.4.ebuild,v 1.1 2013/11/22 12:07:46 pinkbyte Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1 readme.gentoo

DESCRIPTION="Radically simple deployment, model-driven configuration management, and command execution framework"
HOMEPAGE="http://ansible.cc/"
SRC_URI="https://github.com/ansible/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

KEYWORDS="~amd64 ~x86"
LICENSE="GPL-3"
SLOT="0"
IUSE="test"

DEPEND="test? (
		dev-python/nose
		dev-vcs/git
	)"
RDEPEND="
	dev-python/jinja
	dev-python/pyyaml
	dev-python/paramiko
	net-misc/sshpass
	virtual/ssh
"

DOC_CONTENTS="You can define parameters through shell variables OR use config files
Examples of config files installed in /usr/share/doc/${PF}/examples\n\n
You have to create ansible hosts file!\n
More info on http://ansible.cc/docs/gettingstarted.html"

python_prepare_all() {
	distutils-r1_python_prepare_all
	# Skip tests which need ssh access
	sed -i 's:$(NOSETESTS) -d -v:\0 -e \\(TestPlayBook.py\\|TestRunner.py\\):' Makefile || die "sed failed"
}

python_test() {
	make tests || die "tests failed"
}

python_install_all() {
	distutils-r1_python_install_all

	doman docs/man/man1/*.1
	dodoc -r examples
	docompress -x /usr/share/doc/${PF}/examples
	# Hint: do not install example config files into /etc
	# let this choice to user

	newenvd "${FILESDIR}"/${PN}.env 95ansible
}

src_install() {
	distutils-r1_src_install
	readme.gentoo_create_doc
}