1 |
commit: 47b068ed565fccf8100395406f27e3fd2fd1ff3c |
2 |
Author: Michał Górny <mgorny <AT> gentoo <DOT> org> |
3 |
AuthorDate: Tue Feb 1 08:34:06 2022 +0000 |
4 |
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org> |
5 |
CommitDate: Tue Feb 1 10:06:43 2022 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=47b068ed |
7 |
|
8 |
dev-python/django: Bump to 4.0.2 |
9 |
|
10 |
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org> |
11 |
|
12 |
dev-python/django/Manifest | 2 + |
13 |
dev-python/django/django-4.0.2.ebuild | 103 ++++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 105 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest |
17 |
index 15b2ebb1a2e2..c0494f7bcb24 100644 |
18 |
--- a/dev-python/django/Manifest |
19 |
+++ b/dev-python/django/Manifest |
20 |
@@ -4,3 +4,5 @@ DIST Django-3.2.11.checksum.txt 2561 BLAKE2B ece4f40d4d368e2e5ad3cc3ed6072aa8d16 |
21 |
DIST Django-3.2.11.tar.gz 9821958 BLAKE2B 8f83db578e31c3cbeca67bd826b4c639b346e449de83aba6ddf6bf4eef1fc58ebcbbddf91227012e592516d7796d9f3cc468ae4ce51d684b4aa0a417bb39ddb1 SHA512 ea1ca9a76afcd7e20d0ce518efc0497bbd11f4ab7ed20bd4490561bfcfc6c80db8922a22d8aca94c1dc2743e7366b28a0ae76c3d64f55afc142c38a744dd5120 |
22 |
DIST Django-4.0.1.checksum.txt 2552 BLAKE2B 123a613af7ff1ccb423c11086501a4419d86cf07c0ae7a4751f12d32f1592916e72e3e47cee13192944a3fc05ce5ee7ac81038118e346545536f313a10783de6 SHA512 979a7c5efafd4d8923d6c769ddd7d73c67482c33fd1a76c64d75aee0a03399e35703e7cbde9f5ad25baab969c33ab53690400e39c879e54066a146944e5d0ee1 |
23 |
DIST Django-4.0.1.tar.gz 9995484 BLAKE2B af05ec1ec1d079e383efc590de78413b7fd769e7f03c5d4bdcfd26f193a46f783b4c3428558f5d3281cab9a7fa8be4cfecdc4edaf1bea72f37e8e983b3c061f1 SHA512 7753c516b080c10673c3a95e8ec4af00984aeed5f288e4d6e7ab1efd461222a343701b21cfd27bc61ee4e63df5ce3f3be49398490a995f6839e63b40c3fe306c |
24 |
+DIST Django-4.0.2.checksum.txt 2547 BLAKE2B 532139126846e1758bbe7b4dc4ad4aad6c6b3607e298f4373366239637ceca7d01a26472b2a87917e64db7140d28a76c1f5fbb396e7022b1a42b723551770d1f SHA512 eddd8ac31fc60f803f1e6f975c079e84e5ef997e8ac93b7dcf3573bd0c5d057adeb6f092acaecb200529044d81aa2db9849c1c13525678c8c2bd27bd14d6b280 |
25 |
+DIST Django-4.0.2.tar.gz 9996300 BLAKE2B 422b0bb000e7f62a854dc8fa686001acc3f629ded462d2520fad9486a9c8eb5d501d29c6a9f30f63ff8da128ded6f40281439371eb688fb9bc95f2377c5ca0f7 SHA512 c64b25aa69b826805cc7a3efcd63ae41bbc31a61e68cdbda90e6bcec6bd8e2c5fc47b82176d0c1708f55d2c7b082c71939b89cb0621fcf1929d1475e3d393a97 |
26 |
|
27 |
diff --git a/dev-python/django/django-4.0.2.ebuild b/dev-python/django/django-4.0.2.ebuild |
28 |
new file mode 100644 |
29 |
index 000000000000..69f33e23fb87 |
30 |
--- /dev/null |
31 |
+++ b/dev-python/django/django-4.0.2.ebuild |
32 |
@@ -0,0 +1,103 @@ |
33 |
+# Copyright 1999-2022 Gentoo Authors |
34 |
+# Distributed under the terms of the GNU General Public License v2 |
35 |
+ |
36 |
+EAPI=8 |
37 |
+ |
38 |
+PYTHON_COMPAT=( python3_{8..10} ) |
39 |
+PYTHON_REQ_USE='sqlite?,threads(+)' |
40 |
+ |
41 |
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig |
42 |
+ |
43 |
+MY_P=${P^} |
44 |
+DESCRIPTION="High-level Python web framework" |
45 |
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/" |
46 |
+SRC_URI=" |
47 |
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz |
48 |
+ verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )" |
49 |
+S="${WORKDIR}/${MY_P}" |
50 |
+ |
51 |
+LICENSE="BSD" |
52 |
+# admin fonts: Roboto (media-fonts/roboto) |
53 |
+LICENSE+=" Apache-2.0" |
54 |
+# admin icons, jquery, xregexp.js |
55 |
+LICENSE+=" MIT" |
56 |
+SLOT="0" |
57 |
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos" |
58 |
+IUSE="doc sqlite test" |
59 |
+RESTRICT="!test? ( test )" |
60 |
+ |
61 |
+RDEPEND=" |
62 |
+ >=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}] |
63 |
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}] |
64 |
+ $(python_gen_cond_dep ' |
65 |
+ dev-python/backports-zoneinfo[${PYTHON_USEDEP}] |
66 |
+ ' python3_8 pypy3)" |
67 |
+BDEPEND=" |
68 |
+ test? ( |
69 |
+ $(python_gen_impl_dep sqlite) |
70 |
+ ${RDEPEND} |
71 |
+ dev-python/docutils[${PYTHON_USEDEP}] |
72 |
+ dev-python/jinja[${PYTHON_USEDEP}] |
73 |
+ dev-python/numpy[${PYTHON_USEDEP}] |
74 |
+ dev-python/pillow[webp,${PYTHON_USEDEP}] |
75 |
+ dev-python/pyyaml[${PYTHON_USEDEP}] |
76 |
+ dev-python/selenium[${PYTHON_USEDEP}] |
77 |
+ dev-python/tblib[${PYTHON_USEDEP}] |
78 |
+ sys-devel/gettext |
79 |
+ !!<dev-python/ipython-7.21.0-r1 |
80 |
+ !!=dev-python/ipython-7.22.0-r0 |
81 |
+ ) |
82 |
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 ) |
83 |
+" |
84 |
+ |
85 |
+PATCHES=( |
86 |
+ "${FILESDIR}"/${PN}-4.0-bashcomp.patch |
87 |
+) |
88 |
+ |
89 |
+distutils_enable_sphinx docs --no-autodoc |
90 |
+ |
91 |
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc |
92 |
+ |
93 |
+src_unpack() { |
94 |
+ if use verify-sig; then |
95 |
+ cd "${DISTDIR}" || die |
96 |
+ verify-sig_verify_signed_checksums \ |
97 |
+ "${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz" |
98 |
+ cd "${WORKDIR}" || die |
99 |
+ fi |
100 |
+ |
101 |
+ default |
102 |
+} |
103 |
+ |
104 |
+python_prepare_all() { |
105 |
+ # Fails because of warnings |
106 |
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py |
107 |
+ |
108 |
+ distutils-r1_python_prepare_all |
109 |
+} |
110 |
+ |
111 |
+python_test() { |
112 |
+ # Tests have non-standard assumptions about PYTHONPATH, |
113 |
+ # and don't work with ${BUILD_DIR}/lib. |
114 |
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 || |
115 |
+ die "Tests fail with ${EPYTHON}" |
116 |
+} |
117 |
+ |
118 |
+python_install_all() { |
119 |
+ newbashcomp extras/django_bash_completion ${PN}-admin |
120 |
+ bashcomp_alias ${PN}-admin django-admin.py |
121 |
+ |
122 |
+ distutils-r1_python_install_all |
123 |
+} |
124 |
+ |
125 |
+pkg_postinst() { |
126 |
+ optfeature_header "Additional Backend support can be enabled via:" |
127 |
+ optfeature "MySQL backend support" dev-python/mysqlclient |
128 |
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2 |
129 |
+ optfeature_header |
130 |
+ optfeature "GEO Django" "sci-libs/gdal[geos]" |
131 |
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached |
132 |
+ optfeature "ImageField Support" dev-python/pillow |
133 |
+ optfeature "Password encryption" dev-python/bcrypt |
134 |
+ optfeature "High-level abstractions for Django forms" dev-python/django-formtools |
135 |
+} |