[gentoo-commits] repo/gentoo:master commit in: net-libs/gloox/

[Julian Ospald]

commit:     eb6fbf62bf7d65bc52b63f2437ad861d4d31b734
Author:     Julian Ospald <hasufell <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 30 20:21:07 2015 +0000
Commit:     Julian Ospald <hasufell <AT> gentoo <DOT> org>
CommitDate: Wed Sep 30 20:29:50 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb6fbf62

net-libs/gloox: add libressl support

 net-libs/gloox/gloox-1.0.14-r1.ebuild | 51 +++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/net-libs/gloox/gloox-1.0.14-r1.ebuild b/net-libs/gloox/gloox-1.0.14-r1.ebuild
new file mode 100644
index 0000000..c5b4696
--- /dev/null
+++ b/net-libs/gloox/gloox-1.0.14-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+MY_P="${P/_/-}"
+DESCRIPTION="A portable high-level Jabber/XMPP library for C++"
+HOMEPAGE="http://camaya.net/gloox"
+SRC_URI="http://camaya.net/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/13"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~ia64 ~sparc ~x86"
+IUSE="debug gnutls idn libressl ssl static-libs test zlib"
+
+DEPEND="idn? ( net-dns/libidn )
+	gnutls? ( net-libs/gnutls )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	zlib? ( sys-libs/zlib )"
+
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch_user
+}
+
+src_configure() {
+	# Examples are not installed anyway, so - why should we build them?
+	econf \
+		--without-examples \
+		$(use debug && echo "--enable-debug") \
+		$(use_enable static-libs static) \
+		$(use_with idn libidn) \
+		$(use_with gnutls) \
+		$(use_with ssl openssl) \
+		$(use_with test tests) \
+		$(use_with zlib)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}