[gentoo-commits] gentoo-x86 commit in media-libs/glew: ChangeLog glew-1.6.0.ebuild

[Tim Harder (radhermit)]

radhermit    11/05/04 07:46:24

  Modified:             ChangeLog
  Added:                glew-1.6.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.67                 media-libs/glew/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	30 Mar 2011 21:13:55 -0000	1.66
+++ ChangeLog	4 May 2011 07:46:24 -0000	1.67
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/glew
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.66 2011/03/30 21:13:55 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.67 2011/05/04 07:46:24 radhermit Exp $
+
+*glew-1.6.0 (04 May 2011)
+
+  04 May 2011; Tim Harder <radhermit@g.o> +glew-1.6.0.ebuild:
+  Version bump.
 
 *glew-1.5.8 (30 Mar 2011)
 



1.1                  media-libs/glew/glew-1.6.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.6.0.ebuild?rev=1.1&content-type=text/plain

Index: glew-1.6.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/glew-1.6.0.ebuild,v 1.1 2011/05/04 07:46:24 radhermit Exp $

EAPI=4
inherit multilib toolchain-funcs

DESCRIPTION="The OpenGL Extension Wrangler Library"
HOMEPAGE="http://glew.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"

LICENSE="BSD MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE=""

RDEPEND="x11-libs/libXmu
	x11-libs/libXi
	virtual/glu
	virtual/opengl
	x11-libs/libXext
	x11-libs/libX11"
DEPEND="${RDEPEND}"

pkg_setup() {
	myglewopts=(
		AR="$(tc-getAR)"
		STRIP=true
		CC="$(tc-getCC)"
		LD="$(tc-getCC) ${LDFLAGS}"
		M_ARCH=""
		LDFLAGS.EXTRA=""
		POPT="${CFLAGS}"
	)
}

src_prepare() {
	sed -i \
		-e '/INSTALL/s:-s::' \
		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
		Makefile || die

	# don't do stupid Solaris specific stuff that won't work in Prefix
	cp config/Makefile.linux config/Makefile.solaris || die
}

src_compile(){
	emake "${myglewopts[@]}"
}

src_install() {
	emake \
		GLEW_DEST="${ED}/usr" \
		LIBDIR="${ED}/usr/$(get_libdir)" \
		"${myglewopts[@]}" install

	dodoc doc/*.txt README.txt TODO.txt
	dohtml doc/*.{css,html,jpg,png}
}