[gentoo-commits] repo/gentoo:master commit in: dev-util/sysprof/

[Mart Raudsepp]

commit:     22afdee512629291c1afa1f11ded21f707a5ccbc
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 18 11:11:27 2017 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Tue Apr 18 11:11:27 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=22afdee5

dev-util/sysprof: bump to 3.24.1

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-util/sysprof/Manifest              |  1 +
 dev-util/sysprof/sysprof-3.24.1.ebuild | 60 ++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-util/sysprof/Manifest b/dev-util/sysprof/Manifest
index 6a174eda44f..07c4c317e02 100644
--- a/dev-util/sysprof/Manifest
+++ b/dev-util/sysprof/Manifest
@@ -1 +1,2 @@
 DIST sysprof-3.22.2.tar.xz 581864 SHA256 d57fb19a3e5d4ad37d5fb554dc93d9a03f332779c3bffd9c2aa8f176e85269d7 SHA512 601e83f8809bfc970b87a8cbecfc868e957d992aa554316e80b44f21c97a58ef0a236e0b0bda6accc01d5d551f7fca76b4882863a9ea498578731b49dc75322c WHIRLPOOL fdb2bcf0ee191bcecdda93fa3bc9d78aae5301e5fb2f0706021e1b2425d93a2d8ae16472a584ed172b864044b096c66f5c3ef714c848af63937d7dfe40736377
+DIST sysprof-3.24.1.tar.xz 595920 SHA256 054eebe2afb6fe3c06ac8c46bc045c42f675d4fd64e6f16cbc602d5c7ce27bec SHA512 5d323bcb9923c511065132711963dc8856c4d837b4d7ccfae5cc5794be5ac8ad1dc42504025469199f4bfd6a6fad4d8f49b7b21cab6f0c9a954820182e75c7d0 WHIRLPOOL e4cc8391b9583f4e2633e89b5cf18445f9d2c6324dcb4b1b00e2e5742441688c16d514701d5f4077f2579e854dbbfec5058e97d6f37b32b7ba8a812354668ce8

diff --git a/dev-util/sysprof/sysprof-3.24.1.ebuild b/dev-util/sysprof/sysprof-3.24.1.ebuild
new file mode 100644
index 00000000000..93e9abc09be
--- /dev/null
+++ b/dev-util/sysprof/sysprof-3.24.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2 linux-info systemd
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug gtk systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	gtk? ( >=x11-libs/gtk+-3.22.0:3 )
+	systemd? (
+		sys-auth/polkit
+		>=sys-apps/systemd-222 )
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=sys-devel/gettext-0.19.6
+	>=sys-kernel/linux-headers-2.6.32
+	dev-libs/appstream-glib
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	kernel_is -ge 2 6 31 && return
+	die "Sysprof will not work with a kernel version less than 2.6.31"
+}
+
+src_configure() {
+	# introspection & vala not use in build system
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gtk) \
+		--disable-introspection \
+		--disable-static \
+		--disable-vala \
+		--with-sysprofd=$(usex systemd bundled no) \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+}