[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-config/

[Andreas Sturmlechner]

commit:     356e16f0fd1f48bb3831152afca45ae07309abff
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 27 18:41:59 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed May 20 23:28:29 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=356e16f0

lxqt-base/lxqt-config: add version 0.15.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 lxqt-base/lxqt-config/Manifest                  |  1 +
 lxqt-base/lxqt-config/lxqt-config-0.15.0.ebuild | 74 +++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/lxqt-base/lxqt-config/Manifest b/lxqt-base/lxqt-config/Manifest
index 703c24268e9..b4d0b6dbfc0 100644
--- a/lxqt-base/lxqt-config/Manifest
+++ b/lxqt-base/lxqt-config/Manifest
@@ -1 +1,2 @@
 DIST lxqt-config-0.14.1.tar.xz 293304 BLAKE2B f090d7878815edc4f3f0078301a099ffc8ff57865516a9097db75faa1627af33c60d76b75cef8a7da5e9e790869e6768f54c3b17c59b038578f22d645c3c22fd SHA512 747644f8e0623cb2e8eadda57c7307387423152a089d5b423b06650fbf235371764a26e82363cbee9db5c1145e3fdb754e6ecdcf0930dccec375dda424c8b13f
+DIST lxqt-config-0.15.0.tar.xz 312468 BLAKE2B 2b3eb43141f3b46996b785b7cd19b709028c8cecc455a63578c93a9ae580148bc35df1192591bf0fdb5584d2cf66f589dbdde0d43c6848dda263d1f0b80e8c59 SHA512 68dc8ecc38033a7a93167fb0afbe45b3e14eb1132c3faf3395ebed1fc96b5836e8db003ecffde0417dfaf9e73b70fcc69a06523319f1f858cd2020eb61113a0d

diff --git a/lxqt-base/lxqt-config/lxqt-config-0.15.0.ebuild b/lxqt-base/lxqt-config/lxqt-config-0.15.0.ebuild
new file mode 100644
index 00000000000..833ebd052b1
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-0.15.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt.github.io/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.7.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	=lxqt-base/liblxqt-$(ver_cut 1-2)*
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:5= )
+	touchpad? (
+		virtual/libudev
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXext
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}