[gentoo-commits] gentoo-x86 commit in sys-apps/pciutils: pciutils-3.1.9-r2.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/04/01 01:47:34

  Modified:             ChangeLog
  Added:                pciutils-3.1.9-r2.ebuild
  Log:
  Make use of the new hwids ebuild.
  
  (Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

Revision  Changes    Path
1.194                sys-apps/pciutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pciutils/ChangeLog?r1=1.193&r2=1.194

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog	25 Mar 2012 15:43:46 -0000	1.193
+++ ChangeLog	1 Apr 2012 01:47:34 -0000	1.194
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pciutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.193 2012/03/25 15:43:46 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.194 2012/04/01 01:47:34 flameeyes Exp $
+
+*pciutils-3.1.9-r2 (01 Apr 2012)
+
+  01 Apr 2012; Diego E. Pettenò <flameeyes@g.o>
+  +pciutils-3.1.9-r2.ebuild:
+  Make use of the new hwids ebuild.
 
   25 Mar 2012; Markus Meier <maekke@g.o> pciutils-3.1.9-r1.ebuild:
   arm stable, bug #407831



1.1                  sys-apps/pciutils/pciutils-3.1.9-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pciutils/pciutils-3.1.9-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pciutils/pciutils-3.1.9-r2.ebuild?rev=1.1&content-type=text/plain

Index: pciutils-3.1.9-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/pciutils-3.1.9-r2.ebuild,v 1.1 2012/04/01 01:47:34 flameeyes Exp $

EAPI="4"

inherit eutils multilib toolchain-funcs

DESCRIPTION="Various utilities dealing with the PCI bus"
HOMEPAGE="http://atrey.karlin.mff.cuni.cz/~mj/pciutils.html"
SRC_URI="ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="static-libs zlib"

DEPEND="zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	sys-apps/hwids"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.1.7-install-lib.patch #273489
	epatch "${FILESDIR}"/${PN}-3.1.7-fbsd.patch #262321

	if use static-libs ; then
		cp -pPR "${S}" "${S}.static" || die
	fi
}

pemake() {
	emake \
		HOST="${CHOST}" \
		CROSS_COMPILE="${CHOST}-" \
		CC="$(tc-getCC)" \
		DNS="yes" \
		IDSDIR='$(SHAREDIR)/misc' \
		MANDIR='$(SHAREDIR)/man' \
		PREFIX="${EPREFIX}/usr" \
		SHARED="yes" \
		STRIP="" \
		ZLIB=$(usex zlib) \
		PCI_COMPRESSED_IDS=0 \
		PCI_IDS=pci.ids \
		LIBDIR="\${PREFIX}/$(get_libdir)" \
		"$@"
}

src_compile() {
	pemake OPT="${CFLAGS}" all
	if use static-libs ; then
		pemake \
			-C "${S}.static" \
			OPT="${CFLAGS}" \
			SHARED="no" \
			lib/libpci.a
	fi
}

src_install() {
	pemake DESTDIR="${D}" install install-lib
	use static-libs && dolib.a "${S}.static/lib/libpci.a"
	dodoc ChangeLog README TODO

	rm "${D}"/usr/bin/update-pciids "${D}"/usr/share/misc/pci.ids \
		"${D}"/usr/share/man/man8/update-pciids.8*

	newinitd "${FILESDIR}"/init.d-pciparm pciparm
	newconfd "${FILESDIR}"/conf.d-pciparm pciparm
}

pkg_postinst() {
	elog "The 'pcimodules' program has been replaced by 'lspci -k'"
	elog ""
	elog "The 'network-cron' USE flag is gone; if you want a more up-to-date"
	elog "pci.ids file, you should use sys-apps/hwids-99999999 (live ebuild)."
}