[gentoo-commits] repo/gentoo:master commit in: dev-python/httpretty/

[Michał Górny]

commit:     531b96fb745d5474c3f0b87668f5c8526baf6922
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 27 09:23:33 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 27 09:30:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=531b96fb

dev-python/httpretty: Add missing test deps

Closes: https://bugs.gentoo.org/719766
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/httpretty/httpretty-1.0.2-r1.ebuild | 46 ++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-python/httpretty/httpretty-1.0.2-r1.ebuild b/dev-python/httpretty/httpretty-1.0.2-r1.ebuild
new file mode 100644
index 00000000000..eb33b6f3b1d
--- /dev/null
+++ b/dev-python/httpretty/httpretty-1.0.2-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP client mock for Python"
+HOMEPAGE="https://github.com/gabrielfalcao/httpretty"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]"
+# redis skipped as it requires a redis server running
+DEPEND="
+	test? (
+		dev-python/eventlet[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/httplib2[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.2[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		>=dev-python/requests-1.1[${PYTHON_USEDEP}]
+		dev-python/sure[${PYTHON_USEDEP}]
+		>=www-servers/tornado-2.2[${PYTHON_USEDEP}]
+)"
+
+python_prepare_all() {
+	# remove useless deps
+	sed -i -e '/randomly/d' -e '/rednose/d' setup.cfg || die
+	# tests requiring network access
+	rm tests/functional/test_passthrough.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests || die "Tests fail with ${EPYTHON}"
+}