[gentoo-commits] gentoo-x86 commit in sys-fs/ntfsprogs: ChangeLog ntfsprogs-2.0.0-r1.ebuild

[Mike Frysinger (vapier)]

vapier      08/04/20 19:34:57

  Modified:             ChangeLog
  Added:                ntfsprogs-2.0.0-r1.ebuild
  Log:
  Install the "extra" binaries #218601 by fdupoux.
  (Portage version: 2.2_pre5)

Revision  Changes    Path
1.60                 sys-fs/ntfsprogs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ntfsprogs/ChangeLog?rev=1.60&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ntfsprogs/ChangeLog?rev=1.60&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ntfsprogs/ChangeLog?r1=1.59&r2=1.60

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/ntfsprogs/ChangeLog,v
retrieving revision 1.59
retrieving revision 1.60
diff -u -r1.59 -r1.60
--- ChangeLog	31 Mar 2008 21:23:51 -0000	1.59
+++ ChangeLog	20 Apr 2008 19:34:57 -0000	1.60
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/ntfsprogs
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfsprogs/ChangeLog,v 1.59 2008/03/31 21:23:51 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfsprogs/ChangeLog,v 1.60 2008/04/20 19:34:57 vapier Exp $
+
+*ntfsprogs-2.0.0-r1 (20 Apr 2008)
+
+  20 Apr 2008; Mike Frysinger <vapier@g.o>
+  +files/ntfsprogs-2.0.0-extras.patch, +ntfsprogs-2.0.0-r1.ebuild:
+  Install the "extra" binaries #218601 by fdupoux.
 
   31 Mar 2008; Markus Meier <maekke@g.o> ntfsprogs-2.0.0.ebuild:
   amd64 stable, bug #208918



1.1                  sys-fs/ntfsprogs/ntfsprogs-2.0.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ntfsprogs/ntfsprogs-2.0.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ntfsprogs/ntfsprogs-2.0.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: ntfsprogs-2.0.0-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfsprogs/ntfsprogs-2.0.0-r1.ebuild,v 1.1 2008/04/20 19:34:57 vapier Exp $

inherit eutils autotools

DESCRIPTION="User tools for NTFS filesystems"
HOMEPAGE="http://www.linux-ntfs.org/"
SRC_URI="mirror://sourceforge/linux-ntfs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="crypt debug fuse gnome minimal"

RDEPEND="dev-libs/libconfig
	fuse? ( >=sys-fs/fuse-2.7.0 )
	crypt? ( >=dev-libs/libgcrypt-1.2.0 >=net-libs/gnutls-1.2.8 )
	gnome? (
		>=dev-libs/glib-2.0
		>=gnome-base/gnome-vfs-2.0
	)"
DEPEND="${RDEPEND}
	!=sys-fs/ntfs3g-0.1_beta20070714
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-extras.patch #218601
	eautoreconf
	sed -i \
		-e '/CFLAGS/s:-ggdb3\>::' \
		-e '/CFLAGS/s:-O0\>::' \
		configure || die
}

src_compile() {
	econf \
		$(use_enable !minimal extras) \
		$(use_enable crypt crypto) \
		$(use_enable debug) \
		$(use_enable fuse fuse-module) \
		$(use_enable gnome gnome-vfs) \
		|| die "Configure failed"
	emake || die "Make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	mv "${D}"/sbin/mkfs.ntfs "${D}"/usr/sbin/ || die
	mv "${D}"/sbin/mount.{fuse.ntfs,ntfs-fuse} "${D}"/usr/bin/ || die
	mv "${D}"/usr/bin/ntfsck "${D}"/sbin/ || die
	dosym ntfsck /sbin/fsck.ntfs

	dodoc AUTHORS CREDITS ChangeLog NEWS README TODO.* \
		doc/attribute_definitions doc/*.txt doc/tunable_settings
}



-- 
gentoo-commits@l.g.o mailing list