[gentoo-commits] proj/gnome:master commit in: app-crypt/libsecret/

[Gilles Dartiguelongue]

commit:     b1d4f1d1ad9a5e1396d5dc516542133c2ac07f5d
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 22 22:10:32 2012 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Thu Nov 22 22:10:32 2012 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=b1d4f1d1

app-crypt/libsecret: 0.11 → 0.12

---
 app-crypt/libsecret/libsecret-0.12.ebuild |   78 +++++++++++++++++++++++++++++
 app-crypt/libsecret/metadata.xml          |   10 ++++
 2 files changed, 88 insertions(+), 0 deletions(-)

diff --git a/app-crypt/libsecret/libsecret-0.12.ebuild b/app-crypt/libsecret/libsecret-0.12.ebuild
new file mode 100644
index 0000000..bb10dcb
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.12.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+VALA_MIN_API_VERSION=0.18
+VALA_USE_DEPEND=vapigen
+
+inherit eutils gnome2 python vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://live.gnome.org/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+IUSE="+crypt debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.31.0:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2 )
+	introspection? ( >=dev-libs/gobject-introspection-1.29 )"
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-keyring-3"
+# Add ksecrets to RDEPEND when it's added to portage
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		dev-python/mock
+		introspection? (
+			=dev-lang/python-2*
+			>=dev-libs/gjs-1.32
+			dev-python/pygobject:3 )
+	)
+	vala? ( $(vala_depend) )"
+
+pkg_setup() {
+	# python is only needed for tests
+	if use test && use introspection; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	G2CONF="${G2CONF}
+		--enable-manpages
+		--disable-strict
+		--disable-coverage
+		--disable-static
+		$(use_enable crypt gcrypt)
+		$(use_enable introspection)
+		$(use_enable vala)"
+
+	# FIXME: disable failing test
+	sed -e '/test_get_sync);/d' \
+		-e '/test_get_async);/d' \
+		-i libsecret/tests/test-service.c || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	gnome2_src_install
+	prune_libtool_files --all
+}

diff --git a/app-crypt/libsecret/metadata.xml b/app-crypt/libsecret/metadata.xml
new file mode 100644
index 0000000..51e41be
--- /dev/null
+++ b/app-crypt/libsecret/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+  <use>
+    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
+		for introspection</flag>
+    <flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
+  </use>
+</pkgmetadata>