[gentoo-commits] repo/gentoo:master commit in: x11-misc/lightdm-gtk-greeter/

[Lars Wendler]

commit:     1f19782261dc0b423f69c7700da9466f6b49e2f9
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 27 15:02:09 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Feb 27 15:03:06 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f197822

x11-misc/lightdm-gtk-greeter: Bump to version 2.0.4

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 x11-misc/lightdm-gtk-greeter/Manifest              |  1 +
 .../lightdm-gtk-greeter-2.0.4.ebuild               | 76 ++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/x11-misc/lightdm-gtk-greeter/Manifest b/x11-misc/lightdm-gtk-greeter/Manifest
index 42a7572760a..82c7fbe8246 100644
--- a/x11-misc/lightdm-gtk-greeter/Manifest
+++ b/x11-misc/lightdm-gtk-greeter/Manifest
@@ -2,3 +2,4 @@ DIST lightdm-gentoo-patch-2.tar.gz 695543 BLAKE2B 62e21dd413b90053160f774663d89c
 DIST lightdm-gtk-greeter-2.0.1.tar.gz 467375 BLAKE2B 9b6e4c597b0dcace770609f7bbe55dac627445b609619b7965566e964f1584bb75ed3ff7d45567dbdded5fb777578043990b9f8ba6f17d27951adf222740cee8 SHA512 fd41cae828f7feafb462143519500d0d98a8b6729eb5ffd9be4247d47fa0074fa00ac9892c8cbdda9d7656e9d6949ae65e69911ae911269e99e80e4fefb19a08
 DIST lightdm-gtk-greeter-2.0.2.tar.gz 487825 BLAKE2B e17b7528365154d9d5b80664c93deac3d6af2ed5c4be6829fff0f9500ad0e0dd8d57504052d34dbfcee8db2a1b14887d8002d42f185573f8fac01a43e618c4d3 SHA512 6a9b62d3eb94a223df30c0e7ef577645482e63f9ac9cce6466518bb7eabfca3915dba8dbe66dee7456a1f11f81869dc8685b98828b11ae0dd67aa021a9a1d6db
 DIST lightdm-gtk-greeter-2.0.3.tar.gz 490512 BLAKE2B 93aa086d520ed04bef5eda8f5c8afdf8f4d15f2b2b130fb889adc0a4270916d9a0151e20963f7dc8ec1f09c9f00a5966b49c3bd03ead048c63291a42486ede8e SHA512 bd5b18890cf0190faab0e6a2bffab67be359e99f45fda0be7eecded146d2518a4efc0fd4fd29970076246bb989f626dd750cb14b22ddf6188b2be5f113bff3b0
+DIST lightdm-gtk-greeter-2.0.4.tar.gz 566819 BLAKE2B 21b11a12e2af82e5548a72617da5b592a067a5fb883aa68e8076f3ec3793691a0e957da22ff49664334f67b3d7b20dda90bd02dce4bc4feadc18248e48125efc SHA512 d4dbcb7117ffd288b8a3a516423362ead837dfe83ea48cdf24056926d440900fefd22522868c39da2831dca861731b1a53f33a9db0d86c5e334e673a5dac3254

diff --git a/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.4.ebuild b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.4.ebuild
new file mode 100644
index 00000000000..bc0dac2f8c0
--- /dev/null
+++ b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit versionator gnome2-utils
+
+DESCRIPTION="LightDM GTK+ Greeter"
+HOMEPAGE="https://launchpad.net/lightdm-gtk-greeter"
+SRC_URI="https://launchpad.net/lightdm-gtk-greeter/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz
+	branding? ( https://dev.gentoo.org/~hwoarang/distfiles/lightdm-gentoo-patch-2.tar.gz )"
+
+LICENSE="GPL-3 LGPL-3
+	branding? ( CC-BY-3.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="ayatana branding"
+
+COMMON_DEPEND="ayatana? ( dev-libs/libindicator:3 )
+	x11-libs/gtk+:3
+	>=x11-misc/lightdm-1.2.2"
+
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	xfce-base/exo"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/gnome-themes-standard
+	>=x11-themes/adwaita-icon-theme-3.14.1"
+
+GENTOO_BG="gentoo-bg_65.jpg"
+
+src_prepare() {
+	# Ok, this has to be fixed in the tarball but I am too lazy to do it.
+	# I will fix this once I decide to update the tarball with a new gentoo
+	# background
+	# Bug #404467
+	if use branding; then
+		sed -i -e "/xft-hintstyle/s:slight:hintslight:" \
+			"${WORKDIR}"/${PN}.conf || die
+	fi
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-kill-on-sigterm
+		--enable-at-spi-command="${EPREFIX}/usr/libexec/at-spi-bus-launcher --launch-immediately"
+		$(use_enable ayatana libindicator)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use branding; then
+		insinto /etc/lightdm/
+		doins "${WORKDIR}"/${PN}.conf
+		insinto /usr/share/lightdm/backgrounds/
+		doins "${WORKDIR}"/${GENTOO_BG}
+		sed -i -e \
+			"/background/s:=.*:=/usr/share/lightdm/backgrounds/${GENTOO_BG}:" \
+			"${D}"/etc/lightdm/${PN}.conf || die
+		newdoc "${WORKDIR}"/README.txt README-background.txt
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}