[gentoo-commits] gentoo-x86 commit in dev-java/xpp2: xpp2-2.1.10-r2.ebuild ChangeLog

[James Le Cuirot (chewi)]

chewi       15/06/23 23:12:46

  Modified:             ChangeLog
  Added:                xpp2-2.1.10-r2.ebuild
  Log:
  EAPI bump and general rewrite in the new style. Tests added but they
  sadly fail. I wish we could kill this but it's in a string of ancient
  dependencies.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 9C6D7DE4)

Revision  Changes    Path
1.31                 dev-java/xpp2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xpp2/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xpp2/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xpp2/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/xpp2/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	27 Jun 2013 21:40:45 -0000	1.30
+++ ChangeLog	23 Jun 2015 23:12:46 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/xpp2
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/xpp2/ChangeLog,v 1.30 2013/06/27 21:40:45 aballier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/xpp2/ChangeLog,v 1.31 2015/06/23 23:12:46 chewi Exp $
+
+*xpp2-2.1.10-r2 (23 Jun 2015)
+
+  23 Jun 2015; James Le Cuirot <chewi@g.o> +xpp2-2.1.10-r2.ebuild:
+  EAPI bump and general rewrite in the new style. Tests added but they sadly
+  fail. I wish we could kill this but it's in a string of ancient dependencies.
 
   27 Jun 2013; Alexis Ballier <aballier@g.o> xpp2-2.1.10-r1.ebuild:
   keyword ~amd64-fbsd



1.1                  dev-java/xpp2/xpp2-2.1.10-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xpp2/xpp2-2.1.10-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xpp2/xpp2-2.1.10-r2.ebuild?rev=1.1&content-type=text/plain

Index: xpp2-2.1.10-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/xpp2/xpp2-2.1.10-r2.ebuild,v 1.1 2015/06/23 23:12:46 chewi Exp $

EAPI=5
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

MY_PN="PullParser"
MY_P="${MY_PN}${PV}"

DESCRIPTION="A streaming pull XML parser used to quickly process input elements"
HOMEPAGE="http://www.extreme.indiana.edu/xgws/xsoap/xpp/mxp1/index.html"
SRC_URI="http://www.extreme.indiana.edu/xgws/xsoap/xpp/download/${MY_PN}2/${MY_P}.tgz"

LICENSE="Apache-1.1 IBM"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="test"

# Some failures, partly because we haven't patched Xerces but probably
# also because this software is ancient. :(
RESTRICT="test"

CDEPEND="dev-java/xerces:2"
DEPEND=">=virtual/jdk-1.3
	test? ( dev-java/junit:4 )
	${CDEPEND}"
RDEPEND=">=virtual/jre-1.3
	${CDEPEND}"

S="${WORKDIR}/${MY_P}"

EANT_GENTOO_CLASSPATH="xerces-2"
EANT_EXTRA_ARGS="-Dx2_present=true -Djunit.present=true"
EANT_BUILD_TARGET="intf intf_jar impl x2impl"
EANT_DOC_TARGET="api"
EANT_TEST_TARGET="junit"

java_prepare() {
	rm -r build/ lib/ || die

	# Our usual rewriting stomps over the existing classpath, which
	# isn't helpful here.
	sed -i -r \
		-e 's/\bclasspath="/\0${gentoo.classpath}:/g' \
		-e 's/\$\{java\.class\.path\}/${gentoo.classpath}/g' \
		build.xml || die
}

src_install() {
	local suffix

	for suffix in "" -intf -standard -x2; do
		java-pkg_newjar build/lib/${MY_PN}${suffix}-${PV}.jar ${MY_PN}${suffix}.jar
	done

	dodoc README.html
	use doc && java-pkg_dojavadoc doc/api
	use source && java-pkg_dosrc $(find src/java -name org -o -name javax)
}

src_test() {
	java-pkg-2_src_test
}