[gentoo-commits] gentoo-x86 commit in net-analyzer/fail2ban: fail2ban-0.8.6.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/12/30 10:18:51

  Modified:             ChangeLog
  Added:                fail2ban-0.8.6.ebuild
  Log:
  Version bump. Bug #392481
  
  (Portage version: 2.2.0_alpha82/cvs/Linux x86_64)

Revision  Changes    Path
1.75                 net-analyzer/fail2ban/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	15 Dec 2011 08:50:08 -0000	1.74
+++ ChangeLog	30 Dec 2011 10:18:51 -0000	1.75
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/fail2ban
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v 1.74 2011/12/15 08:50:08 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v 1.75 2011/12/30 10:18:51 hwoarang Exp $
+
+*fail2ban-0.8.6 (30 Dec 2011)
+
+  30 Dec 2011; Markos Chandras <hwoarang@g.o> +fail2ban-0.8.6.ebuild,
+  +files/fail2ban-0.8.6-sshd-breakin.patch:
+  Version bump. Bug #392481
 
 *fail2ban-0.8.4-r4 (15 Dec 2011)
 



1.1                  net-analyzer/fail2ban/fail2ban-0.8.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.6.ebuild?rev=1.1&content-type=text/plain

Index: fail2ban-0.8.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.6.ebuild,v 1.1 2011/12/30 10:18:51 hwoarang Exp $

EAPI="3"
PYTHON_DEPEND="2"

inherit distutils eutils

DESCRIPTION="Bans IP that make too many password failures"
HOMEPAGE="http://fail2ban.sourceforge.net/"
SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="selinux"

DEPEND="selinux? ( sec-policy/selinux-fail2ban )"
RDEPEND="net-misc/whois
	virtual/mta
	net-firewall/iptables
	selinux? ( sec-policy/selinux-fail2ban )"

S="${WORKDIR}"/${PN}-${PN}-a20d1f8

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-sshd-breakin.patch
	distutils_src_prepare
}

src_install() {
	distutils_src_install

	newconfd files/gentoo-confd fail2ban || die
	newinitd files/gentoo-initd fail2ban || die
	dodoc ChangeLog README TODO || die "dodoc failed"
	doman man/*.1 || die "doman failed"

	# Use INSTALL_MASK  if you do not want to touch /etc/logrotate.d.
	# See http://thread.gmane.org/gmane.linux.gentoo.devel/35675
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${PN}-logrotate ${PN} || die
}

pkg_preinst() {
	has_version "<${CATEGORY}/${PN}-0.7"
	previous_less_than_0_7=$?
}

pkg_postinst() {
	distutils_pkg_postinst

	if [[ $previous_less_than_0_7 = 0 ]] ; then
		elog
		elog "Configuration files are now in /etc/fail2ban/"
		elog "You probably have to manually update your configuration"
		elog "files before restarting Fail2ban!"
		elog
		elog "Fail2ban is not installed under /usr/lib anymore. The"
		elog "new location is under /usr/share."
		elog
		elog "You are upgrading from version 0.6.x, please see:"
		elog "http://www.fail2ban.org/wiki/index.php/HOWTO_Upgrade_from_0.6_to_0.8"
	fi
}